开启深度写入的半透明效果8.5

//8.5 开启深度写入的半透明效果

Shader "Unlit/Chapter8-AlphaBlendWrite"
{
		Properties
		{
			_Color("Main Tint",Color) = (1,1,1,1)
			_MainTex("Main Tex",2D) = "white"{}
			//用于在透明纹理的基础上控制整体的透明度
			_AlphaScale("Alpha Scale",Range(0,1)) = 1
		}
		SubShader{
			Tags{ "Queue" = "Transparent" "IgnoreProjector" = "True" "RenderType" = "Transparent" }

			//新增的Pass，为了把模型的深度信息写入深度缓冲中，从而剔除模型中被自身遮挡的片元
			pass {
				//开启深度写入
				ZWrite On
				/*一个新的渲染命令，ColorMask在shaderLab中，用于设置颜色通道的写掩码（write mask）
				ColorMask RGB|A|0 |其他任何RGBA的组合
				当是0时，意味着Pass不写入任何颜色通道，即不输出任何颜色
				*/
				ColorMask 0
			}

			pass {
			Tags{ "LightMode" = "ForwardBase" }

				//把Pass的深度写入（ZWrite）设置为关闭状态（Off）
				ZWrite off
				/*Blend 是unity提供的设置混合模式的命令
				想要实现半透明的效果就需要把当前自身的颜色和已经存在于颜色缓冲中的颜色值进行混合，混合时使用的函数就是由该指令决定的
				Blend SrcFactor DsFactor  开启混合，并设置混合因子，源颜色（该片元产生的颜色）会乘以SRCFactor，而目标颜色（已经存在于颜色缓存的颜色）会乘以DSTFactor，
				然后把两者相加后再存入颜色缓冲中   P169  */
				//P175
				Blend SrcAlpha OneMinusSrcAlpha//正常
				//Blend OneMinusDstColor One//柔和叠加
				//Blend DstColor SrcColor // 两倍相乘
				//BlendOp Min   Blend One One//变暗
				//BlendOp Max   Blend One One // 变亮
				//Blend OneMinusDstColor One//滤色
				//Blend One OneMinusSrcColor//滤色（等同于）
				//Blend One One//线性减淡

				CGPROGRAM
#pragma vertex vert
#pragma fragment frag

#include"Lighting.cginc"

				fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed _AlphaScale;

			struct a2v {
				float4 vertex:POSITION;
				float3 normal:NORMAL;
				float4 texcoord:TEXCOORD0;
			};

			struct v2f {
				float4 pos:SV_POSITION;
				float3 worldNormal:TEXCOORD0;
				float3 worldPos:TEXCOORD1;
				float2 uv:TEXCOORD2;
			};

			//在顶点着色器计算出世界空间的法线方向和顶点位置以及变换后的纹理坐标
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				//世界空间下的法线方向
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				//世界空间下的坐标方向
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				//变换后的纹理坐标
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				return o;
			}

			//片元着色器 包含透明度测试代码
			fixed4 frag(v2f i) :SV_Target{
				//世界空间下的法线归一化
				fixed3 worldNormal = normalize(i.worldNormal);
			//世界空间下的光线方向归一化
			fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
			//对主纹理进行取样
			fixed4 texColor = tex2D(_MainTex, i.uv);
			//反射率
			fixed3 albedo = texColor.rgb*_Color.rgb;
			//环境光照
			fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz*albedo;
			//漫反射
			fixed3 diffuse = _LightColor0.rgb*albedo*max(0, dot(worldNormal, worldLightDir));
			//设置了该片元着色器返回值中的透明通道，它的纹理像素的透明通道和材质参数_AlphaScale的乘积
			return fixed4(ambient + diffuse, texColor.a*_AlphaScale);
			}

				ENDCG
		}
		}

			Fallback"Transparent/VertexLit"
	}