采样图效果：
上面3幅图的效果分别是：原始Cubemap、世界空间下的采样、切线空间下的采样；
由以上对比图可知，在需要使用Cubemap 进行环境映射等情况下，我们就需要在世界空间下对Cubemap进行采样。
切线空间转换到世界空间的方法：
//世界空间下的法线、切线、副法线
float3 worldPos = mul(_Object2World, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
//构造切线空间到世界空间的旋转矩阵
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z); 模型空间转换到切线空间的方法：
//世界空间光源方向（指向光源）
float4 lightDirWorld = float4(normalize(_WorldSpaceLightPos0.xyz), 1);
//从世界空间到观察空间
float4 lightDirObj = mul(lightDirView, UNITY_MATRIX_IT_MV);
float4 lightDirView = mul(UNITY_MATRIX_V, lightDirWorld);
//从观察空间到模型空间
//rotation为模型空间到切线空间的旋转矩阵
TANGENT_SPACE_ROTATION;
//o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex));
o.lightDir = mul(rotation, lightDirObj);
//ObjectSpaceLightDir可以把光线方向转化到模型空间，然后通过rotation再转化到切线空间
//等同于上面的语句
//o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)); //方式二完整Shader代码如下：
Shader "Unity Shaders Book/Chapter 15/Water Wave" {
Properties {
_MainTex ("Base (RGB)", 2D) = "white" {}
_WaveMap ("Wave Map", 2D) = "bump" {}
_Cubemap ("Environment Cubemap", Cube) = "_Skybox" {}
_WaveXSpeed ("Wave Horizontal Speed", Range(-0.1, 0.1)) = 0.01
_WaveYSpeed ("Wave Vertical Speed", Range(-0.1, 0.1)) = 0.01
_Color ("Main Color", Color) = (0, 0.15, 0.115, 1)
}
SubShader {
// We must be transparent, so other objects are drawn before this one.
Tags { "Queue"="Transparent" "RenderType"="Opaque" }
Pass {
Tags { "LightMode"="ForwardBase" }
CGPROGRAM
#include "UnityCG.cginc"
#include "Lighting.cginc"
#pragma vertex vert
#pragma fragment frag
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _WaveMap;
float4 _WaveMap_ST;
samplerCUBE _Cubemap;
fixed _WaveXSpeed;
fixed _WaveYSpeed;
fixed4 _Color;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float4 uv : TEXCOORD1;
float4 TtoW0 : TEXCOORD2;
float4 TtoW1 : TEXCOORD3;
float4 TtoW2 : TEXCOORD4;
float3 lightDir : TEXCOORD5;
};
v2f vert(a2v v) {
v2f o;
o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
o.uv.zw = TRANSFORM_TEX(v.texcoord, _WaveMap);
//世界空间下的法线、切线、副法线
float3 worldPos = mul(_Object2World, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
//构造切线空间到世界空间的旋转矩阵
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
//世界空间光源方向（指向光源）
float4 lightDirWorld = float4(normalize(_WorldSpaceLightPos0.xyz), 1);
//从世界空间到观察空间
float4 lightDirView = mul(UNITY_MATRIX_V, lightDirWorld);
//从观察空间到模型空间
float4 lightDirObj = mul(lightDirView, UNITY_MATRIX_IT_MV);
//rotation为模型空间到切线空间的旋转矩阵
TANGENT_SPACE_ROTATION;
o.lightDir = mul(rotation, lightDirObj); //方式一
//ObjectSpaceLightDir可以把光线方向转化到模型空间，然后通过rotation再转化到切线空间
//等同于上面的语句
//o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)); //方式二
return o;
}
fixed4 frag(v2f i) : SV_Target {
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
// Get the normal in tangent space
fixed3 bump = UnpackNormal(tex2D(_WaveMap, i.uv.zw)).rgb;
float2 speed = _Time.y * float2(_WaveXSpeed, _WaveYSpeed);
fixed4 texColor = tex2D(_MainTex, i.uv.xy + speed);
// Convert the normal to world space
//世界空间下的反射光
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
fixed3 reflDir = reflect(-viewDir, bump);
fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * _Color.rgb;
//切线空间下的反射光
//fixed3 reflDir = reflect(-i.lightDir, bump);
//fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * _Color.rgb;
fixed3 finalColor = reflCol;
return fixed4(finalColor, 1);
}
ENDCG
}
}
// Do not cast shadow
FallBack Off
}
世界空间下和切线空间下的效果分别如下面上、下两幅图：
结论：在需要使用Cubemap 进行环境映射等情况下，我们就需要在世界空间下对Cubemap进行采样。
UnityShader之空间变换解析
我们都知道要渲染出一个物体，需要经历以下空间变换，
模型坐标(通常由美术决定)----->世界坐标----->观察空间(相机位置决定)------------>裁剪空间(相机类型和参数决定)------->投影
unity提供了一系列的矩阵来帮助用户进行坐标空间变换，这里列个表记录下：
1:模型空间 2:世界空间 3:观察空间 4:裁剪空间
UNITY_MATRIX_MVP：将坐标或者方向从1到4
UNITY_MATRIX_MV：将坐标或者方向从1到3
UNITY_MATRIX_VP：将坐标或者方向从2到4
UNITY_MATRIX_V：将坐标或者方向从2到3
UNITY_MATRIX_P：将坐标或者方向从3到4
unity_ObjectToWorld:将顶点或者方向从1到2
unity_WorldToObject:unity_ObjectToWorld的逆矩阵，用于将顶点方向从2到1
重点讲下
UNITY_MATRIX_IT_MV:专门用于将法线从模型空间变换到观察空间，为UNITY_MATRIX_MV的逆转置矩阵，如果UNITY_MATRIX_MV为正交矩阵(意味着只有旋转操作)，那么UNITY_MATRIX_MV就等于UNITY_MATRIX_IT_MV,如果有统一缩放操作，UNITY_MATRIX_IT_MV=(1/k)*UNITY_MATRIX_MV ,k为缩放系数((为什么不用UNITY_MATRIX_MV来处理法线，因为如果模型有不统一缩放的时候，用UNITY_MATRIX_MV会造成方向失真)，我也可以把这个矩阵转置一下或者UNITY_MATRIX_MV的逆矩阵，就可以把顶点或者方向矢量从观察空间变换到模型空间,例如
float4 modelPos = mul(transpose(UNITY_MATRIX_IT_MV),viewPos)=mul(viewPos,UNITY_MATRIX_IT_MV)；
UNITY_MATRIX_T_MV:UNITY_MATRIX_MV的转置矩阵，因为求一个矩阵的逆矩阵需要巨大的运算量，但是求一个矩阵的转置矩阵就很简单了，所以当一个矩阵为正交矩阵的时候，通过转置矩阵或者逆矩阵是一个很有用的方法，我们在计算一些方向矢量，不考虑平移操作，缩放系数设为1，这样就可以用这个矩阵来计算从观察空间到模型空间的方向矢量变换；