Unity ShaderLab开发实战（五）边缘光RimColor

参考：https://blog.csdn.net/puppet_master/article/details/53548134

RimColor：边缘发光效果。效果如下图（图片资源也是参考文章里的）：

        边缘很简单，法线和视线越垂直就是边缘，简单原理如下图：

       那边缘发光效果就是希望在边缘处额外加一个光的效果。我们可以根据dot（N,V）来获得视线方向与法线方向的余弦值，通过这个值来区分该像素是否处在边缘，进而判断是否需要增加以及增加边缘光的强弱。

        下面我采用兰伯特光照模型，简单介绍一下Lambert模型：模型表面的明亮度直接取决于光线向量（light vector）和表面法线（normal）两个向量将夹角的余弦值。光线向量是指这个点到光从哪个方向射入，表面法线则定义了这个表面的朝向。

1.在个茶壶上实现效果：

实现代码：

Shader "Custom/RimColor" {
    //属性
    Properties{
        _Diffuse("Diffuse", Color) = (1,1,1,1)
        _RimColor("RimColor", Color) = (1,1,1,1)
        _RimPower("RimPower", Range(0.000001, 3.0)) = 0.1
        _MainTex("Base 2D", 2D) = "white"{}
    }
 
    //子着色器    
    SubShader
    {
        Pass
        {
            //定义Tags
            Tags{ "RenderType" = "Opaque" }
 
            CGPROGRAM
            //引入头文件
            #include "Lighting.cginc"
            //定义Properties中的变量
            fixed4 _Diffuse;
            sampler2D _MainTex;
            //使用了TRANSFROM_TEX宏就需要定义XXX_ST
            float4 _MainTex_ST;
            fixed4 _RimColor;
            float _RimPower;
 
            //定义结构体：vertex shader阶段输出的内容
            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float2 uv : TEXCOORD1;
                //在vertex shader中计算观察方向传递给fragment shader
                float3 worldViewDir : TEXCOORD2;
            };
 
            //定义顶点shader,参数直接使用appdata_base（包含position, noramal, texcoord）
            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                //通过TRANSFORM_TEX宏转化纹理坐标，主要处理了Offset和Tiling的改变,默认时等同于o.uv = v.texcoord.xy;
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.worldNormal = mul(v.normal, (float3x3)_World2Object);
                //顶点转化到世界空间
                float3 worldPos = mul(_Object2World, v.vertex).xyz;
                //可以把计算计算ViewDir的操作放在vertex shader阶段，毕竟逐顶点计算比较省
                o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;
                return o;
            }
 
            //定义片元shader
            fixed4 frag(v2f i) : SV_Target
            {
                //unity自身的diffuse也是带了环境光，这里我们也增加一下环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;
                //归一化法线，即使在vert归一化也不行，从vert到frag阶段有差值处理，传入的法线方向并不是vertex shader直接传出的
                fixed3 worldNormal = normalize(i.worldNormal);
                //把光照方向归一化
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                //根据半兰伯特模型计算像素的光照信息
                fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
                //最终输出颜色为lambert光强*材质diffuse颜色*光颜色
                fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;
                //进行纹理采样
                fixed4 color = tex2D(_MainTex, i.uv);
                
                //以下为本篇主题：计算RimLight
                //把视线方向归一化
                float3 worldViewDir = normalize(i.worldViewDir);
                //计算视线方向与法线方向的夹角，夹角越大，dot值越接近0，说明视线方向越偏离该点，也就是平视，该点越接近边缘
                float rim = 1 - max(0, dot(worldViewDir, worldNormal));
                //计算rimLight
                fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);
                //输出颜色+边缘光颜色
                color.rgb = color.rgb* diffuse + rimColor;
                
                return fixed4(color);
            }
 
            //使用vert函数和frag函数
            #pragma vertex vert
            #pragma fragment frag    
 
            ENDCG
        }
    }
    //前面的Shader失效的话，使用默认的Diffuse
    FallBack "Diffuse"
}

