【题解】BZOJ3594:[Scoi2014]方伯伯的玉米田【DP+二维树状数组优化】

题目描述

方伯伯在自己的农田边散步，他突然发现田里的一排玉米非常的不美。
这排玉米一共有N株，它们的高度参差不齐。
方伯伯认为单调不下降序列很美，所以他决定先把一些玉米拔高，再把破坏美感的玉米拔除掉，使得剩下的玉米的高度构成一个单调不下降序列。
方伯伯可以选择一个区间，把这个区间的玉米全部拔高1单位高度，他可以进行最多K次这样的操作。拔玉米则可以随意选择一个集合的玉米拔掉。
问能最多剩多少株玉米，来构成一排美丽的玉米。
输入

第1行包含2个整数n，K，分别表示这排玉米的数目以及最多可进行多少次操作。
第2行包含n个整数，第i个数表示这排玉米，从左到右第i株玉米的高度ai。
输出

输出1个整数，最多剩下的玉米数。
样例输入
3 1

2 1 3

样例输出
3
提示

1 < N < 10000，1 < K ≤ 500，1 ≤ ai ≤5000

【题解】

初始的思路十分重要

每次拔高玉米的右端点总是n

为什么？

如果对中间一段进行操作，对前面的是更优的，但对后面的会劣，所以如果右端点为n，则对后面不会有影响

朴素DP：

dp[i][j]表示前i个，拔j次，最优解

dp[i][j]=max(dp[k][l])+1(i>k,l<=j,a[i]+j>=a[k]+l)
CODE:

uses math;
var
    a:Array[0..10000] of int64;
    dp:array[0..10000,0..500] of int64;
    n,m,i,j,k,l:longint;
begin
    readln(n,m);
    for i:=1 to n do
        read(a[i]);
    for i:=1 to n do
        for j:=m downto 0 do
            for k:=0 to i-1 do
                for l:=m downto 0 do
                    if a[k]+l<=a[i]+j then
                        dp[i][j]:=max(dp[i][j],dp[k][l]+1);
    writeln(dp[n][m]);
end.

时间复杂度O(n^2*k^2)全超 想到用二维树状数组优化

把dp数组变成一个树状数组

定义不变，时间复杂度O(nlogn*klogk)

uses math;
var
    a:Array[0..10000] of int64;
    c:array[0..10000,0..500] of int64;
    n,m,i,j,k,l,maxa,ans,sum:longint;
function lowbit(x:int64):int64;
begin
    exit(x and -x);
end;
procedure change(x,y,z:int64);
var
    yy:int64;
begin
    yy:=y;
    while x<=maxa+m do
        begin
            y:=yy;
            while y<=m+1 do
                begin
                    c[x][y]:=max(c[x][y],z);
                    inc(y,lowbit(y));
                end;
            inc(x,lowbit(x));
        end;
end;
function getsum(x,y:int64):int64;
var
    yy:int64;
begin
    getsum:=0;
    yy:=y;
    while x>0 do
        begin
            y:=yy;
            while y>0 do
                begin
                    getsum:=max(getsum,c[x][y]);
                    dec(y,lowbit(y));
                end;
            dec(x,lowbit(x));
        end;
end;
begin
    readln(n,m);
    for i:=1 to n do
        begin
            read(a[i]);
            maxa:=max(maxa,a[i]);
        end;
    for i:=1 to n do
        for j:=m downto 0 do
            begin
                sum:=getsum(a[i]+j,j+1)+1;
                change(a[i]+j,j+1,sum);
                ans:=max(ans,sum);
            end;
    writeln(ans);
end.