GDScript：通用状态机V2.0

之前用GDScript写过一个通用状态机，见《GDScript：有限状态机（FSM）的实现》 最近又参考了GDQuest的开源项目godot-3d-mannequin重写了一版。个人觉得GDQuest的版本耦合度稍大，不便于后期维护，不过他使用节点树代替我之前版本的字典容器，是非常巧妙的设计，不但减少了代码量而且便于动态增减状态。不论是哪个版本，能够在50行代码之内完成一个状态机，足以说明GDScirpt这种语言对游戏逻辑开发的友好

FSM类

extends Node
class_name FSM,"fsm.png"

signal transitioned(state_path)

export var _host : NodePath = NodePath("..")
onready var host := get_node_or_null(_host)

export var initial_state : NodePath = ""
onready var state := get_node_or_null(initial_state) 

func _ready() -> void:
	yield(owner, "ready")
	if is_instance_valid(state):
		state.enter(self)
func _process(delta: float) -> void:
	if is_instance_valid(state):
		state.update(self,delta)
func _physics_process(delta: float) -> void:
	if is_instance_valid(state):
		state.fixed_update(self,delta)
func _unhandled_input(event) -> void:
	if is_instance_valid(state):
		state.input(self,event)

func transition_to(target_state_path: String, msg: Dictionary = {}) -> void:
	if not has_node(target_state_path):
		return
	if is_instance_valid(state):
		state.exit(self)
	state = get_node_or_null(target_state_path)
	if is_instance_valid(state):
		state.enter(self,msg)
	emit_signal("transitioned",target_state_path)

State类

extends Node
class_name State,"state.png"


func enter(fsm:FSM,msg:Dictionary = {}) -> void:
	return
func update(fsm:FSM,delta:float) -> void:
	return
func fixed_update(fsm:FSM,delta:float) -> void:
	return
func exit(fsm:FSM) -> void:
	return
func input(fsm:FSM,e:InputEvent)-> void:
	return