Matcap简介

Matcap Shader是一种在某些层面能替代甚至超越PBR的次时代渲染方案。

它的效率极高、计算成本极低，显示效果极佳，却能完美运行于不同的移动平台，并兼容AR、VR设备，所以极具研究与实用价值。

但Matcap也有很多局限性和缺点，此系列文章就是用于讲解Matcap的实现方法与针对其问题的优化。

Unity Community Wiki 中将其定义为：

用于均一表面反射材质的着色器，在Zbrush/Mudbox等软件中被广泛运用。它借助一幅含有球面的图片作为视线空间的环境映射，计算成本非常低廉，当相机不转动时视觉效果极其出色。

ZB中的Matcap

Matcap原理

Matcap的原理并不复杂，就是使用一张中间为球面的图片作为不同法线方向的光照颜色，然后将这些颜色根据模型的法线信息渲染到相应位置。

例如下图图二（黑白）中，球形就是Matcap贴图，箭头代表了右下朝向的法线，车与人的模型法线朝向此相同方向时，就会渲染为球形贴图上相应点的颜色——白色。

matcap原理示意图

Matcap的优点

正如文章开始所说，Matcap一大优势是——运算效率极高，计算成本极低，在很多场合却能够替代PBR。用Unlit级别的计算成本，获得3A级的渲染效果，这正是Matcap吸引人的地方。

除此之外，Matcap也拥有PBR不具备的优势——充满了很多新的可能性，只需简单更换Matcap贴图，就能实现各种神奇的渲染效果。具体请看下方示例，每幅左上角为Matcap取样贴图。

粗糙金属质感

冰霜质感

素描质感

粉晶质感

幽灵质感

卡通质感

车漆质感

如何实现Matcap

Matcap的原理简单，实现起来也并不复杂，下面是基础Matcap在U3D中的实现代码：

Shader "TJia/Matcap_Basic" {
	Properties {
		_MatCapDiffuse ("MatCapDiffuse (RGB)", 2D) = "white" {}
	}
	
	Subshader {
		Tags { "RenderType"="Opaque" }
		
		Pass {
			Tags { "LightMode" = "Always" }
			
			CGPROGRAM
				#pragma vertex vert
				#pragma fragment frag
				#include "UnityCG.cginc"
				
				struct v2f { 
					float4 pos : SV_POSITION;
					float2	NtoV : TEXCOORD1;
				};
				
				v2f vert (appdata_tan v)
				{
					v2f o;
					o.pos = UnityObjectToClipPos (v.vertex);

					o.NtoV.x = mul(UNITY_MATRIX_IT_MV[0].xyz, v.normal);
					o.NtoV.y = mul(UNITY_MATRIX_IT_MV[1].xyz, v.normal);
					return o;
				}
				
				uniform sampler2D _MatCapDiffuse;
				
				float4 frag (v2f i) : COLOR
				{
					fixed4 matcapLookup = tex2D(_MatCapDiffuse, i.NtoV * 0.5 + 0.5);					
					fixed4 finalColor = matcapLookup;
					return finalColor;
				}

			ENDCG
		}
	}
}

说明：

LightMode 为 Alyaws，这样无论是否有灯光都会渲染
UNITY_MATRIX_IT_MV 用于将法线从模型空间转化到视觉空间，以便映射Matcap采样贴图，使用方法可自行查询
NtoV（视觉空间下的二维法线向量）值域为[-1,1]，而贴图UV的定义域是[0,1]，所以用 uv = i.NtoV * 0.5 + 0.5 的方法进行了映射

最终结果如下，可以更换MatcapDiffuse来更换渲染效果：