S3C2440时钟体系的简单编程
编程目的：
使FCLK=400MHZ
HCLK=100MHZ
PCLK=50MHZ
步骤：
1.设置MPLLCON寄存器使FCLK=400MHZ
2.设置CLKDIVN寄存器使HCLK=FCLK/4并且使PCLK=FCLK/8从而得到HCLK=100MHZ,PCLK=50MHZ
下面是寄存器的配置手册：
可以看到手册上写道当HDIVN的2：1置为10的时候HCLK=FCLK/4，但是他有个前提条件就是CAMDIVN[9]=0；通过查找手册，CAMDIVN[9]的默认值为0，这里我们就不需要去管他。再往下看，当CLKDIVN的0位为1的时候PCLK=HCLK/2。
即:
CLKDIVN[2:1]=0100
CLKDIVN[0] =0001
CLKDIVN=0101=0X5
接着我们来设置MPLL的时钟:
我们来看到手册：
当晶振为12M的时候要想设置400MHZ的速率
需置
MDIV=92
PDIV=1
SDIV=1
在手册上面也有一条计算公式：
换算好后即为：
*MPLL=（2（MDIV+8）FIN）/((PDIV+2)2^SDIV)
FIN=晶振频率
由此可得我们应该这样设置寄存器：
**PLLCON=(92<<12)|(1<<4)|(1<<0)**即可达到我们的目的：
设置完寄存器后记得查看手册是否有注意事项。
下面我们就可以开始写代码了：
代码如下
.text
.global _start
_start:
/* 关闭看门狗 */
ldr r0, =0x53000000
ldr r1, =0
str r1, [r0]
/* 设置MPLL, FCLK : HCLK : PCLK = 400m : 100m : 50m */
/* LOCKTIME(0x4C000000) = 0xFFFFFFFF */
ldr r0, =0x4C000000
ldr r1, =0xFFFFFFFF
str r1, [r0]
/* CLKDIVN(0x4C000014) = 0X5, tFCLK:tHCLK:tPCLK = 1:4:8 */
ldr r0, =0x4C000014
ldr r1, =0x5
str r1, [r0]
/* 设置CPU工作于异步模式 */
mrc p15,0,r0,c1,c0,0
orr r0,r0,#0xc0000000 //R1_nF:OR:R1_iA
mcr p15,0,r0,c1,c0,0
/* 设置MPLLCON(0x4C000004) = (92<<12)|(1<<4)|(1<<0)
* m = MDIV+8 = 92+8=100
* p = PDIV+2 = 1+2 = 3
* s = SDIV = 1
* FCLK = 2*m*Fin/(p*2^s) = 2*100*12/(3*2^1)=400M
*/
ldr r0, =0x4C000004
ldr r1, =(92<<12)|(1<<4)|(1<<0)
str r1, [r0]
/* 一旦设置PLL, 就会锁定lock time直到PLL输出稳定
* 然后CPU工作于新的频率FCLK
*/
/* 设置内存: sp 栈 */
/* 分辨是nor/nand启动
* 写0到0地址, 再读出来
* 如果得到0, 表示0地址上的内容被修改了, 它对应ram, 这就是nand启动
* 否则就是nor启动
*/
mov r1, #0
ldr r0, [r1] /* 读出原来的值备份 */
str r1, [r1] /* 0->[0] */
ldr r2, [r1] /* r2=[0] */
cmp r1, r2 /* r1==r2? 如果相等表示是NAND启动 */
ldr sp, =0x40000000+4096 /* 先假设是nor启动 */
moveq sp, #4096 /* nand启动 */
streq r0, [r1] /* 恢复原来的值 */
bl main
halt:
b halt