内置时间变量

1: float4是内置向量 (x, y, z, w); float4 a; 访问单独成员a.x, a.y, a.z, a.w;
2: fixed4 是内置向量(r, g, b, a); fixed4 c; color.r, color.g, color.b, color.a;
3: float3是内置向量(x, y, z);
4: fixed3 是内置向量(r, g, b);
5: float2 是内置向量(x, y);
6: _Time: 自场景加载开始所经过的时间t，4个分量分别是 (t/20, t, t2, t3);
7: _SinTime: t 是时间的正弦值，4个分量分别是 (t/8, t/4, t/2, t);
8: _CosTime: t 是时间的余弦值，4个分量分别是 (t/8, t/4, t/2, t);
9: unity_DeltaTime: dt 是时间增量，4个分量的值(dt, 1/dt, smoothDt, 1/smoothDt),平滑时间，防止时间间隔起伏太大;

顶点动画

在Unity里面新建一个Plane,给它附上一张贴图，然后我们来编写Shader。
它的原理就是使用正弦函数，对平面在不同的距离的高度进行随时间的修改，以达到正弦波动的效果。

Shader "Custom/SinShader"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
	}
	SubShader
	{
		Tags { "RenderType"="Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
			};

			struct v2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : POSITION;
			};

			sampler2D _MainTex;
			float4 _MainTex_ST;

			v2f vert (appdata v)
			{
				v2f o;
				//计算一个偏移量
			    float4 offset = float4(0,0,0,0);
			    float dist = distance(v.vertex.xyz, float3(0, 0, 0));
			    //偏移量的y是随着距离以及时间做正选函数运动
			    offset.y = sin(3 * dist +_Time.z) / 5;
                //把加上偏移量的值,从顶点从模型空间直接转化到裁剪空间
				o.vertex = UnityObjectToClipPos(v.vertex + offset);
				//根据顶点的纹理，计算出对应的纹理的真正uv坐标
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				fixed4 col = tex2D(_MainTex, i.uv);
				return col;
			}
			ENDCG
		}
	}
}

shader中变量的xyz,rgb,uv表示的含义：
在shader中，经常能看到某个变量.rgb.xyz.uv类似这种值，有时，代码中是.xz有时是.rr，确实容易让人迷惑。有一个方法，可以很容易的理解其变量的含义。变量后面有几个字母，就代表了，这是一个包含几个元素的值。x表示有一个，.xy.xz.yz都是两个，xyz是三个。如果一个值是float4,代表是由4个float组成的一个变量，同理，float3和float2表示3个和2个。接下来，将这个值看成是一个数组一个float3可以看成是[x,y,z]，float2可以看成是[u,v]。此时，我们将XYZ看成是在数组中的索引0，1，2，rgb看成是0，1,2，uv看成是0,1。那么一个float4的变量，其.xyz表示的是，依次取第一个元素，第二个元素，第三个元素，组成一个新的float3。代码中.xy表示的是，依次取第一个元素，第二个元素，组成一个新的float2,.xx表示的是，依次取，第一个元素，还是第一个元素，组成一个新的float2。假如，我们想要取.x，那么写成[0]也是可以的，.y写成[1]也是一样的。将其看成是一个数组结构的变量，就容易理解了。

UV动画

UV动画就是给鱼加上一个波光的效果。这里需要用到两个图片，一个是鱼的贴图，另外一个是波光的贴图。这里可以思考一个波光的贴图为什么是黑色的。
请添加图片描述
原理就是通过对两张纹理的采样进行相加，而波光的uv会随着时间变化进行增加（注意这里图片的Wrap模式设为Repeat）,所以波光会一直在动。

Shader "Custom/uvlight"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _SubTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            sampler2D _SubTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                float2 offset = float2(0,0);
                offset.x = _Time.y * 0.25;
                offset.y = _Time.y * 0.25;
                fixed4 light = tex2D(_SubTex,i.uv+offset);
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv) + light;
                return col;
            }
            ENDCG
        }
    }
}

项目地址

https://gitcode.net/KindSuper_liu/UnityXFramework/-/tree/master/Assets/chao/ShaderDemo

Unity Shader动画-做捕鱼达人效果

内置时间变量

顶点动画

UV动画

项目地址

猜你喜欢