纹理另一种常见的应用就是凹凸映射，使用一张纹理来修改模型表面的法线，以便为模型提供更多的细节。
有两种主要方法实现：一种方法是使用一张高度纹理来模拟表面位移，然后得到一个修改后的法线值，也被称为高度映射。另一种方法则是使用一张法线纹理来直接存储表面法线，也被称为法线映射。
第一种方式计算会更加复杂，我们通常会将高度图和法线映射一起使用，法线方向的分量范围在[-1,1]，而像素的分量范围为[0,1]，因此我们需要做一个映射：
这就要求，在Shader中第法线纹理进行纹理采样后，还需要对结果进行一次反映射的过程，以得到原先的法线方向。反映射的过程实际就是使用上面映射函数的逆函数：
因为法线纹理中存储的法线方向在模型空间中，但是在实际制作中我们往往会采用切线空间来存储法线，对于模型每个顶点它都会有一个属于自己的切线空间，这个切线空间的原点就是该顶点本身，而z轴是顶点的法线方向，x轴是顶点的切线方向，y轴可由法线和切线叉积而得 。
将法线贴图导入，将texture type设置为normal map，代表是法线贴图。
思路： CPU传递过来的期限储存在模型空间下，法线纹理中的光照法线推算信息，是存储在切线空间下的。CPU传递过来的切线信息和法线纹理中的切线信息有转换关系，所以可以推算出一个转换矩阵用于转换法线。计算出来的转换矩阵是从切线空间到模型空间的转换，但是我们需要的是从切线空间到世界空间的转换矩阵（因为光照运算需要在世界空间中完成），所以应该先把CPU传递过来的切线信息转换到世界空间下，在计算切线的转换矩阵，这样就能得到从切线空间到世界空间的转换矩阵，拥有了转换矩阵，就可以将法线纹理中，求解的法线信息从切线空间转换到世界空间下。
在切线空间下计算：
Shader "Unity Shaders Book/Chapter 7/Normal Map In Tangent Space" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" {}
//法线纹理，“bump”是Unity内置的法线纹理
_BumpMap ("Normal Map", 2D) = "bump" {}
//用于控制凹凸程度
_BumpScale ("Bump Scale", Float) = 1.0
_Specular ("Specular", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader {
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
//主纹理信息
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
//法线信息
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
//高光反射
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
//将顶点的切线方向填充到tangent中，使用.w分量来决定切线空间中的第三个坐标轴
float4 tangent : TANGENT;
//由于两张图的纹理坐标点基本一致，可以用一个变量代替
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
//将主纹理的uv存储在xy，将副纹理的uv存储在zw
float4 uv : TEXCOORD0;
float3 lightDir: TEXCOORD1;
float3 viewDir : TEXCOORD2;
};
float4x4 inverse(float4x4 input) {
#define minor(a,b,c) determinant(float3x3(input.a, input.b, input.c))
float4x4 cofactors = float4x4(
minor(_22_23_24, _32_33_34, _42_43_44),
-minor(_21_23_24, _31_33_34, _41_43_44),
minor(_21_22_24, _31_32_34, _41_42_44),
-minor(_21_22_23, _31_32_33, _41_42_43),
-minor(_12_13_14, _32_33_34, _42_43_44),
minor(_11_13_14, _31_33_34, _41_43_44),
-minor(_11_12_14, _31_32_34, _41_42_44),
minor(_11_12_13, _31_32_33, _41_42_43),
minor(_12_13_14, _22_23_24, _42_43_44),
-minor(_11_13_14, _21_23_24, _41_43_44),
minor(_11_12_14, _21_22_24, _41_42_44),
-minor(_11_12_13, _21_22_23, _41_42_43),
-minor(_12_13_14, _22_23_24, _32_33_34),
minor(_11_13_14, _21_23_24, _31_33_34),
-minor(_11_12_14, _21_22_24, _31_32_34),
minor(_11_12_13, _21_22_23, _31_32_33)
);
#undef minor
return transpose(cofactors) / determinant(input);
}
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
//构造一个矩阵，将点/向量从切线空间转换为世界空间
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
//计算切线与法线垂直的线的方向向量
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
//需要将转换矩阵，传递给片元着色器，用于转换切线空间下的法线到世界空间中
float3x3 worldToTangent = float3x3(worldTangent, worldBinormal, worldNormal);
// Transform the light and view dir from world space to tangent space
o.lightDir = mul(worldToTangent, WorldSpaceLightDir(v.vertex));
o.viewDir = mul(worldToTangent, WorldSpaceViewDir(v.vertex));
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentViewDir = normalize(i.viewDir);
//计算法线纹理中的法线信息，解出的法线在切线空间
//解法线前，需要先对法线纹理贴图进行采样
fixed4 packedNormal = tex2D(_BumpMap, i.uv.zw);
fixed3 tangentNormal;
tangentNormal = UnpackNormal(packedNormal);
//通过缩放值，影响凹凸感
tangentNormal.xy *= _BumpScale;
//计算法线高度
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal, halfDir)), _Gloss);
return fixed4(ambient + diffuse + specular, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}