shader 兰伯特光照模型

基于顶点的

Shader "MyShader/Diffuse"
{
	Properties
	{
		_Diffuse("diffuse",Color) = (1,1,1,1)
	}
		SubShader
	{
		Tags { "RenderType" = "Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag

			#include "UnityCG.cginc"
			#include "UnityLightingCommon.cginc"

		   float4 _Diffuse;
			struct v2f
			{
				float4 vertex:SV_POSITION;
				fixed3 color : Color;
			};

            v2f vert (appdata_base v)
            {
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				float3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
				float3 worldNormal = UnityObjectToWorldNormal(v.normal);
				float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				float3 diffuse = _LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal, worldLight));
				o.color = diffuse + ambient;
				return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
				return fixed4(i.color,1);
            }
            ENDCG
        }
    }
}

基于片元的

Shader "MyShader/Diffuse2"
{
	Properties
	{
		_Diffuse("diffuse",Color) = (1,1,1,1)
	}
		SubShader
	{
		Tags { "RenderType" = "Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag


			#include "UnityCG.cginc"
			#include "UnityLightingCommon.cginc"

			fixed4 _Diffuse;

			struct v2f
			{
				float4 vertex:SV_POSITION;
				float3 worldNormal:NORMAL;
			};

            v2f vert (appdata_base v)
            {
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
				float3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
				float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				float3 diffuse = _Diffuse.rgb*_LightColor0.rgb*saturate(dot(worldLight, i.worldNormal));
				float3 temp = diffuse + ambient;
				return fixed4(temp, 1);
            }
            ENDCG
        }
    }
}

半兰伯特光照模型

Shader "MyShader/Diffuse2"
{
	Properties
	{
		_Diffuse("diffuse",Color) = (1,1,1,1)
	}
		SubShader
	{
		Tags { "RenderType" = "Opaque" }
		LOD 100

		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag


			#include "UnityCG.cginc"
			#include "UnityLightingCommon.cginc"

			fixed4 _Diffuse;

			struct v2f
			{
				float4 vertex:SV_POSITION;
				float3 worldNormal:NORMAL;
			};

			v2f vert(appdata_base v)
			{
				v2f o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				return o;
			}

			fixed4 frag(v2f i) : SV_Target
			{
				float3 ambient = UNITY_LIGHTMODEL_AMBIENT.rgb;
				float3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
				float3 diffuse = _Diffuse.rgb*_LightColor0.rgb*(dot(worldLight, i.worldNormal)*0.5+0.5);
				float3 temp = diffuse + ambient;
				return fixed4(temp, 1);
			}
			ENDCG
		}
	}
}

半兰伯特光照模型能使阴暗的部分亮一些，效果更佳。