unity shader 入门之路（七）初次使用shader forge

文本编辑器和可视化编辑器究竟有多大差距，我们可以具体到之前学习的标准光照模型。

这是兰伯特模型：

/*******************************************
Lambert(兰伯特)光照模型
    1. 理想的漫反射；
    2. 计算都在顶点着色器，因此像素不会平滑过渡；
*******************************************/
Shader "JQM/Lambert"
{
    Properties
    {
        _Color("Color", color) = (1.0,1.0,1.0,1.0)
    }
    SubShader{
        Pass{
            
            Tags { "LightMode" = "ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            //使用自定义变量
            uniform float4 _Color;

            //使用Unity定义的变量
            uniform float4 _LightColor0;

            struct vertexInput{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
            };

            struct vertexOutput{
                float4 pos:SV_POSITION;
                float4 col:COLOR;
            };

            //顶点程序
            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;
                
                float3 normalDirection = normalize( mul(float4(v.normal,0.0),_World2Object).xyz);//将模型空间的法线转到世界空间
                float3 lightDirection;
                float atten = 1.0;

                lightDirection = normalize(_WorldSpaceLightPos0.xyz);//灯光方向
                float3 diffuseReflection = atten * _LightColor0.xyz *  max(0.0, dot(normalDirection,lightDirection));//计算兰伯特漫反射
                float3 lightFinal = diffuseReflection + UNITY_LIGHTMODEL_AMBIENT.xyz;//与环境光结合

                o.col = float4(lightFinal*_Color.rgb,1.0);
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                return o;
            }

            //片段程序
            float4 frag(vertexOutput i):COLOR
            {
                return i.col;
            }

            ENDCG
        }
    }
    
}

这是半兰伯特模型：

Shader "Unity Shaders Book/Chapter 6/HalfLambert"  
{  
    Properties  
    {  
         //定义属性，控制材质的漫反射颜色  
        _Diffuse ("Diffuse", Color)=(1,1,1,1)  
    }  
    SubShader  
    {  
        Pass  
        {  
            //指明该Pass的光照模式  
            Tags{"LightMode"="ForwardBase"}  
              
            CGPROGRAM  
  
            //告诉Unity我们定义的定点着色器和片远着色器的名字  
            #pragma vertex vert  
            #pragma fragment frag  
  
            // 包含引用内置文件       
            #include "Lighting.cginc"  
  
            //引用属性，定义一个与该属性类型相匹配的变量  
            fixed4 _Diffuse;  
  
            //定义顶点着色器的输入和输出结构体  
            struct a2v  
            {  
                float4 vertex : POSITION;  
                float3 normal : NORMAL;//存储模型法线信息  
            };  
  
            struct v2f  
            {  
                float4 pos : SV_POSITION;  
                float3 worldNormal : TEXCOORD0;  
            };  
  
            //在顶点着色器中只需将模法线传递给片元着色器  
            v2f vert (a2v v)  
            {  
                v2f o;  
                //将顶点坐标从模型坐标转换为裁剪坐标  
                o.pos = UnityObjectToClipPos(v.vertex);  
                //将模型法线转换到世界坐标，并传递给片元着色器  
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);  
                return o;  
            }  
  
            //在片元着色器中计算漫反射光照模型  
            fixed4 frag (v2f i) : SV_Target  
            {  
                   //获取环境光  
                   fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;  
                   //获取世界空间下的法线并归一化  
                   fixed3 worldNormal = normalize(i.worldNormal);  
                   //获取世界空间下的光照方向  
                   fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);  
                   //计算半兰伯特值 = dot(法线方向 ，光照方向)*0.5 +0.5;  
                   fixed halfLambert = dot(worldNormal, worldLightDir) * 0.5 + 0.5;  
                   //计算漫反射光照模型  
                   fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * halfLambert;  
  
                   fixed3 color = ambient + diffuse;  
                   return fixed4(color,1.0);  
            }  
            ENDCG  
        }  
    }  
    Fallback "Diffuse"  
}

如果使用的编辑器不带有代码不全和智能联想，纠错，蛋疼系数相当的高。

如果使用shader forge，我们得这样：

从这里找到shader forge（别问我为什么你那里没有）