2.如果只希望部分有自发光效果，而其他部分没有自发光，我们就需要用Mask图来控制了，我们用一张Alpha8的灰度图来控制是否开启边缘光效果，将上面的shader简单修改一下，增加Mask图的通道：

Shader "ApcShader/RimLight"
{
    //属性
    Properties{
        _Diffuse("Diffuse", Color) = (1,1,1,1)
        _RimColor("RimColor", Color) = (1,1,1,1)
        _RimPower("RimPower", Range(0.000001, 20.0)) = 0.1
        _RimMask("RimMask", 2D) = "white"{}
        _MainTex("Base 2D", 2D) = "white"{}
    }
 
    //子着色器    
    SubShader
    {
        Pass
        {
            //定义Tags
            Tags{ "RenderType" = "Opaque" }
 
            CGPROGRAM
            //引入头文件
            #include "Lighting.cginc"
            //定义Properties中的变量
            fixed4 _Diffuse;
            sampler2D _MainTex;
            //使用了TRANSFROM_TEX宏就需要定义XXX_ST
            float4 _MainTex_ST;
            sampler2D _RimMask;
            fixed4 _RimColor;
            float _RimPower;
 
            //定义结构体：vertex shader阶段输出的内容
            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float2 uv : TEXCOORD1;
                //在vertex shader中计算观察方向传递给fragment shader
                float3 worldViewDir : TEXCOORD2;
            };
 
            //定义顶点shader,参数直接使用appdata_base（包含position, noramal, texcoord）
            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                //通过TRANSFORM_TEX宏转化纹理坐标，主要处理了Offset和Tiling的改变,默认时等同于o.uv = v.texcoord.xy;
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.worldNormal = mul(v.normal, (float3x3)_World2Object);
                //顶点转化到世界空间
                float3 worldPos = mul(_Object2World, v.vertex).xyz;
                //可以把计算计算ViewDir的操作放在vertex shader阶段，毕竟逐顶点计算比较省
                o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;
                return o;
            }
 
            //定义片元shader
            fixed4 frag(v2f i) : SV_Target
            {
                //unity自身的diffuse也是带了环境光，这里我们也增加一下环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;
                //归一化法线，即使在vert归一化也不行，从vert到frag阶段有差值处理，传入的法线方向并不是vertex shader直接传出的
                fixed3 worldNormal = normalize(i.worldNormal);
                //把光照方向归一化
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                //根据半兰伯特模型计算像素的光照信息
                fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
                //最终输出颜色为lambert光强*材质diffuse颜色*光颜色
                fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;
                //进行纹理采样
                fixed4 color = tex2D(_MainTex, i.uv);
                
                //以下为本篇主题：计算RimLight
                //把视线方向归一化
                float3 worldViewDir = normalize(i.worldViewDir);
                //计算视线方向与法线方向的夹角，夹角越大，dot值越接近0，说明视线方向越偏离该点，也就是平视，该点越接近边缘
                float rim = 1 - max(0, dot(worldViewDir, worldNormal));
                //计算RimLight
                fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);
                //通过RimMask控制是否有边缘光,Rim目前存在一张Alpha8类型的图片中
                fixed rimMask = tex2D(_RimMask, i.uv).a;
                //输出颜色+边缘光颜色
                color.rgb = color.rgb* diffuse + rimColor * (1 - rimMask);
                
                return fixed4(color);
            }
 
            //使用vert函数和frag函数
            #pragma vertex vert
            #pragma fragment frag    
 
            ENDCG
        }
    }
    //前面的Shader失效的话，使用默认的Diffuse
    FallBack "Diffuse"

}

3.动态RimColor效果

用一张Mask纹理，白色代表有边缘光，黑色无边缘光，通过采样这张Mask纹理，控制模型上显示边缘光的部分：

效果：（自己随便做的，有参数可以调，大家可以发挥自己的想象，eg：火山喷发等等）

