在前一章中，我们实现了基础的基于uv偏移的流动材质。
【unity shader】水体渲染基础-基于texture distortion的流体流动材质
但显然，在需要水体呈定向流动的时候，之前的方案就显得不那么真实了。
1.实现基础的uv定向偏移
直接取time，写一个函数让uv定向偏移，用偏移后的uv采样贴图即可。
float2 DirectionalFlowUV(float2 uv, float2 flowVector, float tilling, float time)
{
//实例的flowVector为（0,1）
uv.y -= time;
return uv * tilling;
}
想调整不同的角度，调整对应的flowVector。
float2 DirectionalFlowUV(float2 uv, float2 flowVector, float tilling, float time)
{
uv -= flowVector * time;
return uv * tilling;
}
1.1 实现uv旋转
当然，只是单纯的沿uv的xy方向做简单的偏移，不管怎么去组合不同的flowVector ，只能实现uv在不同方向上的平移，uv整体的效果依然保持与x方向平行。
要是想让uv整体实现偏移，我们最好在Photoshop或者sd里让贴图动一下
我们最好换一种uv的计算方法。
对于一张贴图上的采样点p来说，无论是对其uv做x，y方向上的变化（得到p1，p2），异或进行混合的线性变化（得到p3），最终的结果都只是实现了线性的平移而已，全部的uv会遵照同样的逻辑进行平移，最终变成整个贴图的平移。
所以我们需要实现的逻辑是，求解保持到原点的距离（即半径）的情况下，以原点为圆心进行特定角度旋转后的uv坐标。
这样，全部的坐标才能根据自身不同的半径，实现不同偏移量的旋转，从而实现整体贴图的旋转。
为展示通用的情况，我们这里拿掉挡住视线的贴图，让p点本身也带一定角度，而不是直接位于x轴上。
现在我们需要在默认旋转角为a度的p点，求解其再旋转b度的p’点的坐标s，t。
当然，OP和OP’的长度是一样的，都为r。
这里需要用到高中的三角函数拆分公式，我直接贴出。
对于s，t来说，其值为
s = r * cos(a + b)
t = r * sin(a + b)
对于x, y来说，其值为
x = r * cosa
y = r * sina
对s，t进行拆分
s = r * (cosa * cosb - sina * sinb)
t = r * (sina * cosb + cosa * sinb)
直接用x，y的值带入即可
s = x * cosb - y * sinb
t = y * cosb + x * sinb
所以我们就求解出了旋转后的坐标和旋转前的坐标，及角度的对应关系。
当旋转45度时，我们可以求得对应关系为
s = x * √2/2 - y * √2/2
t = x * √2/2 + y * √2/2
我们直接将其化归，就能够得到对应的float2x2矩阵
(1, 1)
(-1, 1)
用对应的矩阵去乘以原有的uv，就能够得到旋转45度后的uv值了。
注意这里unity默认的三角函数参数不是角度，而是弧度，要做转换。
float2 DirectionalFlowUV(float2 uv, float angle, float tilling, float time)
{
float2 uv2;
uv2.x = uv.x * cos(angle) - uv.y * sin(angle);
uv2.y = uv.x * sin(angle) + uv.y * cos(angle);
uv2 += time;
return uv2 * tilling;
}
接下来还要解决旋转后法线错误的问题。
我们直接将法线作为颜色输出，可以看到在无旋转情况下，法线显示正常。
但是在旋转90度后，法线的方向仍是朝y轴（即上图中蓝色的部分，在下图中仍为蓝色），则说明旋转90度后，法线仍是朝z轴方向，并没有完成旋转。
我们需要用旋转后的矩阵，同样对采样后的结果做旋转。
float2 dh2;
dh2.x = dh.x * cos(_Rotate) - dh.y * sin(_Rotate);
dh2.y = dh.x * sin(_Rotate) + dh.y * cos(_Rotate);
float3 worldNormal = normalize(float3(-dh2.x, 1, -dh2.y));
1.2 采样flowmap
虽然直接使用角度来控制是比较爽，但是为了使用flowmap提供的方向，我们还是得把对应的部分修改一下。
float2 DirectionalFlowUV(float2 uv,float3 flowVectorAndSpeed, float tilling, float time)
{
float2 uv2;
float2 dir = normalize(flowVectorAndSpeed.xy);
uv2.x = uv.x * dir.x - uv.y * dir.y;
uv2.y = uv.x * dir.y + uv.y * dir.x;
uv2 += time * flowVectorAndSpeed;
return uv2 * tilling;
}
但是直接采样的结果显然非常杂乱，各个坐标的旋转角度都不一致，由于非线性变化的引入，导致效果完全没有连续性。
2. 实现旋转+tiled flow
我们在处理平移的uv扭曲的方案中，主要是采取了两种存在时间差的uv来进行采样，然后对采样的结果进行混合。但这是由于frac函数本身存在重置的周期，而旋转变化无法单纯通过时间处理来解决过度扭曲问题。
由于无法统筹处理整个平面，我们把平面划分为多个区域，使每个区域内呈相同的流动方向，让区域间进行混合，以实现连续性。这种方法就是Frans van Hoesel提出的Tiled Directional Flow算法。
2.1 实现阶梯采样
增加一个基于整形参数_GridResolution的阶梯函数，使对应的uv呈阶梯变化。
float2 tiledUV = floor(i.uv * _GridResolution) / _GridResolution;
float3 flow = tex2D(_FlowMap, tiledUV);
由于同一阶梯内的uv一致，我们就能得到按方格切分好的平面，并且单个方格内的uv呈单向变化。
2.2 混合多个方格
首先我们先把已有的阶梯采样，和旋转的计算封装为方法，从fs中独立出来。
float3 FlowCell(float2 uv, float time)
{
float2 uvTiled = floor(uv * _GridResolution) / _GridResolution;
float3 flow = tex2D(_FlowMap, uvTiled);
flow.xy = flow.xy * 2 -1;
float2 uvFlow = DirectionalFlowUV(uv, flow, _Tiling, time);
float3 dh = UnpackDerivativeHeight(tex2D(_MainTex, uvFlow));
float3 dh2;
float2 dir = normalize(flow.xy);
dh2.x = dh.x * dir.x - dh.y * dir.y;
dh2.y = dh.x * dir.y + dh.y * dir.x;
dh2.z = dh.z;
return dh2;
}
fixed4 frag (v2f i) : SV_Target
{
float flowTime = _Time.y;
float3 dh = FlowCell(i.uv, flowTime);
float3 worldNormal = normalize(float3(-dh.x, 1, -dh.y));
fixed3 col = dh.z * dh.z * _Color;
fixed3 diffuse = _LightColor0 * dot(_WorldSpaceLightPos0, worldNormal);
return fixed4(col.xyz + diffuse, 1.0);
}
实现偏移采样也很简单，增加一个二维浮点数offset作为参数，在阶梯采样的时候加入，就能采到相邻阶梯的信息了。
float3 FlowCell(float2 uv, float2 offset, float time)
{
float2 uvTiled = floor(uv * _GridResolution + offset) / _GridResolution;
//..........
}
我们直接做一个双采样，然后均值混合。
//in fragment shader
float3 dhA = FlowCell(i.uv, float2(0, 0), flowTime);
float3 dhB = FlowCell(i.uv, float2(1, 0), flowTime);
float3 dh = 0.5 * dhA + 0.5 * dhB;
可以看到在u（x）方向上，显然不连续问题已经得到了一些改善。
为了保证混合效果，我们采用一种动态权重的混合方法，以小数函数frac来获取单个单元格内的uv变化，根据u值的不同，来分配混合权重。
float t = frac(i.uv.x * _GridResolution);
float wA = 1 - t;
float wB = t;
float3 dh = wA * dhA + wB * dhB;
但现在可以看到每个单元格中间仍然有间隙，这是由于t的跳变导致的。
一方面，我们压缩偏移量，使得单个单元格能发生两次偏移。
float3 FlowCell(float2 uv, float2 offset, float time)
{
offset *= 0.5;
//.............
}
另一方面，对于权重的计算，变化幅度也要加倍，来匹配每个方格的两次跳变。
float t = abs(2 * frac(i.uv.x * _GridResolution) - 1);
// float t = frac(i.uv.x * _GridResolution);
float wA = 1 - t;
float wB = t;
接下来我们对v方向上做偏移采样。
注意这里是对四个不同的区块做采样混合，而不是做只针对0,0块的直接相邻块做采样混合。
float3 dhA = FlowCell(i.uv, float2(0, 0), flowTime);
float3 dhB = FlowCell(i.uv, float2(1, 0), flowTime);
float3 dhC = FlowCell(i.uv, float2(0, 1), flowTime);
float3 dhD = FlowCell(i.uv, float2(1, 1), flowTime);
float2 t = abs(2 * frac(i.uv * _GridResolution) - 1);
// float t = frac(i.uv.x * _GridResolution);
float wA = (1 - t.x) * (1 - t.y);
float wB = t.x * (1 - t.y);
float wC = (1 - t.x) * t.y;
float wD = t.x * t.y;
float3 dh = wA * dhA + wB * dhB + wC * dhC + wD * dhD;
至此，已经实现了uv旋转融合，但仔细观察，依然存在依稀的网格感，特别是水平方向上的。
我们需要移动floor的结果，使其位于每个单元格的中间。
float3 FlowCell(float2 uv, float2 offset, float time)
{
float shift = 1 - offset;
offset *= 0.5;
shift *= 0.5;
float2 uvTiled = (floor(uv * _GridResolution + offset) + shift) / _GridResolution;
//..........
}
我们可以调整tilling和_gridResolution来获取不同的效果，但注意_gridResolution不能调整的过大。
2.3 补充其他控制参数
现在把其他的参数也一起加上。
动态调整法线强度(浪高）
//in FlowCell function
dh2 *= flow.z * _HeightScaleModulated + _HeightScale;
给tilling增加flowmap的噪音
//in FlowCell function
float tilling = flow.z * _TilingModulated + _Tiling;
float2 uvFlow = DirectionalFlowUV(uv, flow, tilling, time);
我们可以添加一个控制uvtiling缩放的参数，在采样范围控制在flowmap的较小范围内时，整体会呈现一个相对定向的流动
_UvTilingScale("uv tiling scale", Range(0.1, 1)) = 1
//in FlowCell function
float3 flow = tex2D(_FlowMap, uvTiled * _UvTilingScale);
我个人比较喜欢低_UvTilingScale下的感觉哈。
在_gridResolution太小时，依然会出现瑕疵。
2.4 实现低_gridResolution的混合
那么问题来了，右侧这边模糊了，但是左侧的计算结果比较清晰，我们该怎么办呢？
答案也很简单，把左边的结果偏移一下，跟右边的结果混合就能一定程度上缓解了。
对应来说，就是给uv再加1/4个偏移（先前已经偏移过1/2了）。同时，我们把四个区块混合的方法分离出来。
float3 FlowCell(float2 uv, float2 offset, float time, bool gridOffsetTag)
{
float shift = 1 - offset;
offset *= 0.5;
shift *= 0.5;
if(gridOffsetTag)
{
offset += 0.25;
shift -= 0.25;
}
//........
}
float3 FlowGrid(float2 uv, float flowTime, bool gridOffsetTag)
{
float3 dhA = FlowCell(uv, float2(0, 0), flowTime, gridOffsetTag);
float3 dhB = FlowCell(uv, float2(1, 0), flowTime, gridOffsetTag);
float3 dhC = FlowCell(uv, float2(0, 1), flowTime, gridOffsetTag);
float3 dhD = FlowCell(uv, float2(1, 1), flowTime, gridOffsetTag);
float2 t = uv * _GridResolution;
if(gridOffsetTag)
{
t += 0.25;
}
t = abs(2 * frac(t) - 1);
// float t = frac(i.uv.x * _GridResolution);
float wA = (1 - t.x) * (1 - t.y);
float wB = t.x * (1 - t.y);
float wC = (1 - t.x) * t.y;
float wD = t.x * t.y;
float3 dh = wA * dhA + wB * dhB + wC * dhC + wD * dhD;
return dh;
}
//in fs
float3 dh = FlowGrid(i.uv, flowTime, false);
dh = (dh + FlowGrid(i.uv, flowTime, true)) * 0.5;
混合前（左） 混合后（右）
