【Unity学习】Unity Shader 实现透明效果（1）

获得透明度效果的两种方法

在Unity中，可以使用两种办法来获得透明效果：
1. 使用透明度测试(Alpha Test)，但其实得到的并不是真正的半透明效果
2. 使用透明度混合(Alpha Blending),得到的效果是比较真实的

渲染顺序问题

1.对于不透明的物体，不考虑渲染顺序也能产生正确结果，因为有深度缓冲（Z-buffer）
2.对于半透明物体，这招就不管用了，因为在使用透明度混合时，我们关闭了深度写入（Z-Write）
3.深度写入时将深度值更新到缓冲中

透明度测试Alpha Test原理

只要一个片元的透明度不满足条件，那么它对应的片元就要被舍弃。被舍弃的不进行任何操作，不被舍弃的当作正常不透明片元处理。所以它甚至不用关闭深度写入。所以它要么完全透明、要么不透明。

透明度测试Alpha Test原理

可以得到真正的半透明效果。它使用当前片元的透明度作为混合因子，与已经存储在颜色缓冲中的颜色进行混合，得到新的颜色。需要关闭深度写入。
但要注意的是，但是要注意的是，它只关闭了深度写入，但是没有关闭深度测试，所以如果它的深度值距离摄像机更远，则不会再进行混合操作。所以对透明度混合来说，深度缓冲是只读的。

Unity Shader的渲染顺序

Unity提供了渲染队列(render queue)这一解决方案。
我们可以使用SubShader中的Queue标签来决定我们的模型将归于哪个渲染队列。
索引号越小表示越早被渲染。
其中Unity预先定义了5个渲染队列：

名称	队列索引号	描述
Background	1000	会在其它任何队列之前被渲染
Geometry	2000	默认渲染队列，不透明物体
AlphaTest	2450	透明度测试用的队列
Transparent	3000	在Geometry和AlphaTest之后，按从后往前的顺序进行渲染，任何使用了透明度混合的物体都应该在这个队列
Overlay	4000	用于实现一些叠加效果，需要最后渲染时使用此队列

示例：
透明度混合

SubShader {
    Tags {"Queue"="Transparent"} // 透明度混合
    Pass {
        ZWrite OFF;   // 关闭深度写入
    }
}

透明度测试

SubShader {
    Tags {"Queue"="Transparent"  "IgnoreProjector"="True"  "RanderType"="TransparentCutout"} // 透明度测试
    Pass {
        ZWrite OFF;   // 关闭深度写入
    }
}

其中IgnoreProjector标签可以设置不受投影器影响，RanderType标签可以将Shader归入到提前定义的组

实现透明度测试

Shader "Unity Shaders Learn/Alpha Test" {
    Properties {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _Cutoff ("Alpha Cutoff", Range(0, 1)) = 0.5
    }
    SubShader {
        Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}

        Pass {
            Tags { "LightMode"="ForwardBase" }

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed _Cutoff;

            struct a2v {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float4 texcoord : TEXCOORD0;
            };

            struct v2f {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v) {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;

                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target {
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                fixed4 texColor = tex2D(_MainTex, i.uv);

                // 最重要的透明度测试部分，使用函数clip（float/2/3/4 x）只要有负数就true
                clip (texColor.a - _Cutoff);
                // Equal to 
//              if ((texColor.a - _Cutoff) < 0.0) {
//                  discard;
//              }

                fixed3 albedo = texColor.rgb * _Color.rgb;

                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));

                return fixed4(ambient + diffuse, 1.0);
            }

            ENDCG
        }
    } 
    FallBack "Transparent/Cutout/VertexLit"
}

透明度混合见【Unity学习】Unity Shader 实现透明效果（2）