Flash 3D引擎（Sandy3D）应用指南 4——在3D场景中移动物品。

原文地址：http://www.flashsandy.org/tutorials/3.0/sandy_cs3_tut04

本指南的目标

在这里，我们将学到怎么去移动物品。

在之前的指南中，我们看到怎么去移动摄像机实现物品移动的效果。但这些物品实际上依然放在它们原来的位置。我们现在想移动这些物品！

你可以在屏幕上移动一个物品或一组包含一个或多个对象的物品。要移动一个对象，你首先要有它的一个引用，你可以通过这个对象的rotateX、rotateY、rotateZ属性围挠三个坐标轴旋转它。使用 pan、roll和tilt属性来围挠它自身的坐标轴来旋转。如果你想移动一组对像，你需要引入一个叫TransformGroup的新类。无需惊奇，它只是一个实现了ATransformable接口的组(Group)，所以我们可以像一般对象好样移动它。

在这个指南，我们将要画两个对象。我们将会看到移动一个对象和移动整组对象的区别。

怎么做？

在fla文件中，把文档类（Document class）设置为Example004.as 。

代码下载：example004.rar

AS 代码如下：

在这里我们先看看完整的代码，在后面的段落将解释这些代码。

package {
   import flash.display.Sprite; 
   import flash.events.*;
   import flash.ui.*;
   import sandy.core.Scene3D;
   import sandy.core.data.*;
   import sandy.core.scenegraph.*;
   import sandy.materials.*;
   import sandy.materials.attributes.*;
   import sandy.primitive.*;
 
   public class Example004 extends Sprite {
      private var scene:Scene3D;
      private var camera:Camera3D;
      private var tg:TransformGroup;
      private var myCone:Cone;
      private var myHedra:Hedra;
 
      public function Example004() { 
         camera = new Camera3D( 300, 300 );
         camera.x = 100;
         camera.y = 100;
         camera.z = -400;
         camera.lookAt(0,0,0);
 
         var root:Group = createScene();
 
         scene = new Scene3D( "scene", this, camera, root );
 
         addEventListener( Event.ENTER_FRAME, enterFrameHandler );
         stage.addEventListener(KeyboardEvent.KEY_DOWN, keyPressed);
      }
 
      private function createScene():Group {
         var g:Group = new Group();
 
         var myXLine:Line3D = new Line3D( "x-coord", new Vector(-50, 0, 0), new Vector( 50, 0, 0 ));
         var myYLine:Line3D = new Line3D( "y-coord", new Vector(0, -50, 0), new Vector( 0, 50, 0 ));
         var myZLine:Line3D = new Line3D( "z-coord", new Vector(0, 0, -50), new Vector( 0, 0, 50 ));
 
         tg = new TransformGroup('myGroup');
 
         myCone = new Cone("theObj1",50, 100);
         myHedra = new Hedra( "theObj2", 80, 60, 60 );
 
         myCone.x = -160;
         myCone.z = 150;
         myHedra.x = 90;
 
         var materialAttr:MaterialAttributes = new MaterialAttributes( 
                              new LineAttributes( 0.5, 0x2111BB, 0.4 ),
                              new LightAttributes( true, 0.1)
                        );
 
         var material:Material = new ColorMaterial( 0xFFCC33, 1, materialAttr );
         material.lightingEnable = true;
         var app:Appearance = new Appearance( material );
 
         myCone.appearance = app;
         myHedra.appearance = app;
 
         tg.addChild(myCone);
         tg.addChild(myHedra);
 
         g.addChild(tg);
         g.addChild(myXLine);
         g.addChild(myYLine);
         g.addChild(myZLine);
 
         return g;
      }
 
      private function enterFrameHandler( event : Event ) : void {
         myHedra.pan +=4;
         myCone.pan +=4;
         scene.render();
      }
 
      private function keyPressed(event:KeyboardEvent):void {
         switch(event.keyCode) {
            case Keyboard.UP:
               tg.y +=2;
               break;
            case Keyboard.DOWN:
               tg.y -=2;
               break;
            case Keyboard.RIGHT:
               tg.roll +=2;
               break;
            case Keyboard.LEFT:
               tg.roll -=2;
               break;
         }
      }
   }
}

查看代码

让我们看看我们在代码里做了什么。

声明我们需要的对象

首先我们必需定义三个私有的变量：

private var tg:TransformGroup;
private var myCone:Cone;
private var myHedra:Hedra;

这让我们可以在这个类的任何地方引用这些变量。可能这样做不是最好的方法，但它很简单、快速同时让我们可以更好地解释代码。

创建TransformGroup

下一步，我们在createScene()方法里实例化了TransformGroup类。

tg = new TransformGroup('myGroup');

这个TransformGroup将用来维持两个元素：一个圆锥体和一个多面体（Hedra）。

实例化和放置对象

现在我们创建两个新的对象并把让它们分开放置。

myCone = new Cone("theObj1",50, 100);
myHedra = new Hedra( "theObj2", 80, 60, 60 );

myCone.x = -160;
myCone.z = 150;
myHedra.x = 90;

增加Appearance

一定要记住为每个你创建的对象设置appearance属性。

myCone.appearance = app;
myHedra.appearance = app;

把对象加入到TransformGroup

现在我们把这两个对象加入到Transform group，这样我们就有了一个让我们可以移动的“节点”的引用。

tg.addChild(myCone);
tg.addChild(myHedra);

把所有剩余的对象加入到根组（main group）

g.addChild(tg);
g.addChild(myXLine);
g.addChild(myYLine);
g.addChild(myZLine);

记住，我们需要增加我们刚才创建的TransformGroup和三条直线。但不要加入那两个已经加入到TransformGroup的对象。

处理 enterFrame 事件

让我们看看有两个事件处理函数里做了什么

在 enterFrameHandler 函数里，我们决定展示如果直接获取单个对像，我们单独旋转每一个独立的对象。

myHedra.pan +=4;
myCone.pan +=4;
scene.render();

处理键盘输入事件

在 keyPressed 函数中，我想展示怎么样获取整个组来移动里面的两个对象。

switch(event.keyCode) {
   case Keyboard.UP:
      tg.y +=2;
      break;
   case Keyboard.DOWN:
      tg.y -=2;
      break;
   case Keyboard.RIGHT:
      tg.roll +=2;
      break;
   case Keyboard.LEFT:
      tg.roll -=2;
      break;
}

现在让我们看看最终结果：http://www.flashsandy.org/_media/tutorials/3.0/example004.swf

Flash 3D引擎（Sandy3D）应用指南 4——在3D场景中移动物品。

猜你喜欢