Unity系列文章目录
文章目录
前言
遮罩纹理（mask texture）是本章要介绍的最后一种纹理，它非常有用，在很多商业游戏中
都可以见到它的身影。那么什么是遮罩呢？简单来讲，遮罩允许我们可以保护某些区域，使它们
免于某些修改。例如，在之前的实现中，我们都是把高光反射应用到模型表面的所有地方，即所
有的像素都使用同样大小的高光强度和高光指数。但有时，我们希望模型表面某些区域的反光强
烈一些，而某些区域弱一些。为了得到更加细腻的效果，我们就可以使用一张遮罩纹理来控制光
照。另一种常见的应用是在制作地形材质时需要混合多张图片，例如表现草地的纹理、表现石子
的纹理、表现裸露土地的纹理等，使用遮罩纹理可以控制如何混合这些纹理。
使用遮罩纹理的流程一般是：通过采样得到遮罩纹理的纹素值，然后使用其中某个（或某几
个）通道的值（例如texel.r）来与某种表面属性进行相乘，这样，当该通道的值为0 时，可以保
护表面不受该属性的影响。总而言之，使用遮罩纹理可以让美术人员更加精准（像素级别）地控
制模型表面的各种性质。
一、实践
在本节中，我们将学习如何使用一张高光遮罩纹理，逐像素地控制模型表面的高光反射强度。
图17.20 显示了只包含漫反射、未使用遮罩的高光反射和使用遮罩的高光反射的对比效果。
▲图7.20 使用高光遮罩纹理。从左到右：只包含漫反射，未使用遮罩的高光反射，使用遮罩的高光反射
我们使用的遮罩纹理如图7.21 所示。可以看出，遮罩纹理可以让我们更加精细地控制光照细
节，得到更细腻的效果。
为了在Unity Shader 中实现上述效果，我们需要进行如下准备工作。
（1）在Unity 中新建一个场景。在本书资源中，该场景
名为Scene_7_4。在Unity 5.2 中，默认情况下场景将包含一
个摄像机和一个平行光，并且使用了内置的天空盒子。在
Window -> Lighting -> Skybox 中去掉场景中的天空盒子。
（2）新建一个材质。在本书资源中，该材质名为
MaskTextureMat。
（3）新建一个Unity Shader。在本书资源中，该Unity
Shader 名为Chapter7-MaskTexture。把新的Unity Shader
赋给第2 步中创建的材质。
（4）在场景中创建一个胶囊体，并把第2 步中的材质
赋给该胶囊体。
（5）保存场景。
打开新建的Chapter7-MaskTexture，删除所有已有代码，并进行如下修改：
（ 1）首先，我们需要为这个 Shader 起一个名字：
Sh ader “Unity Shaders Book/Chapter 7/Mask Texture” {
（ 2）我们需要在 Properties 语义块中声明更多的变量来控制高光反射：
Properties {
_Color (“Color Tint”, Color) = (1,1,1,1)
_MainTex (“Main Tex”, 2D) = “white” {}
_BumpMap (“Normal Map”, 2D) = “bump” {}
_BumpScale(“Bump Scale”, Float) = 1.0
_SpecularMask (“Specular Mask”, 2D) = “white” {}
_SpecularScale (“Specular Scale”, Float) = 1.0
_Specular (“Specular”, Color) = (1, 1, 1, 1)
_Gloss (“Gloss”, Range(8.0, 256)) = 20
}
上面属性中的_SpecularMask 即是我们需要使用的高光反射遮罩纹理，_SpecularScale 则是用
于控制遮罩影响度的系数。
（3）然后，我们在SubShader 语义块中定义了一个Pass 语义块，并在Pass 的第一行指明了该
Pass 的光照模式：
SubShader {
Pass {
Tags { “LightMode”=“ForwardBase” }
LightMode 标签是Pass 标签中的一种，它用于定义该Pass 在Unity 的光照流水线中的角色。
（4）然后，我们使用CGPROGRAM 和ENDCG 来包围住Cg 代码片，以定义最重要的顶点着
色器和片元着色器代码。我们使用#pragma 指令来告诉Unity，我们定义的顶点着色器和片元着色
器叫什么名字。在本例中，它们的名字分别是vert 和frag：
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
（5）为了使用Unity 内置的一些变量，如_LightColor0，还需要包含进Unity 的内置文件
Lighting.cginc：
#include “Lighting.cginc”
（6）随后，我们需要定义和Properties 中各个属性类型相匹配的变量：
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float _BumpScale;
sampler2D _SpecularMask;
float _SpecularScale;
fixed4 _Specular;
float _Gloss;
我们为主纹理_MainTex、法线纹理_BumpMap 和遮罩纹理_SpecularMask 定义了它们共同使
用的纹理属性变量_MainTex_ST。这意味着，在材质面板中修改主纹理的平铺系数和偏移系数会
同时影响3 个纹理的采样。使用这种方式可以让我们节省需要存储的纹理坐标数目，如果我们为
每一个纹理都使用一个单独的属性变量TextureName_ST，那么随着使用的纹理数目的增加，我们
会迅速占满顶点着色器中可以使用的插值寄存器。而很多时候，我们不需要对纹理进行平铺和位
移操作，或者很多纹理可以使用同一种平铺和位移操作，此时我们就可以对这些纹理使用同一个
变换后的纹理坐标进行采样。
（ 7）定义顶点着色器的输入和输出结构体：
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float2 uv : TEXCOORD0;
float3 lightDir: TEXCOORD1;
float3 viewDir : TEXCOORD2;
};
（8）在顶点着色器中，我们对光照方向和视角方向进行了坐标空间的变换，把它们从模型空
间变换到了切线空间中，以便在片元着色器中和法线进行光照运算：
v2f vert(a2v v) {
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
TANGENT_SPACE_ROTATION;
o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
o.viewDir = mul(rotation, ObjSpaceViewDir(v.vertex)).xyz;
return o;
}
（9）使用遮罩纹理的地方是片元着色器。我们使用它来控制模型表面的高光反射强度：
fixed4 frag(v2f i) : SV_Target {
fixed3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentViewDir = normalize(i.viewDir);
fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uv));
tangentNormal.xy *= _BumpScale;
tangentNormal.z = sqrt(1.0 - saturate(dot(tangentNormal.xy, tangentNormal.xy)));
fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
fixed3 halfDir = normalize(tangentLightDir + tangentViewDir);
// Get the mask value
fixed specularMask = tex2D(_SpecularMask, i.uv).r * _SpecularScale;
// Compute specular term with the specular mask
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(tangentNormal,
halfDir)), _Gloss) * specularMask;
return fixed4(ambient + diffuse + specular, 1.0);
}
环境光照和漫反射光照和之前使用过的代码完全一样。在计算高光反射时，我们首先对遮罩
纹理_SpecularMask 进行采样。由于本书使用的遮罩纹理中每个纹素的rgb 分量其实都是一样的，
表明了该点对应的高光反射强度，在这里我们选择使用r 分量来计算掩码值。然后，我们用得到
的掩码值和_SpecularScale 相乘，一起来控制高光反射的强度。
需要说明的是，我们使用的这张遮罩纹理其实有很多空间被浪费了—它的rgb 分量存储的
都是同一个值。在实际的游戏制作中，我们往往会充分利用遮罩纹理中的每一个颜色通道来存储
不同的表面属性，我们会在7.4.2 节中介绍这样一个例子。
（10）最后，我们为该Unity Shader 设置了合适的Fallback：
Fallback “Specular”
7.4.2 其他遮罩纹理
在真实的游戏制作过程中，遮罩纹理已经不止限于保护某些区域使它们免于某些修改，而是
可以存储任何我们希望逐像素控制的表面属性。通常，我们会充分利用一张纹理的RGBA 四个通
道，用于存储不同的属性。例如，我们可以把高光反射的强度存储在R 通道，把边缘光照的强度
存储在G 通道，把高光反射的指数部分存储在B 通道，最后把自发光强度存储在A 通道。
在游戏《DOTA 2》的开发中，开发人员为每个模型使用了4 张纹理：一张用于定义模型颜色，
一张用于定义表面法线，另外两张则都是遮罩纹理。这样，两张遮罩纹理提供了共8 种额外的表
面属性，这使得游戏中的人物材质自由度很强，可以支持很多高级的模型属性。读者可以在他们
的官网上找到关于《DOTA 2》的更加详细的制作资料，包括游戏中的人物模型、纹理以及制作手
册等。这是非常好的学习资料。
参考
Unity Shader入门精要
冯乐乐