Unity Shader 中实现凹凸映射

使用切线空间

每一个顶点都有自己的切线空间。在该空间中，z轴是顶点的法线方向，x轴是顶点的切点方向，而y方向则是两者叉积的方向。
我们需要在顶点着色器中把视角方向和光照方向从模型空间变换到切线空间中，即我们需要从模型空间到切线空间的变换矩阵。而很好求的是，这个变换矩阵的逆矩阵正是在顶点着色器中切线(x轴)，副切线(y轴)，法线(z轴)的顺序！！按列！！排列即可得到。
并且，如果变换中仅存在平移和旋转变换，则变换矩阵的逆矩阵就是它的转置。所以变换矩阵即是按行排列xyz轴之后的结果。

Shader中的实现

使用切线空间来实现的方式

Shader "Unity Shaders Learn/Chapter 7/Normal Map In Tangent Space" {
    Properties {
        _Color ("Color Tint", Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _BumpMap("Normal Map", 2D) = "bump"{}
        _BumpScale("Bumo Scale",Float) = 1.0
        _Gloss("Gloss", Range(8.0,256)) = 20
        _Specular("Specular", Color) = (1,1,1,1)
    }
    SubShader{
            Pass{
        Tags { "LightMode" = "ForwardBase" }
        CGPROGRAM
        #pragma vertex vert
        #pragma fragment frag
        #include "Lighting.cginc"

        fixed4 _Color;
        sampler2D _MainTex;
        float4 _MainTex_ST;
        sampler2D _BumpMap;
        float4 _BumpMap_ST;
        float _BumpScale;
        fixed4 _Specular;
        float _Gloss;

        struct a2v {
            float4 vertex : POSITION;
            float3 normal : NORMAL;
            float4 tangent : TANGENT;
            float4 texcoord : TEXCOORD0;
        };

        struct v2f {
            float4 pos : SV_POSITION;
            float4 uv : TEXCOORD0;
            float3 lightDir : TEXCOORD1;
            float3 viewDir : TEXCOORD2;
        };

        v2f vert(a2v v) {
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex);
            // uv 变量中 xy存储了_MainTex的纹理坐标， zw存储了_BumpMap的纹理坐标，分别对其进行赋值
            o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
            o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;

            // 以下注释的两句话是通过手动来计算出模型空间到切线空间的变换矩阵rotation
            // float3 binormal = cross(normalize(v.normal), normalize(v.tangent.xyz)) * v.tangent.w;   // 通过叉乘切线法线来确定y轴
            // float3x3 rotation = float3x3(v.tangent.xyz, binormal, v.normal);    // 将其拼装成变换矩阵
            // 而宏命令TANGENT_SPACE_ROTATION则直接等于以上两句
            TANGENT_SPACE_ROTATION;

            //得到切线空间下的光照和视角方向
            o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
            o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;

            return o;
        }

        fixed4 frag(v2f i) :SV_Target{
            // 归一化顶点着色器中得到的数据
            fixed3 tangentLightDir = normalize(i.lightDir);
            fixed3 tangentViewDir = normalize(i.viewDir);

            // 获取每个像素点的法线坐标
            fixed4 packedNormal = tex2D(_BumpMap, i.uv.zw);
            fixed3 tangentNormal;
            // 如果纹理坐标没有被标记为normal map的话

            // 如果是normal map类型,使用自带的UnpackNormal方式
            tangentNormal = UnpackNormal(packedNormal);
            tangentNormal.xy *= _BumpScale;
            tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
            // 计算反照率albedo，环境光ambient，漫反射光diffuse
            fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
            fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
            fixed3 diffuse = _LightColor0.rgb * albedo * (dot(tangentNormal, tangentLightDir)*0.5 + 0.5);  //漫反射由法线和光线来决定
            // 计算高光specular,采用Blinn模型，计算出halfDir，即归一化的视线加光线
            fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
            fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss);

            return fixed4(ambient + diffuse + specular, 1.0);
        }

        ENDCG
            }
    }
    FallBack "Specular"
}

可以通过修改Material上的参数面板来调整效果。比如：

调整了Bumo Scale之后，显得更加突起