Matcap是Material Capture(材质捕获)的缩写，原理是将一张已经渲染好的光照贴图作为相机空间环境贴图（view-space environment map），然后用物体表面的法线去采样这个贴图并把采样的颜色贴到模型表面，因为是直接采样没有做复杂的光照计算，所以性能更好。
优点：计算成本低，适合中低端手机，近似PBR效果
缺点：
- 因为光照是假的，所以无法响应光源和相机位置的变化
- 没有漫反射，高光反射，金属度，光滑度等参数可以调整
- 在平面上效果不好，如立方体
红色箭头表示物体在相机空间中的法线，中间的图表示一个光照贴图（为了方便理解映射关系，分成四个区域加上不同的颜色），因为法线的取值范围是 [-1, 1]，而贴图的uv取值范围是 [0, 1]，所以需要先做转换然后采样，右图是采样后的结果
shader基础实现
Shader "MyCustom/Matcap"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {
}
_Matcap ("_Matcap", 2D) = "white" {
}
}
SubShader
{
Tags {
"RenderType" = "Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float2 uv : TEXCOORD0;
float2 matcapuv : TEXCOORD1;
float4 vertex : SV_POSITION;
};
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _Matcap;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.uv, _MainTex);
//UNITY_MATRIX_IT_MV是UNITY_MATRIX_MV的逆转置矩阵，用于将法线从模型空间转换到观察空间
//如果使用UNITY_MATRIX_MV做转化，对非统一缩放的模型会有问题
float3 viewNormal = normalize(mul((float3x3)UNITY_MATRIX_IT_MV, v.normal));
//法线值区间[-1,1]转换到纹理的区间[0,1]
o.matcapuv = viewNormal.xy * 0.5 + 0.5;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed4 col = tex2D(_MainTex, i.uv);
fixed4 matcap = tex2D(_Matcap, i.matcapuv);
col *= matcap;
return col;
}
ENDCG
}
}
Fallback "Diffuse"
}
这里只使用matcap贴图
物体上向上的法线就会去贴图的上方采样，同理其他方向也一样
即使物体旋转，相机空间中的法线不变，采样的结果就不变
边缘采样问题
把球体模型移到窗口边缘，有的matcap贴图在边缘就会出现采样问题，如图红色箭头所指，这是因为这张matcap贴图制作有误差，圆和贴图边缘没有百分百相切，为了避免这种误差，需要做一点修正，即将值域的范围缩小一点
// o.matcapuv = viewNormal.xy * 0.5 + 0.5;
o.matcapuv = viewNormal.xy * 0.495 + 0.5;
修正后的效果
模型平面采样问题
对于平面模型如立方体，每个面颜色都一样，这是因为平面上每个点的法线都一样，采样的颜色自然都一样，解决方法是把平面的法线映射到球面上
如图，平面上hy点映射到球面上的h点，在h点的法向量为n是反射向量和眼睛矢量的半角向量
图中蓝色z轴表示相机这个gameObject的局部空间z轴，而相机空间中z轴与它是相反的，因为相机使用的是右手坐标系，所以眼睛矢量为（0, 0, 1）
优化后的shader
Shader "MyCustom/Matcap"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {
}
_Matcap ("_Matcap", 2D) = "white" {
}
}
SubShader
{
Tags {
"RenderType" = "Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float2 uv : TEXCOORD0;
float2 matcapuv : TEXCOORD1;
float4 vertex : SV_POSITION;
};
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _Matcap;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.uv, _MainTex);
//UNITY_MATRIX_IT_MV是UNITY_MATRIX_MV的逆转置矩阵，用于将法线从模型空间转换到观察空间
//如果使用UNITY_MATRIX_MV做转化，对Scale不一致的模型，会导致变换的法线归一化后与面不垂直
float3 viewNormal = normalize(mul((float3x3)UNITY_MATRIX_IT_MV, v.normal));
float3 viewPos = UnityObjectToViewPos(v.vertex);
//在相机空间中的反射向量
float3 viewRef = reflect(viewPos, viewNormal);
//球面法向量
float3 sphereNormal = viewRef + float3(0,0,1);
//模长
float3 m = sqrt(pow(sphereNormal.x, 2) + pow(sphereNormal.y, 2) + pow(sphereNormal.z, 2));
//归一化处理
sphereNormal = sphereNormal / m;
//法线值区间[-1,1]转换到纹理的区间[0,1]
o.matcapuv = sphereNormal.xy * 0.495 + 0.5;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed4 col = tex2D(_MainTex, i.uv);
fixed4 matcap = tex2D(_Matcap, i.matcapuv);
col *= matcap;
return col;
}
ENDCG
}
}
Fallback "Diffuse"
}
可以看到平面上也出现了渐变的效果
添加环境光反射
为了能反射环境光，可以对场景中的CubeMap进行采样，将采样后的颜色贴到物体表面，这样会更加真实
最终的shader
Shader "MyCustom/Matcap"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {
}
_Matcap ("_Matcap", 2D) = "white" {
}
_CubeMap ("_CubeMap", Cube) = "" {
}
_ReflectionStrength ("[反射强度] _ReflectionStrength", Range(0, 1)) = 0.5
}
SubShader
{
Tags {
"RenderType" = "Opaque" }
LOD 100
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
struct appdata
{
float4 vertex : POSITION;
float2 uv : TEXCOORD0;
float3 normal : NORMAL;
};
struct v2f
{
float2 uv : TEXCOORD0;
float2 matcapuv : TEXCOORD1;
float3 worldRef : TEXCOORD2;
float4 vertex : SV_POSITION;
};
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _Matcap;
samplerCUBE _CubeMap;
float _ReflectionStrength;
v2f vert (appdata v)
{
v2f o;
o.vertex = UnityObjectToClipPos(v.vertex);
o.uv = TRANSFORM_TEX(v.uv, _MainTex);
float3 worldNormal = normalize(UnityObjectToWorldNormal(v.normal));
float3 worldPos = mul(unity_ObjectToWorld, v.vertex);
float3 worldView = normalize(UnityWorldSpaceViewDir(worldPos));
//世界空间中的反射
o.worldRef = reflect(-worldView, worldNormal);
//UNITY_MATRIX_IT_MV是UNITY_MATRIX_MV的逆转置矩阵，用于将法线从模型空间转换到观察空间
//如果使用UNITY_MATRIX_MV做转化，对Scale不一致的模型，会导致变换的法线归一化后与面不垂直
float3 viewNormal = normalize(mul((float3x3)UNITY_MATRIX_IT_MV, v.normal));
float3 viewPos = UnityObjectToViewPos(v.vertex);
//在相机空间中的反射向量
float3 viewRef = reflect(viewPos, viewNormal);
//球面法向量
float3 sphereNormal = viewRef + float3(0,0,1);
//模长
float3 m = sqrt(pow(sphereNormal.x, 2) + pow(sphereNormal.y, 2) + pow(sphereNormal.z, 2));
//归一化处理
sphereNormal = sphereNormal / m;
//法线值区间[-1,1]转换到纹理的区间[0,1]
o.matcapuv = sphereNormal.xy * 0.495 + 0.5;
return o;
}
fixed4 frag (v2f i) : SV_Target
{
fixed4 col = tex2D(_MainTex, i.uv);
fixed4 matcap = tex2D(_Matcap, i.matcapuv);
//对cubemap采样获得环境光
float3 reflection = texCUBE(_CubeMap, i.worldRef).rgb;
col.rgb = lerp(col.rgb, reflection, _ReflectionStrength);
col *= matcap;
return col;
}
ENDCG
}
}
Fallback "Diffuse"
}
这里场景的天空盒和材质使用了同一个cubemap，对于玻璃或金属材质调高反射强度获得一个比较好的效果
只需更换matcap贴图，就可以获得不同材质效果