代码：

Shader "Custom/RimColor" {
    //属性
    Properties{
        _Diffuse("Diffuse", Color) = (1,1,1,1)
        _RimColor("RimColor", Color) = (1,1,1,1)
        _RimPower("RimPower", Range(0.000001, 20.0)) = 0.1
        _RimMask("RimMask", 2D) = "white"{}
        _MainTex("Base 2D", 2D) = "white"{}
        _RimSpeed("RimSpeed", Range(-10, 10)) = 1.0
    }
 
    //子着色器    
    SubShader
    {
        Pass
        {
            //定义Tags
            Tags{ "RenderType" = "Opaque" }
 
            CGPROGRAM
            //引入头文件
            #include "Lighting.cginc"
            //定义Properties中的变量
            fixed4 _Diffuse;
            sampler2D _MainTex;
            //使用了TRANSFROM_TEX宏就需要定义XXX_ST
            float4 _MainTex_ST;
            sampler2D _RimMask;
            fixed4 _RimColor;
            float _RimPower;
            float _RimSpeed;
 
            //定义结构体：vertex shader阶段输出的内容
            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float2 uv : TEXCOORD1;
                //在vertex shader中计算观察方向传递给fragment shader
                float3 worldViewDir : TEXCOORD2;
            };
 
            //定义顶点shader,参数直接使用appdata_base（包含position, noramal, texcoord）
            v2f vert(appdata_base v)
            {
                v2f o;
                o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                //通过TRANSFORM_TEX宏转化纹理坐标，主要处理了Offset和Tiling的改变,默认时等同于o.uv = v.texcoord.xy;
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.worldNormal = mul(v.normal, (float3x3)_World2Object);
                //顶点转化到世界空间
                float3 worldPos = mul(_Object2World, v.vertex).xyz;
                //可以把计算计算ViewDir的操作放在vertex shader阶段，毕竟逐顶点计算比较省
                o.worldViewDir = _WorldSpaceCameraPos.xyz - worldPos;
                return o;
            }
 
            //定义片元shader
            fixed4 frag(v2f i) : SV_Target
            {
                //unity自身的diffuse也是带了环境光，这里我们也增加一下环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * _Diffuse.xyz;
                //归一化法线，即使在vert归一化也不行，从vert到frag阶段有差值处理，传入的法线方向并不是vertex shader直接传出的
                fixed3 worldNormal = normalize(i.worldNormal);
                //把光照方向归一化
                fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                //根据半兰伯特模型计算像素的光照信息
                fixed3 lambert = 0.5 * dot(worldNormal, worldLightDir) + 0.5;
                //最终输出颜色为lambert光强*材质diffuse颜色*光颜色
                fixed3 diffuse = lambert * _Diffuse.xyz * _LightColor0.xyz + ambient;
                //进行纹理采样
                fixed4 color = tex2D(_MainTex, i.uv);
                
                //以下为本篇主题：计算RimLight
                //把视线方向归一化
                float3 worldViewDir = normalize(i.worldViewDir);
                //计算视线方向与法线方向的夹角，夹角越大，dot值越接近0，说明视线方向越偏离该点，也就是平视，该点越接近边缘
                float rim = 1 - max(0, dot(worldViewDir, worldNormal));
                //计算rimLight
                fixed3 rimColor = _RimColor * pow(rim, 1 / _RimPower);
                fixed rimMask = tex2D(_RimMask, i.uv + float2(0, _Time.y * _RimSpeed)).r;
                //输出颜色+边缘光颜色
                color.rgb = color.rgb* diffuse + rimColor * (1 - rimMask);
                
                return fixed4(color);
            }
 
            //使用vert函数和frag函数
            #pragma vertex vert
            #pragma fragment frag    
 
            ENDCG
        }
    }
    //前面的Shader失效的话，使用默认的Diffuse
    FallBack "Diffuse"
}