Unity随记(六) 利用Camera.SetReplacementShader实现简单的场景击杀效果

先上效果图
2D版本：
在这里插入图片描述
3D版本：

小蓝在小红濒死状态下补上了致命一击，人物变成黑色剪影效果，场景配合变成黄白交替闪烁，再配合一个慢动作就是上面的这个简单的场景击杀效果(因为是战斗场景和人物同时做出一个整体的配合表现击杀的效果，暂时就取个这个名字吧~)

实现思路

在击杀时刻，调用SetReplacementShader方法，将人物的shader临时替换成黑色剪影效果的渲染方式，场景的shader替换成了黄白闪交替的渲染方式，当然这个替换shader的操作就是这个API内部的处理，我们要准备的就是实现自己想要的渲染效果即可。官方地址传送，官方给出的例子如下：

Shader "EffectShader" {
     SubShader {
         Tags { "RenderType"="Opaque" }
         Pass {
             ...
         }
     }
     SubShader {
         Tags { "RenderType"="SomethingElse" }
         Pass {
             ...
         }
     }
 ...
 }

调用方式：

void Start() {
    camera.SetReplacementShader (EffectShader, "RenderType");
}

官方的那个例子简洁明了，也是我第一次使用RenderType这个tag标签的地方，既然要让这个API来自动替换shader,当然得通知他一个替换的对应关系，才能达到我们的预期,官方这里使用的是RenderType这个关键字，这个API的效果就是把此相机（调用API的这个相机）所渲染的物体中查找RenderType这个tag的值，如果在这个EffectShader中的SubShader中找到与之匹配的，则将该SubShader替换匹配到的Shader,而没有匹配上的那部分则不可见。所以这里的EffectShader内部应该也是做了特殊的处理，猜测主要进行一个替换操作，而不是正常的执行，毕竟正常情况下一个Shader只有一个SubShader参与执行。

这里的第二个参数是用户自己传入的key，当然也可以自己定义了，或许不用RenderType可能对SetReplacementShader的理解更加容易些。

实现

准备好用于替换的shader，有两个SubShader,一个渲染黑色剪影，一个渲染场景的闪烁：

Shader "Hidden/KillEffect_2D"
{
	Properties
	{
		_MainTex("Texture", 2D) = "white" {}
	}

	SubShader
	{
		Tags { "BattleType" = "Scene" }
		Pass
		{
			CGPROGRAM
			#pragma vertex vert_2d
			#pragma fragment frag_2d_flash
			#include "UnityCG.cginc"
			#include "BattleKillSceneInclude.cginc"
			ENDCG
		}
	}

	SubShader
	{
		Tags { "BattleType" = "Army" }
		Pass
		{
			CGPROGRAM
			#pragma vertex vert_2d
			#pragma fragment frag_2d_black_army
			#include "UnityCG.cginc"
			#include "BattleKillSceneInclude.cginc"
			ENDCG
		}
	}
}

这里我使用的tag关键字是 BattleType来建立一个对应关系，我的人物渲染shader的tag：

Tags { "BattleType" = "Army" "LightMode" = "ForwardBase"}

场景物体的Tag:

Tags { "BattleType" = "Scene" "LightMode" = "ForwardBase"}

接下来就是在击杀时刻，C#调用Camera.SetReplacementShader进行替换操作即可：

 Shader killEffect = Shader.Find("Hidden/KillEffect");
 Time.timeScale = 0.15f;//慢动作
 Camera.main.SetReplacementShader(killEffect, "BattleType");
 yield return new WaitForSecondsRealtime(3);
 Time.timeScale = 1;
 //还原操作，恢复正常渲染
 Camera.main.ResetReplacementShader();

Shader效果部分

2D部分

黑色剪影，就简单的将color设为纯黑色即可，而黄白闪烁则直接使用单纯的颜色值返回即可，不用经过纹理采样的步骤（我的场景本来就没有用纹理。。。），代码如下

fixed4 frag_2d_flash(v2f i) : SV_Target
{
	half2 time = PerFun010(FLASH_COLOR_YELLOE_DURATION, FLASH_COLOR_WHITE_DURATION);
	if (time.y == 0)
	{
		return fixed4(FLASH_COLOR_YELLOE, 1);
	}
	else {
		return fixed4(FLASH_COLOR_WHITE, 1);
	}
}

这里的黄白交替的时间控制则是在PerFun010方法中，简单模拟一个周期性的线性变化：

// linear change 0 -> 1 -> 0...
inline half2 PerFun010(half T1, half T2)
{
	half T = T1 + T2;
	half x = fmod(_Time.y, T);
	int stepValue = step(T1, x);

	return half2((1 - stepValue) * x / T1 + stepValue * (1 - (x - T1) / T2), stepValue);
}

就是在T1和T2周期交替变换，经过T1的时间从0->1,再经过T2的时间从1->0,交替下去，返回值的x则表示具体变化值（比如0.3），而y表示在哪个阶段，T1阶段为0，T2阶段为1。这里效果因为只需要知道阶段即可，所以判断条件写的是

if (time.y == 0)

3D部分

要有3D的感觉，法线就是关键。在光照模型中的漫反射（diffuse）和高光（specular）都离不开法线（normal）。这里也是通过法线与光照方向的计算，叠加一点颜色上去体现一个3D的感觉，在Vert中，通过光照方向与法线进行Dot操作，再取Pow,类似于加了高光specular的处理：

v2f_3d vert_3d(appdata v)
{
	v2f_3d o;
	o.vertex = UnityObjectToClipPos(v.vertex);
	o.uv = TRANSFORM_TEX(v.uv, _MainTex);

	fixed3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
	fixed3 worldNormal = normalize(UnityObjectToWorldNormal(v.normal));
	fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
	o.specular = pow(abs(dot(worldLightDir, worldNormal)), 0.3h);
	return o;
}