参考：
https://blog.csdn.net/xiao2yizhizai/article/details/78189089
启动文件主要未完成如下工作，程序的执行过程：
—设置堆栈指针SP = __initial_sp
—设置PC指针 = Reset_Handler
—配置系统时钟
—软件设置SP
—加载.data,.bss.并初始化栈区
—跳转到C库中的__main,最终会调用（Call）用户程序的main()函数
程序在FLASH上的存储结构：
硬件复位后，CPU内的时序逻辑电路首先将0x08000000位置存放的堆栈栈顶地址装入SP寄存器；然后将0x08000000位置存放的向量地址装入PC程序计数器。CPU从PC寄存器指向物理地址取出第1条指令开始执行程序，也就是开始执行复位中断服务程序Reset_Handler。
复位中断服务程序会调用 SystemInit()函数(C 语言的) 来配置系统时钟、配置 FSMC 总线上的外部 SRAM，然后跳转到 C 库中__main 函数。由 C 库中的__main 函数完成用户程序的初始化工作（比如：变量赋初值等）， 后由__main 函数调用用户写的 main()函数开始执行 C 程序。
我们来看一下startup_stm32f40_41xxxx.s文件。
//此语句等价于#define Stack_Size 0x00000400
Stack_Size EQU 0x00000400
AREA STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem SPACE Stack_Size
__initial_sp
EQU 是表示宏定义的伪指令，类似于 C 语言中的#define。伪指令的意思是指这个“指令”并不会生成二进制程序代码，也不会引起变量空间分配。
0x00000400 表示堆栈大小，注意这里是以字节为单位。
开辟一段数据空间可读可写，段名 STACK，按照 8 字节对齐。
ARER 伪指令表示下面将开始定义一个代码段或者数据段。此处是定义数据段。ARER 后面的关键字表示这个段的属性。
STACK ：表示这个段的名字，可以任意命名。
NOINIT：表示此数据段不需要填入初始数据。
READWRITE：表示此段可读可写。
ALIGN=3 ：表示首地址按照 2 的 3 次方对齐，也就是按照 8 字节对齐。
SPACE 这行指令告诉汇编器给 STACK 段分配 0x0000400 字节的连续内存空间。
__initial_sp 只是一个标号。这里解释一下什么是标号，标号主要用于表示一片内存空间的某个位置，等价于 C 语言中的“地址”概念。地址仅仅表示存储空间的一个位置，从 C 语言的角度来看，变量的地址，数组的地址或是函数的入口地址在本质上并无区别。
__initial_sp 紧接着 SPACE 语句放置，表示了栈空间顶地址。M4 堆栈是由高地址空间向低地址空间增长的。压栈（PUSH）时，堆栈指针 SP 递减。弹栈（POP）时，SP 递增。栈（STACK）用于存储局部变量、保存函数返回地址。
; <h> Heap Configuration
; <o> Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
; </h>
Heap_Size EQU 0x00000200
AREA HEAP, NOINIT, READWRITE, ALIGN=3
__heap_base
Heap_Mem SPACE Heap_Size
__heap_limit
PRESERVE8
THUMB
分配一片连续的内存空间给名字叫 HEAP 的段，也就是分配堆空
间。堆的大小为 0x00000200。堆的首地址是 8 字节对齐。堆主要用于动态内存分配，也就是说用 malloc 函数分配的空间位于堆空间。
__heap_base 表示堆的开始地址。
__heap_limit 表示堆的结束地址。
PRESERVE8 指定当前文件保持堆栈八字节对齐。
THUMB 表示后面的指令是 THUMB 指令集 （CM4 采用的是 16 位 THUMB 指令集，这是相对于
ARM7，ARM9，ARM11 的 32 位的 ARM 指令集而言的）
; Vector Table Mapped to Address 0 at Reset
AREA RESET, DATA, READONLY
EXPORT __Vectors
EXPORT __Vectors_End
EXPORT __Vectors_Size
AREA 定义一块代码段，只读，段名字是 RESET。READONLY 表示只读，缺省就表示代码段了。
3 行 EXPORT 语句将 3 个标号申明为可被外部引用，主要提供给连接器用于连接库文件或其他其他文件。
__Vectors DCD __initial_sp ; Top of Stack
DCD Reset_Handler ; Reset Handler
DCD NMI_Handler ; NMI Handler
DCD HardFault_Handler ; Hard Fault Handler
DCD MemManage_Handler ; MPU Fault Handler
DCD BusFault_Handler ; Bus Fault Handler
DCD UsageFault_Handler ; Usage Fault Handler
······省略······
DCD DCMI_IRQHandler ; DCMI
DCD CRYP_IRQHandler ; CRYP crypto
DCD HASH_RNG_IRQHandler ; Hash and Rng
DCD FPU_IRQHandler ; FPU
__Vectors_End
__Vectors_Size EQU __Vectors_End - __Vectors
建立中断向量表，中断向量表定位在代码段的前面。具体的物理地址由连接器的配置参数（IROM1的地址）决定。如果程序在Flash 运行，则中断向量表的起始地址是0x08000000。
DCD 表示分配 1 个 4 字节的空间。每行 DCD都会生成一个 4 字节的二进制代码。中断向量表存放的实际上是中断服务程序的入口地址。当异常（也即是中断事件）发生时，CPU 的中断系统会将相应的入口地址赋值给 PC程序计数器，之后就开始执行中断服务程序。
AREA |.text|, CODE, READONLY
; Reset handler
Reset_Handler PROC
EXPORT Reset_Handler [WEAK]
IMPORT SystemInit
IMPORT __main
LDR R0, =SystemInit
BLX R0
LDR R0, =__main
BX R0
ENDP
… 下面是其他的中断服务程序 …
; Dummy Exception Handlers (infinite loops which can be modified)
NMI_Handler PROC
EXPORT NMI_Handler [WEAK]
B . <------ 死循环，用户可以自己编写中断服务程
ENDP
HardFault_Handler\
PROC
EXPORT HardFault_Handler [WEAK] B .
ENDP
… 中间的代码已省略 …
Default_Handler PROC <------ 缺省的中断服务程序（开始）
EXPORT WWDG_IRQHandler [WEAK]
EXPORT PVD_IRQHandler [WEAK]
… 中间的代码已省略 …
CRYP_IRQHandler
HASH_RNG_IRQHandler
FPU_IRQHandler
B . <------ 死循环
ENDP <------ 缺省的中断服务程序(结束)
汇编代码实现的中断服务程序，重点把这个复位中断服务程序说一下。
利用 PROC、ENDP这一对伪指令把程序段分为若干个过程，使程序的结构加清晰。
WEAK 声明其他的同名标号优先于该标号被引用,就是说如果外面声明了的话会调用外面的。这个申明很重要，它让我们可以在 C 文件中任意地方放置中断服务程序，只要保证 C 函数的名字和向量表中的名字一致即可。
IMPORT：伪指令用于通知编译器要使用的标号在其他的源文件中定义。但要在当前源文件中引用，而且无论当前源文件是否引用该标号，该标号均会被加入到当前源文件的符号表中。
SystemInit 函数在文件 system_stm32f4xx.c 里面，这个文件在下期教程有详细讲解。
这里重点说明一下__main标号，__main标号并不表示C程序中的main函数入口地址，因此LDR R0，=_main 也并不是跳转至 main 函数开始执行 C 程序。__main 标号表示 C/C++标准实时库函数里的一个初始化子程序__main 的入口地址。
__main该程序的一个主要作用是初始化堆栈（跳转__user_initial_stackheap标号进行初始化堆栈的，下面会讲到这个标号），并初始化映像文件，后跳转到 C 程序中的 main 函数。这就解释了为何所有的 C 程序必须有一个 main 函数作为程序的起点。因为这是由 C/C++标准实时库所规，并且不能更改。
;*******************************************************************************
; User Stack and Heap initialization
;*******************************************************************************
IF :DEF:__MICROLIB
EXPORT __initial_sp
EXPORT __heap_base
EXPORT __heap_limit
ELSE
IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap
__user_initial_stackheap
LDR R0, = Heap_Mem
LDR R1, =(Stack_Mem + Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR
ALIGN
ENDIF
END
;************************ (C) COPYRIGHT STMicroelectronics *****END OF FILE*****
汇编语言实现的IF…ELSE…语句，判断是否定义了使用了MICROLIB