描边效果
Shader "Unlit/Outline"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {
}
_Diffuse ("Diffuse", Color) = (1, 1, 1, 1)
_OutlineWidth ("Outline Width", Float) = 0.001
_OutlineColor ("Outline Color", Color) = (0.5, 1, 1, 1)
}
SubShader
{
Tags {
"Queue" = "Geometry" "RenderType" = "Opaque" }
// Pass1 : 描边
Pass
{
Cull Front
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include <UnityCG.cginc>
#include <Lighting.cginc>
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct v2f
{
float4 pos : SV_POSITION;
};
fixed4 _OutlineColor;
float _OutlineWidth;
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.pos.xy += mul((float3x3)UNITY_MATRIX_VP, UnityObjectToWorldNormal(v.normal)).xy * _OutlineWidth;
return o;
}
fixed4 frag(v2f i) : SV_Target
{
return _OutlineColor;
}
ENDCG
}
// Pass2 : 正常渲染(包括光照)
Pass
{
Tags {
"LightMode" = "ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include <UnityCG.cginc>
#include <UnityLightingCommon.cginc>
#include <Lighting.cginc>
#include <AutoLight.cginc>
struct a2v
{
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 texcoord : TEXCOORD0;
};
struct v2f
{
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float4 worldPos : TEXCOORD1;
float3 worldNormal : TEXCOORD2;
SHADOW_COORDS(4)
};
sampler2D _MainTex;
float4 _MainTex_ST;
fixed4 _Diffuse;
v2f vert(a2v v)
{
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.worldPos = mul(unity_ObjectToWorld, v.vertex);
o.worldNormal = UnityObjectToWorldNormal(v.normal);
o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target
{
fixed3 worldNormal = normalize(i.worldNormal);
float3 worldPos = i.worldPos;
fixed3 litDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 color = tex2D(_MainTex, i.uv).rgb * _Diffuse.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
fixed3 diffuse = _LightColor0.rgb * color * (dot(litDir, worldNormal) * 0.5 + 0.5);
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);
return fixed4(diffuse * atten + ambient, 1.0);
}
ENDCG
}
}
Fallback off
}