SAP 提供Rest Wep 服务之路径

转载来自：

https://blog.csdn.net/stone0823/article/details/81661261

Restfu Web 服务的四个状态：GET ,POST ,PUT, DELETE 和路径的关系

创建的步骤就不再说了，在上个Blog中已经提到了

创建自定义表 ZEMPLOYEE 作为数据传输的载体

创建自定义类 ZCL_EMP_HANDLER 配个接口 IF_HTTP_EXTENSION

方法：IF_HTTP_EXTENSION~HANDLE_REQUEST

METHOD if_http_extension~handle_request.

  DATA: lv_verb TYPE string,
        path TYPE string,
        path_info TYPE string,
        params TYPE string.

  DATA: lt_employee TYPE STANDARD TABLE OF zemployee,
        ls_employee LIKE LINE OF lt_employee.

  DATA: req_json TYPE string.

  DATA: serializer TYPE REF TO zcl_trex_json_serializer,
        deserializer TYPE REF TO zcl_trex_json_deserializer,
        lv_json TYPE string.

  DATA: result_tab TYPE match_result_tab ,
        wa         LIKE LINE OF result_tab.

  lv_verb = server->request->get_header_field( '~request_method' ) .
  path = server->request->get_header_field( '~request_uri' ).
  SPLIT path AT '?' INTO path_info params. "分解服务地址

* POST http Method
* list all employees
  IF lv_verb = 'GET' AND path_info = '/sap/bc/ztst_emp'.
    SELECT * FROM zemployee INTO TABLE lt_employee.

    CREATE OBJECT serializer
      EXPORTING DATA = lt_employee[].
    CALL METHOD serializer->serialize( ).
    lv_json = serializer->get_data( ).

    server->response->set_status( code = 200 reason = 'Ok' ).
    server->response->set_content_type( 'application/json' ).
    server->response->set_cdata( data = lv_json ).

  ENDIF.

* POST http method: create new employee
  IF lv_verb = 'POST' AND path_info = '/sap/bc/ztst_emp'.
    req_json = server->request->get_cdata( ).

    CLEAR ls_employee.
    CREATE OBJECT deserializer.
    CALL METHOD deserializer->deserialize(
      EXPORTING json = req_json
      IMPORTING abap = ls_employee ).

    MODIFY zemployee FROM ls_employee.

    server->response->set_status( code = 201 reason = 'Employee created successfully.' ).
  ENDIF.

* PUT http method: modify employee
  IF lv_verb = 'PUT'.
    REFRESH result_tab.
    FIND ALL OCCURRENCES OF REGEX '/sap/bc/ztst_emp/\d+' IN path_info RESULTS result_tab. 

    IF NOT result_tab IS INITIAL.
      req_json = server->request->get_cdata( ).

      CLEAR ls_employee.
      CREATE OBJECT deserializer.
      CALL METHOD deserializer->deserialize(
        EXPORTING json = req_json
        IMPORTING abap = ls_employee ).

      MODIFY zemployee FROM ls_employee.

      server->response->set_status( code = 200 reason = 'Employee updated successfully.' ).
    ENDIF.
  ENDIF.

* DELETE http method: delete employee
  IF lv_verb = 'DELETE'.
    REFRESH result_tab.
    FIND ALL OCCURRENCES OF REGEX '/sap/bc/ztst_emp/\d+' IN path_info RESULTS result_tab. " d代表emp_id的值

    IF NOT result_tab IS INITIAL.
      DATA: f1 TYPE string,
            f2 TYPE string,
            f3 TYPE string,
            f4 TYPE string,
            emp_id TYPE string.
      CLEAR wa.
      READ TABLE result_tab INTO wa INDEX 1.
      path_info = path_info+wa-offset(wa-length) .
      SPLIT path_info AT '/' INTO f1 f2 f3 f4 emp_id.

      DELETE FROM zemployee WHERE empid = emp_id.

      server->response->set_status( code = 204 reason = 'Employee deleted successfully.' ).
    ENDIF.
  ENDIF.

ENDMETHOD.

在SICF 中配置一个服务 ztst_emp