一、如何将多张灰度图片合成一张图片
https://www.bilibili.com/read/cv18187528/
二、常见光照模型
float lambert = max(0,ndotl);//兰伯特，法线点乘光线
float3 halflambert = (nDotl * 0.5 + 0.5) * _MainCol;//半兰伯特，兰伯特*0.5+0.5
float phong = pow(max(0.0,vdotr),_SpecularPow);//Phong，视线方向点乘光线的反射方向
float blinPhong = pow(max(0.0,ndoth),_SpecularPow);//BlinPhong，法线点乘半程向量。
//半程向量为光线方向和视线方向的中间向量
三、面板声明
1、面板参数声明格式
数值，范围：
• _Name (“标签名”, float) = defaultVal
• _Name (“标签名”, range(min, max)) = defaultVal
• _Name (“标签名”, int) = defaultVal
位置，向量，颜色：
• _Name (“标签名”, vector) = (xVal, yVal, zVal, wVal)
• _Name (“标签名”, color) = (rVal, gVal, bVal, aVal)
2D，3D纹理，环境球：
• _Name (“标签名”, 2d) = “defaultTex” {}
• _Name (“标签名”, 3d) = “defaultTex” {}
• _Name (“标签名”, cube) = “defaultTex” {}
2、属性参数
[HideInInspect]
• 用途：在面板上隐藏该参数；
• 可用于：任何参数；
• 例：[HideInInspect] _FakeLightDir (“伪光方向”, vector) = (0.0, 1.0, 0.0, 1.0)
[NoScaleOffset]
• 用途：禁用纹理的TilingOffset面板；不需要做TilingOffset的纹理，比如大部分的角色纹理，防止美术误设置；
• 可用于：纹理参数；
• 例：[NoScaleOffset] _MainTex (“主贴图”, 2d) = “white” {}
[Normal]
• 用途：标示该纹理参数为法线贴图，以激活相关自检功能；
• 可用于：2D纹理参数；
• 例：[Normal] _NormTex (“法线贴图”, 2d) = “bump”{}
[HDR]
• 用途：用于设置高动态范围颜色值；如：灯光颜色，自发光颜色等；
• 可用于：颜色参数；
• 例：[HDR] _EmitCol (“自发光颜色”, color) = (1.0, 1.0, 1.0, 1.0)
[Gamma]
• 用途：用于颜色参数的色彩空间的转换；一般用于色彩空间为Linear的项目；
• 可用于：颜色参数；
• 例：[Gamma] _EmitCol (“自发光颜色”, color) = (1.0, 1.0, 1.0, 1.0)
[PowerSlider(value)]
• 用途：对范围参数做Power处理后再传入Shader；纠正部分参数调节手感；
• 可用于：范围参数；
• 例：[PowerSlider(0.5)] _SpecPow (“高光次幂”, range(1, 90)) = 30
[Header(Label)]
• 用途：标签，用于排版；
• 可用于：单独使用；
• 例：[Header(Texture)]
[Space(value)]
• 用途：空行，用于排版；
• 可用于：单独使用；
• 例：[Space(50)]
其他：[Toggle] [Enum] [Keyword] 配合宏使用，暂时不用知道；自定义Drawer需要一定C#能力，暂时不用知道；
四、常规参数精度设置
• fixed： 11位定点数，-2.0~2.0，精度1/256；
• half： 16位浮点数，-60000~60000，精度约3位小数；
• float： 32位浮点数，-3.4E38~3.4E38，精度约6，7位小数；
• Int： 32位整形数，较少使用；
• bool： 布尔型数，较少使用；
• 矩阵：
• float2x2, float3x3, float4x4, float2x3 诸如此类格式；
• half2x2, half3x3, half4x4, half2x3 诸如此类格式；
• 纹理对象：
• sampler2D： 2D纹理
• sampler3D： 3D纹理
• samplerCUBE： Cube纹理
五、实践模板
Shader "Unlit/NewUnlitShader"
{
Properties
{
[Header(Texture)]
_MainTex ("RGB:颜色 A：透贴", 2d) = "white" {
}
_MaskTex ("R:高光强度 G：边缘光强度 B：高光染色 A：高光次幂",2d) ="black"{
}
_NormTex ("RGB:法线贴图",2d)="bump"{
} //法线较为特殊，默认要为"bump"
_MatelnessMask ("金属度遮罩",2d)="black"{
}
_EmissionMask ("自发光遮罩",2d)="black"{
}
_DiffWarpTex ("颜色Warp图",2d)="gray"{
}
_FresWarpTex ("菲涅尔Warp图",2d)="gray"{
}
_Cubemap ("环境球",cube)="_Skybox"{
} //环境球默认为"_Skybox"
[Header(DirDiff)]
_LightCol ("光颜色",color)=(1.0,1.0,1.0,1.0)
[Header(DirSpec)]
_SpecPow ("高光次幂",range(0.0,99.0))=5
_SpecInt ("高光强度",range(0.0,10.0))=5
[Header(EnvDiff)]
_EnvCol ("环境光颜色",color)=(1.0,1.0,1.0,1.0)
[Header(EnvSpec)]
_EnvSpecInt ("环境光镜面反射强度",range(0.0,30.0))=0.5
[Header(RimLight)]
[HDR]_RimCol ("轮廓光颜色",color)=(1.0,1.0,1.0,1.0)
[Header(Emission)]
_EmiInt ("自发光强度",range(0.0,10.0))=1.0
[HideInInspector]
_Cutoff ("Alpha cutoff",range(0,1))=0.5
[HideInInspector]
_Color ("Main color",color)=(1.0,1.0,1.0,1.0)
}
SubShader
{
Tags {
"RenderType"="Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
// make fog work
#pragma multi_compile_fwdbase_fullshadows
#pragma target 3.0
#include "UnityCG.cginc"
#include "AutoLight.cginc"
#include "Lighting.cginc"
//输入参数
uniform sampler2D _MainTex;
uniform sampler2D _MaskTex;
uniform sampler2D _NormTex;
uniform sampler2D _MatelnessMask;
uniform sampler2D _EmissionMask;
uniform sampler2D _DiffWarpTex;
uniform sampler2D _FresWarpTex;
uniform samplerCUBE _Cubemap;
// DirDiff
uniform half3 _LightCol;
// DirSpec
uniform half _SpecPow;
uniform half _SpecInt;
// EnvDiff
uniform half3 _EnvCol;
// EnvSpec
uniform half _EnvSpecInt;
// RimLight
uniform half3 _RimCol;
// Emission
uniform half _EmitInt;
// Other
uniform half _Cutoff;
// 输入结构
struct VertexInput {
float4 vertex : POSITION; // 顶点信息 Get✔
float2 uv0 : TEXCOORD0; // UV信息 Get✔
float4 normal : NORMAL; // 法线信息 Get✔
float4 tangent : TANGENT; // 切线信息 Get✔
};
// 输出结构
struct VertexOutput {
float4 pos : SV_POSITION; // 屏幕顶点位置
float2 uv0 : TEXCOORD0; // UV0
float4 posWS : TEXCOORD1; // 世界空间顶点位置
float3 nDirWS : TEXCOORD2; // 世界空间法线方向
float3 tDirWS : TEXCOORD3; // 世界空间切线方向
float3 bDirWS : TEXCOORD4; // 世界空间副切线方向
LIGHTING_COORDS(5,6) // 投影相关
};
// 输入结构>>>顶点Shader>>>输出结构
VertexOutput vert (VertexInput v) {
VertexOutput o = (VertexOutput)0; // 新建输出结构
o.pos = UnityObjectToClipPos( v.vertex ); // 顶点位置 OS->CS
o.uv0 = v.uv0; // 传递UV
o.posWS = mul(unity_ObjectToWorld, v.vertex); // 顶点位置 OS->WS
o.nDirWS = UnityObjectToWorldNormal(v.normal); // 法线方向 OS->WS
o.tDirWS = normalize(mul(unity_ObjectToWorld, float4(v.tangent.xyz, 0.0)).xyz); // 切线方向 OS>WS
o.bDirWS = normalize(cross(o.nDirWS, o.tDirWS) * v.tangent.w); // 副切线方向
TRANSFER_VERTEX_TO_FRAGMENT(o) // 投影相关
return o; // 返回输出结构
}
// 输出结构>>>像素
float4 frag(VertexOutput i) : COLOR {
// 向量准备
half3 nDirTS = UnpackNormal(tex2D(_NormTex, i.uv0));//切线空间（tangent space）
half3x3 TBN = half3x3(i.tDirWS, i.bDirWS, i.nDirWS);//构造TBN矩阵
half3 nDirWS = normalize(mul(nDirTS, TBN));//TBN中的N（法线）如果是世界空间，则该TBN矩阵功能为TS->WS，如果是模型空间，则OS->WS,这里的N是世界空间
half3 vDirWS = normalize(_WorldSpaceCameraPos.xyz - i.posWS);//视线方向 view
half3 vrDirWS = reflect(-vDirWS, nDirWS);//视线方向的反射方向
half3 lDirWS = _WorldSpaceLightPos0.xyz;//光方向
half3 lrDirWS = reflect(-lDirWS, nDirWS);//光的反射方向
// 中间量准备
half ndotl = dot(nDirWS, lDirWS);//法线方向 点乘 光方向
half ndotv = dot(nDirWS, vDirWS);//法线方向 点乘 视线方向
half vdotr = dot(vDirWS, lrDirWS);//视线方向 点乘 光的反射方向
// 采样纹理
half4 var_MainTex = tex2D(_MainTex, i.uv0);
half4 var_MaskTex = tex2D(_MaskTex, i.uv0);
half var_MatelnessMask = tex2D(_MatelnessMask, i.uv0).r;
half var_EmissionMask = tex2D(_EmissionMask, i.uv0).r;
half3 var_FresWarpTex = tex2D(_FresWarpTex, ndotv);
half3 var_Cubemap = texCUBElod(_Cubemap, float4(vrDirWS, lerp(8.0, 0.0, var_MaskTex.a))).rgb;
// 提取信息
half3 baseCol = var_MainTex.rgb;
half opacity = var_MainTex.a;
half specInt = var_MaskTex.r;
half rimInt = var_MaskTex.g;
half specTint = var_MaskTex.b;
half specPow = var_MaskTex.a;
half matellic = var_MatelnessMask;
half emitInt = var_EmissionMask;
half3 envCube = var_Cubemap;
half shadow = LIGHT_ATTENUATION(i);
// 光照模型
// 漫反射颜色 镜面反射颜色
half3 diffCol = lerp(baseCol, half3(0.0, 0.0, 0.0), matellic);//根据金属度去判断漫反射的强度，金属度越大，物体越光滑，漫反射越低
half3 specCol = lerp(baseCol, half3(0.3, 0.3, 0.3), specTint) * specInt;//half3(0.3, 0.3, 0.3)为一个经验值，是经验积累出来的相对合适的一个镜面反射的值
// 菲涅尔
half3 fresnel = lerp(var_FresWarpTex, 0.0, matellic);//菲涅尔效果是一种反射效果，近的模糊，远的清晰；·菲涅尔效果取决于入射角的大小；·菲涅尔效果通常用于营造写实的艺术风格。金属度越高的菲涅尔越低
half fresnelCol = fresnel.r; // 无实际用途
half fresnelRim = fresnel.g;
half fresnelSpec = fresnel.b;
// 光源漫反射
half halfLambert = ndotl * 0.5 + 0.5; //半兰伯特模型
half3 var_DiffWarpTex = tex2D(_DiffWarpTex, half2(halfLambert, 0.2)); //RampTexture:渐变纹理，这里的RampTexture实现效果和半兰伯特效果相同
half3 dirDiff = diffCol * var_DiffWarpTex * _LightCol;
// 光源镜面反射
half phong = pow(max(0.0, vdotr), specPow * _SpecPow);//Phong模型
half spec = phong * max(0.0, ndotl);
spec = max(spec, fresnelSpec);
spec = spec * _SpecInt;
half3 dirSpec = specCol * spec * _LightCol;
// 环境漫反射
half3 envDiff = diffCol * _EnvCol;
// 环境镜面反射
half reflectInt = max(fresnelSpec, matellic) * specInt;//反射度的计算
half3 envSpec = specCol * reflectInt * envCube * _EnvSpecInt;
// 轮廓光
half3 rimLight = _RimCol * fresnelRim * rimInt * max(0.0, nDirWS.g);
// 自发光
half3 emission = diffCol * emitInt * _EmitInt;
// 混合
half3 finalRGB = (dirDiff + dirSpec) * shadow + envDiff + envSpec + rimLight + emission;
// 透明剪切
clip(opacity - _Cutoff);
// 返回值
return float4(finalRGB, 1.0);
}
ENDCG
}
}
// 声明回退Shader
FallBack "Legacy Shaders/Transparent/Cutout/VertexLit"
}