消融效果
原理：噪声纹理+透明度测试
使用噪声纹理采样的结果和某个控制消融程度的阈值比较，如果小于阈值，就使用clip函数把它对应的像素裁剪掉，这些部分就对应了图中被“烧毁”的区域。而镂空区域边缘的烧焦效果则是将两种颜色混合，再用pow函数处理后，与原纹理颜色混合后的结果。
BurnHelpers：
using UnityEngine;
using System.Collections;
public class BurnHelper : MonoBehaviour {
public Material material;
[Range(0.01f, 1.0f)]
public float burnSpeed = 0.3f;
private float burnAmount = 0.0f;
// Use this for initialization
void Start () {
if (material == null) {
Renderer renderer = gameObject.GetComponentInChildren<Renderer>();
if (renderer != null) {
material = renderer.material;
}
}
if (material == null) {
this.enabled = false;
} else {
material.SetFloat("_BurnAmount", 0.0f);
}
}
// Update is called once per frame
void Update () {
burnAmount = Mathf.Repeat(Time.time * burnSpeed, 1.0f);
material.SetFloat("_BurnAmount", burnAmount);
}
}
Shader：
Shader "Unity Shaders Book/Chapter 15/Dissolve" {
Properties {
_BurnAmount ("Burn Amount", Range(0.0, 1.0)) = 0.0 //控制消融程度，0正常，1消融
_LineWidth("Burn Line Width", Range(0.0, 0.2)) = 0.1 //控制模拟燃烧效果时的线宽
_MainTex ("Base (RGB)", 2D) = "white" {}
_BumpMap ("Normal Map", 2D) = "bump" {} //法线纹理
_BurnFirstColor("Burn First Color", Color) = (1, 0, 0, 1) //火焰边缘颜色
_BurnSecondColor("Burn Second Color", Color) = (1, 0, 0, 1) //火焰边缘颜色
_BurnMap("Burn Map", 2D) = "white"{} //噪声纹理
}
SubShader {
Tags { "RenderType"="Opaque" "Queue"="Geometry"}
Pass {
Tags { "LightMode"="ForwardBase" }
#使得面片都能被渲染
Cull Off
CGPROGRAM
#include "Lighting.cginc"
#include "AutoLight.cginc"
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
fixed _BurnAmount;
fixed _LineWidth;
sampler2D _MainTex;
sampler2D _BumpMap;
fixed4 _BurnFirstColor;
fixed4 _BurnSecondColor;
sampler2D _BurnMap;
float4 _MainTex_ST;
float4 _BumpMap_ST;
float4 _BurnMap_ST;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float2 uvMainTex : TEXCOORD0;
float2 uvBumpMap : TEXCOORD1;
float2 uvBurnMap : TEXCOORD2;
float3 lightDir : TEXCOORD3;
float3 worldPos : TEXCOORD4;
SHADOW_COORDS(5)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uvMainTex = TRANSFORM_TEX(v.texcoord, _MainTex);
o.uvBumpMap = TRANSFORM_TEX(v.texcoord, _BumpMap);
o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);
TANGENT_SPACE_ROTATION;
o.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)).xyz;
o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;
clip(burn.r - _BurnAmount);
float3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uvBumpMap));
fixed3 albedo = tex2D(_MainTex, i.uvMainTex).rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));
fixed t = 1 - smoothstep(0.0, _LineWidth, burn.r - _BurnAmount);
fixed3 burnColor = lerp(_BurnFirstColor, _BurnSecondColor, t);
burnColor = pow(burnColor, 5);
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
fixed3 finalColor = lerp(ambient + diffuse * atten, burnColor, t * step(0.0001, _BurnAmount));
return fixed4(finalColor, 1);
}
ENDCG
}
// Pass to render object as a shadow caster
Pass {
Tags { "LightMode" = "ShadowCaster" }
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile_shadowcaster
#include "UnityCG.cginc"
fixed _BurnAmount;
sampler2D _BurnMap;
float4 _BurnMap_ST;
struct v2f {
V2F_SHADOW_CASTER;
float2 uvBurnMap : TEXCOORD1;
};
v2f vert(appdata_base v) {
v2f o;
TRANSFER_SHADOW_CASTER_NORMALOFFSET(o)
o.uvBurnMap = TRANSFORM_TEX(v.texcoord, _BurnMap);
return o;
}
fixed4 frag(v2f i) : SV_Target {
fixed3 burn = tex2D(_BurnMap, i.uvBurnMap).rgb;
clip(burn.r - _BurnAmount);
SHADOW_CASTER_FRAGMENT(i)
}
ENDCG
}
}
FallBack "Diffuse"
}
顶点着色器：
首先对三张纹理进行纹理坐标计算，再把光源方向从模型空间转换到切线空间，最后计算阴影纹理采样坐标。
片元着色器：
我们首先对噪声纹理进行采样，并将采样结果和用于控制消融程度的属性_ BurnAmount 相减，传递给clip函数。当结果小于0时，该像素将会被剔除，从而不会显示到屏幕上。
根据漫反射纹理得到材质的反射率albedo,并由此计算得到环境光照，进而得到漫反射光照。计算切线空间下的光照方向和法线方向（UnpackNormal），从而在切线空间下计算光照。
float3 tangentLightDir = normalize(i.lightDir);
fixed3 tangentNormal = UnpackNormal(tex2D(_BumpMap, i.uvBumpMap));
fixed3 albedo = tex2D(_MainTex, i.uvMainTex).rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(tangentNormal, tangentLightDir));然后，我们计算了烧焦颜色_burnColor 。我们想要在宽度为_LineWidth的范围内模拟一个烧焦的颜色变化，第一步 就使用了smoothstep函数来计算混合系数t。当t值为1时，表明该像素位于消融的边界处，当t值为0时，表明该像素为正常的模型颜色，而中间的插值则表示需要模拟一个烧焦效果。我们首先用t来混合两种火焰颜色_BurmFirstColor和_ BurnSecondColor, 为了让效果更接近烧焦的痕迹，我们还使用pow函数对结果进行处理。然后，我们再次使用t来混合正常的光照颜色(环境光+漫反射)和烧焦颜色。我们这里又使用了step函数来保证当_BurnAmount 为0时，不显示任何消融效果。最后，返回混合后的颜色值finalColor。
fixed t = 1 - smoothstep(0.0, _LineWidth, burn.r - _BurnAmount);
fixed3 burnColor = lerp(_BurnFirstColor, _BurnSecondColor, t);
burnColor = pow(burnColor, 5);
UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
fixed3 finalColor = lerp(ambient + diffuse * atten, burnColor, t * step(0.0001, _BurnAmount));smoothstep函数：
在
min与max之间进行插值，在限制处进行平滑。此函数采用与 Lerp （线性插值）相似的方式在
min与max之间进行插值。 但是，插值会从起点逐渐加速，然后朝着终点减慢。 这可用于创建表现十分自然的动画、淡化和其他过渡。
阴影投射Pass：
由于本例中使用了透明度测试，所以阴影透射需要进行特别处理。
在Unity中，用于投射阴影的Pass的LightMode需要被设置为ShadowCaster,同时，还需要使用#pragma multi compile_ shadowcaster 指明它需要的编译指令。
阴影投射的重点在于我们需要按正常Pass的处理来剔除片元或进行顶点动画，以便阴影可以
和物体正常渲染的结果相匹配。在自定义的阴影投射的Pass中，我们通常会使用Unity提供的内置宏V2F_ SHADOW_ CASTER【v2f结构体】、TRANSFER_ SHADOW_ CASTER NORMALOFFSET【顶点着色器】 (旧版本中会使用TRANSFER_ SHADOW_ CASTER)和SHADOW_ CASTER_FRAGMENT【片元着色器】来帮助我们计算阴影投射时需要的各种变量，而我们可以只关注自定义计算的部分。在上面的代码中，我们首先在v2f结构体中利用V2F_ SHADOW_ CASTER来定义阴影投射需要定义的变量。随后，在顶点着色器中，我们使用TRANSFER_SHADOW_CASTER_NORMALOFFSET来填充V2F_SHADOW_CASTER在背后声明的一些变量， 这是由Unity在背后为我们完成的。我们需要在顶点着色器中关注自定义的计算部分，这里指的就是我们需要计算噪声纹理的采样坐标uvBurnMap。在片元着色器中，我们首先按之前的处理方法使用噪声纹理的采样结果来剔除片元，最后再利用SHADOW_ CASTER_FRAGMENT来让Unity为我们完成阴影投射的部分，把结果输出到深度图和阴影映射纹理中。
TRANSFER_SHADOW_ CASTER_NORMALOFFSET会使用名称v作为输入结构体,v中需要包含顶点位置v.vertex和顶点法线v.normal的信息，我们可以直接使用内置的appdata_base结构体，它包含这些必须的顶点变量。