跟我一起阅读并修复源码（3：编译工程，源码分析）之四

在上一章跟我一起阅读并修复某知名DEX交易所源码（3：编译工程）之三_lixiaodog的博客-CSDN博客中

中我们修复了 Factory.sol文件，在本章中我们将阅读Factory.sol中的代码，找到其中的调用关系。

import "../library/SafeMath.sol";

import "../interface/IERC20.sol";

import "../interface/IMdexFactory.sol";

import "../interface/IMdexPair.sol";

这几行代码引入安全数学库，ERC20接口，MDEX工厂接口，还有MDEXPAIR接口。让我们分别进入其中，快速阅读一下。

1：SafeMath.sol

我们可以看到其中实现的其实就是平常所看到的通用数学操作，比如加减等。那为什么可以用操作符实现的运算需要一个库来实现呢？大数相加溢出会形成巨大的漏洞。所以为了代码安全，请在以后的开发中一定注意加数值溢出问题。

2:IERC20.sol

pragma solidity >=0.5.0 <0.8.0;

interface IERC20 {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external view returns (string memory);

    function symbol() external view returns (string memory);

    function decimals() external view returns (uint8);

    function totalSupply() external view returns (uint);

    function balanceOf(address owner) external view returns (uint);

    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);

    function transfer(address to, uint value) external returns (bool);

    function transferFrom(address from, address to, uint value) external returns (bool);
}

本合约定义了一个ERC20的标准TOKEN接口，一个合约只要实现了这个接口就是一个标准的ERC20TOKEN。

3：IMdexFactory.sol

这个合约定义了MDEX工厂的接口，我们将在它的实现里详细解析他的代码。

4：IMdexPair.sol

这个合约定义了mdexPair，事实上整个DEX交易所的交易大部分都和PAIR相关，我们将详细解析它的一个实现的代码。

此时，我们发现在interface目录下的接口我们已经基本了解了。

现在让我们回到Factory.sol

首先看contract MdexERC20，这个合约实现了IMdexERC20，

    string public constant _name = 'HSwap LP Token';

    string public constant _symbol = 'HMDX';

    uint8 public constant _decimals = 18;

    uint  public _totalSupply;

定义了常用的几个存储并提供给以下的接口实现函数使用。

mapping(address => mapping(address => uint)) public _allowance;

此变量记录了所有地址的的授权合约以及数量。以便其它合约可以不经过私钥的签名可以直接从某地址扣除TOKEN。这也是所有DEFI实现的基础，不然DEFI就无从谈起。

bytes32 public _DOMAIN_SEPARATOR;

    _DOMAIN_SEPARATOR = keccak256(
            abi.encode(
                keccak256('EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)'),
                keccak256(bytes(_name)),
                keccak256(bytes('1')),
                chainId,
                address(this)
            )
        );

这是一个散列，本合约的构造函数中，它被赋予了一个初始值，后面他将被用来和其它几个实时参数在permit函数中生成EIP-712签名。

    function _mint(address to, uint value) internal {
        _totalSupply = _totalSupply.add(value);
        _balanceOf[to] = _balanceOf[to].add(value);
        emit Transfer(address(0), to, value);
    }

本函数实现了MINT操作，本质上就是无中生有，增加TOKEN数量。

    function _burn(address from, uint value) internal {
        _balanceOf[from] = _balanceOf[from].sub(value);
        _totalSupply = _totalSupply.sub(value);
        emit Transfer(from, address(0), value);
    }

本函数实现了燃烧TOKEN，把一定数量的TOKEN转移到地址0。

    function _approve(address owner, address spender, uint value) public {
        _allowance[owner][spender] = value;
        emit Approval(owner, spender, value);
    }

    function _transfer(address from, address to, uint value) public {
        _balanceOf[from] = _balanceOf[from].sub(value);
        _balanceOf[to] = _balanceOf[to].add(value);
        emit Transfer(from, to, value);
    }

    function approve(address spender, uint value) external override virtual returns (bool) {
        _approve(msg.sender, spender, value);
        return true;
    }

    function transfer(address to, uint value) external override virtual returns (bool) {
        _transfer(msg.sender, to, value);
        return true;
    }

    function transferFrom(address from, address to, uint value) external override virtual returns (bool) {
        if (_allowance[from][msg.sender] != uint(- 1)) {
            _allowance[from][msg.sender] = _allowance[from][msg.sender].sub(value);
        }
        _transfer(from, to, value);
        return true;
    }

以上几个函数，实现了授权，交易等基本操作。

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) override virtual external {
        require(deadline >= block.timestamp, 'MdexSwap: EXPIRED');
        bytes32 digest = keccak256(
            abi.encodePacked(
                '\x19\x01',
                _DOMAIN_SEPARATOR,
                keccak256(abi.encode(_PERMIT_TYPEHASH, owner, spender, value, _nonces[owner]++, deadline))
            )
        );
        address recoveredAddress = ecrecover(digest, v, r, s);
        require(recoveredAddress != address(0) && recoveredAddress == owner, 'MdexSwap: INVALID_SIGNATURE');
        _approve(owner, spender, value);
    }

在本函数中调用ecrecover来检索签名者地址，并验证是否通过。在下一章

跟我一起阅读并修复某知名DEX交易所源码（3：编译工程，源码分析）之五_lixiaodog的博客-CSDN博客

我们将分析一个非常重要的mdexpair合约。

跟我一起阅读并修复源码（3：编译工程，源码分析）之四

猜你喜欢