主要针对RT-Thread系统中任务切换函数汇编部分进行一下记录，方便回头查看，gcc/MDK/IAR内容差不多，只是语法格式不同而已，本人一般使用gcc环境，所以对 context_gcc.S详解。
先贴源码
/*
* Copyright (c) 2006-2018, RT-Thread Development Team
*
* SPDX-License-Identifier: Apache-2.0
*
* Change Logs:
* Date Author Notes
* 2009-10-11 Bernard first version
* 2012-01-01 aozima support context switch load/store FPU register.
* 2013-06-18 aozima add restore MSP feature.
* 2013-06-23 aozima support lazy stack optimized.
* 2018-07-24 aozima enhancement hard fault exception handler.
*/
/**
* @addtogroup cortex-m7
*/
/*@{*/
.cpu cortex-m4
.syntax unified
.thumb
.text
.equ SCB_VTOR, 0xE000ED08 /* Vector Table Offset Register */
.equ NVIC_INT_CTRL, 0xE000ED04 /* interrupt control state register */
.equ NVIC_SYSPRI2, 0xE000ED20 /* system priority register (2) */
.equ NVIC_PENDSV_PRI, 0x00FF0000 /* PendSV priority value (lowest) */
.equ NVIC_PENDSVSET, 0x10000000 /* value to trigger PendSV exception */
/*
* rt_base_t rt_hw_interrupt_disable();
*/
.global rt_hw_interrupt_disable
.type rt_hw_interrupt_disable, %function
rt_hw_interrupt_disable:
MRS r0, PRIMASK
CPSID I
BX LR
/*
* void rt_hw_interrupt_enable(rt_base_t level);
*/
.global rt_hw_interrupt_enable
.type rt_hw_interrupt_enable, %function
rt_hw_interrupt_enable:
MSR PRIMASK, r0
BX LR
/*
* void rt_hw_context_switch(rt_uint32 from, rt_uint32 to);
* r0 --> from
* r1 --> to
*/
.global rt_hw_context_switch_interrupt
.type rt_hw_context_switch_interrupt, %function
.global rt_hw_context_switch
.type rt_hw_context_switch, %function
rt_hw_context_switch_interrupt:
rt_hw_context_switch:
/* set rt_thread_switch_interrupt_flag to 1 */
LDR r2, =rt_thread_switch_interrupt_flag
LDR r3, [r2]
CMP r3, #1
BEQ _reswitch
MOV r3, #1
STR r3, [r2]
LDR r2, =rt_interrupt_from_thread /* set rt_interrupt_from_thread */
STR r0, [r2]
_reswitch:
LDR r2, =rt_interrupt_to_thread /* set rt_interrupt_to_thread */
STR r1, [r2]
LDR r0, =NVIC_INT_CTRL /* trigger the PendSV exception (causes context switch) */
LDR r1, =NVIC_PENDSVSET
STR r1, [r0]
BX LR
/* r0 --> switch from thread stack
* r1 --> switch to thread stack
* psr, pc, lr, r12, r3, r2, r1, r0 are pushed into [from] stack
*/
.global PendSV_Handler
.type PendSV_Handler, %function
PendSV_Handler:
/* disable interrupt to protect context switch */
MRS r2, PRIMASK
CPSID I
/* get rt_thread_switch_interrupt_flag */
LDR r0, =rt_thread_switch_interrupt_flag
LDR r1, [r0]
CBZ r1, pendsv_exit /* pendsv already handled */
/* clear rt_thread_switch_interrupt_flag to 0 */
MOV r1, #0x00
STR r1, [r0]
LDR r0, =rt_interrupt_from_thread
LDR r1, [r0]
CBZ r1, switch_to_thread /* skip register save at the first time */
MRS r1, psp /* get from thread stack pointer */
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
TST lr, #0x10 /* if(!EXC_RETURN[4]) */
VSTMDBEQ r1!, {
d8 - d15} /* push FPU register s16~s31 */
#endif
STMFD r1!, {
r4 - r11} /* push r4 - r11 register */
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
MOV r4, #0x00 /* flag = 0 */
TST lr, #0x10 /* if(!EXC_RETURN[4]) */
MOVEQ r4, #0x01 /* flag = 1 */
STMFD r1!, {
r4} /* push flag */
#endif
LDR r0, [r0]
STR r1, [r0] /* update from thread stack pointer */
switch_to_thread:
LDR r1, =rt_interrupt_to_thread
LDR r1, [r1]
LDR r1, [r1] /* load thread stack pointer */
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
LDMFD r1!, {
r3} /* pop flag */
#endif
LDMFD r1!, {
r4 - r11} /* pop r4 - r11 register */
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
CMP r3, #0 /* if(flag_r3 != 0) */
VLDMIANE r1!, {
d8 - d15} /* pop FPU register s16~s31 */
#endif
MSR psp, r1 /* update stack pointer */
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
ORR lr, lr, #0x10 /* lr |= (1 << 4), clean FPCA. */
CMP r3, #0 /* if(flag_r3 != 0) */
BICNE lr, lr, #0x10 /* lr &= ~(1 << 4), set FPCA. */
#endif
pendsv_exit:
/* restore interrupt */
MSR PRIMASK, r2
ORR lr, lr, #0x04
BX lr
/*
* void rt_hw_context_switch_to(rt_uint32 to);
* r0 --> to
*/
.global rt_hw_context_switch_to
.type rt_hw_context_switch_to, %function
rt_hw_context_switch_to:
LDR r1, =rt_interrupt_to_thread
STR r0, [r1]
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
/* CLEAR CONTROL.FPCA */
MRS r2, CONTROL /* read */
BIC r2, #0x04 /* modify */
MSR CONTROL, r2 /* write-back */
#endif
/* set from thread to 0 */
LDR r1, =rt_interrupt_from_thread
MOV r0, #0x0
STR r0, [r1]
/* set interrupt flag to 1 */
LDR r1, =rt_thread_switch_interrupt_flag
MOV r0, #1
STR r0, [r1]
/* set the PendSV exception priority */
LDR r0, =NVIC_SYSPRI2
LDR r1, =NVIC_PENDSV_PRI
LDR.W r2, [r0,#0x00] /* read */
ORR r1,r1,r2 /* modify */
STR r1, [r0] /* write-back */
LDR r0, =NVIC_INT_CTRL /* trigger the PendSV exception (causes context switch) */
LDR r1, =NVIC_PENDSVSET
STR r1, [r0]
/* restore MSP */
LDR r0, =SCB_VTOR
LDR r0, [r0]
LDR r0, [r0]
NOP
MSR msp, r0
/* enable interrupts at processor level */
CPSIE F
CPSIE I
/* never reach here! */
/* compatible with old version */
.global rt_hw_interrupt_thread_switch
.type rt_hw_interrupt_thread_switch, %function
rt_hw_interrupt_thread_switch:
BX lr
NOP
.global HardFault_Handler
.type HardFault_Handler, %function
HardFault_Handler:
/* get current context */
MRS r0, msp /* get fault context from handler. */
TST lr, #0x04 /* if(!EXC_RETURN[2]) */
BEQ _get_sp_done
MRS r0, psp /* get fault context from thread. */
_get_sp_done:
STMFD r0!, {
r4 - r11} /* push r4 - r11 register */
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
STMFD r0!, {
lr} /* push dummy for flag */
#endif
STMFD r0!, {
lr} /* push exec_return register */
TST lr, #0x04 /* if(!EXC_RETURN[2]) */
BEQ _update_msp
MSR psp, r0 /* update stack pointer to PSP. */
B _update_done
_update_msp:
MSR msp, r0 /* update stack pointer to MSP. */
_update_done:
PUSH {
LR}
BL rt_hw_hard_fault_exception
POP {
LR}
ORR lr, lr, #0x04
BX lr
1、宏定义
.equ SCB_VTOR, 0xE000ED08 /* Vector Table Offset Register */
.equ NVIC_INT_CTRL, 0xE000ED04 /* interrupt control state register */
.equ NVIC_SYSPRI2, 0xE000ED20 /* system priority register (2) */
.equ NVIC_PENDSV_PRI, 0x00FF0000 /* PendSV priority value (lowest) */
.equ NVIC_PENDSVSET, 0x10000000 /* value to trigger PendSV exception */
定义这几个宏，SCB_VTOR、NVIC_INT_CTRL、NVIC_SYSPRI2(实际是3)，这三个是Cortex-M核的寄存器，SCB_VTOR中断向量表偏移寄存器，NVIC_INT_CTRL中断控制寄存器，NVIC_SYSPRI2中断设置优先级寄存器。
NVIC_PENDSV_PRI可悬挂异常的中断优先级，0x00FF0000对应NVIC_SYSPRI3的bit16-23，即最低优先级，如下：
NVIC_PENDSVSET是触发可悬挂中断的位0x10000000，对应NVIC_INT_CTRL的bit28，
2、开/关中断（异常）
PRIMASK 中断屏蔽寄存器，bit0等于1时屏蔽一切中断，0时无影响。
CPSID I 关中断，等价于MOV r2,#1 ; MSR PRIMASK, r2；即PRIMASK=1。
CPSIE I 开中断，等价于MOV r2,#0 ; MSR PRIMASK, r2；即PRIMASK=0。
CPSID F 关异常；
CPSIE I 开异常；道理相同。
rt_hw_interrupt_disable是保存中断掩码状态，并关中断；但rt_hw_interrupt_enable是将上述保存的中断掩码恢复，开不开中断取决于保存的掩码状态（并不一定是开中断）。
3、启动第一个任务
由于是第一个任务，无中断上文，只有中断下文。
以下直接注释解释。
/*
* void rt_hw_context_switch_to(rt_uint32 to);
* r0 --> to
*/
.global rt_hw_context_switch_to
.type rt_hw_context_switch_to, %function
rt_hw_context_switch_to:
;中断下文任务栈保存在rt_interrupt_to_thread，rt_interrupt_to_thread是全局变量，PENDSV任务切换中会用
LDR r1, =rt_interrupt_to_thread
STR r0, [r1]
;若使用浮点型处理，则使能异常中断浮点处理功能，对应下图CONTROL寄存器
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
/* CLEAR CONTROL.FPCA */
MRS r2, CONTROL /* read */
BIC r2, #0x04 /* modify */
MSR CONTROL, r2 /* write-back */
#endif
;无中断上文任务栈，所以rt_interrupt_from_thread保存为0，rt_interrupt_from_thread是全局变量，PENDSV任务切换中会用
/* set from thread to 0 */
LDR r1, =rt_interrupt_from_thread
MOV r0, #0x0
STR r0, [r1]
；有任务需要切换，设置rt_thread_switch_interrupt_flag=1，rt_thread_switch_interrupt_flag是全局变量，PENDSV任务切换中会用
/* set interrupt flag to 1 */
LDR r1, =rt_thread_switch_interrupt_flag
MOV r0, #1
STR r0, [r1]
;设置PendSV的中断优先级，两个宏及对应bit位上图已做说明
/* set the PendSV exception priority */
LDR r0, =NVIC_SYSPRI2
LDR r1, =NVIC_PENDSV_PRI
LDR.W r2, [r0,#0x00] /* read */
ORR r1,r1,r2 /* modify */
STR r1, [r0] /* write-back */
;触发PendSV中断，使其挂起，对应bit位，上图已做说明
LDR r0, =NVIC_INT_CTRL /* trigger the PendSV exception (causes context switch) */
LDR r1, =NVIC_PENDSVSET
STR r1, [r0]
;中断向量偏移寄存器SCB_VTOR中取出中断向量表，再从中断向量表中取出第一项的地址，保存到主堆栈指针MSP上
/* restore MSP */
LDR r0, =SCB_VTOR
LDR r0, [r0]
LDR r0, [r0]
NOP
MSR msp, r0
;开启中断/异常，即PRIMASK=0，FAULTMASK=0
/* enable interrupts at processor level */
CPSIE F
CPSIE I
/* never reach here! */
/* compatible with old version */
.global rt_hw_interrupt_thread_switch
.type rt_hw_interrupt_thread_switch, %function
rt_hw_interrupt_thread_switch:
BX lr
NOP
CONTROL寄存器
4、任务切换Ⅰ
这一步只是处理前一个任务的入栈地址保存，后一个任务的出栈地址保存，以及任务切换标志置位。
Cortex-M系列，普通任务切换和中断任务切换是一样的，所以两者写成了一个函数。以下直接在源码中注释。
- r0 输入参数
- r1 输出参数
/*
* void rt_hw_context_switch(rt_uint32 from, rt_uint32 to);
* r0 --> from
* r1 --> to
*/
.global rt_hw_context_switch_interrupt
.type rt_hw_context_switch_interrupt, %function
.global rt_hw_context_switch
.type rt_hw_context_switch, %function
rt_hw_context_switch_interrupt:
rt_hw_context_switch:
;从rt_thread_switch_interrupt_flag切换任务标志变量中取出数值，若不是1则置1，说明有任务要切换；若是1，说明前一个任务的栈已经入列，则只需处理后一个任务的栈即可，跳转到_reswitch。
/* set rt_thread_switch_interrupt_flag to 1 */
LDR r2, =rt_thread_switch_interrupt_flag
LDR r3, [r2]
;对比rt_thread_switch_interrupt_flag是否为1
CMP r3, #1
BEQ _reswitch
MOV r3, #1
STR r3, [r2]
;将上一个任务的栈r0，保存到全局变量rt_interrupt_from_thread中
LDR r2, =rt_interrupt_from_thread /* set rt_interrupt_from_thread */
STR r0, [r2]
_reswitch:
;将上一个任务的栈r1，保存到全局变量rt_interrupt_to_thread中
LDR r2, =rt_interrupt_to_thread /* set rt_interrupt_to_thread */
STR r1, [r2]
;NVIC_INT_CTRL寄存器和NVIC_PENDSVSET上文已做说明，这里是触发PendSV中断，然后BX LR返回连接寄存器。
LDR r0, =NVIC_INT_CTRL /* trigger the PendSV exception (causes context switch) */
LDR r1, =NVIC_PENDSVSET
STR r1, [r0]
BX LR
5、任务切换Ⅱ
这一步PendSV中断函数处理真正的任务切换。
/* r0 --> switch from thread stack
* r1 --> switch to thread stack
* psr, pc, lr, r12, r3, r2, r1, r0 are pushed into [from] stack
*/
.global PendSV_Handler
.type PendSV_Handler, %function
PendSV_Handler:
;关闭全局中断
/* disable interrupt to protect context switch */
MRS r2, PRIMASK
CPSID I
;检查rt_thread_switch_interrupt_flag是否为1,1则有任务需切换，0则无任务需要切换，跳到最后的退出函数pendsv_exit
/* get rt_thread_switch_interrupt_flag */
LDR r0, =rt_thread_switch_interrupt_flag
LDR r1, [r0]
CBZ r1, pendsv_exit /* pendsv already handled */
;rt_thread_switch_interrupt_flag标志清零
/* clear rt_thread_switch_interrupt_flag to 0 */
MOV r1, #0x00
STR r1, [r0]
;上一个任务的栈地址rt_interrupt_from_thread取出到r1，为0说明是第一次任务切换，忽略入栈操作，跳转至switch_to_thread
LDR r0, =rt_interrupt_from_thread
LDR r1, [r0]
CBZ r1, switch_to_thread /* skip register save at the first time */
;进程堆栈指针psp入栈r1
MRS r1, psp /* get from thread stack pointer */
;若使能浮点运算，则特殊处理
;连接寄存器LR的低5位有效数据，高31位全是1，详细说明见下图
;LR的bit4是是否为浮点状态返回标志，bit4位0则是浮点返回，则将浮点的d8-d15寄存器压入堆栈r1
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
TST lr, #0x10 /* if(!EXC_RETURN[4]) */
VSTMDBEQ r1!, {
d8 - d15} /* push FPU register s16~s31 */
#endif
;r4-r11压入堆栈r1（psr,pc,lr,r12,r3,r2,r1,r0硬件会自动压入堆栈，无需人为操作）
STMFD r1!, {
r4 - r11} /* push r4 - r11 register */
;将是否是浮点返回标志压入堆栈，根据LR的bit4判断
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
MOV r4, #0x00 /* flag = 0 */
TST lr, #0x10 /* if(!EXC_RETURN[4]) */
MOVEQ r4, #0x01 /* flag = 1 */
STMFD r1!, {
r4} /* push flag */
#endif
;最后更新前一个任务的线程栈指针
LDR r0, [r0]
STR r1, [r0] /* update from thread stack pointer */
;后一个任务的栈处理
switch_to_thread:
LDR r1, =rt_interrupt_to_thread
LDR r1, [r1]
LDR r1, [r1] /* load thread stack pointer */
;r1取浮点返回标志r3
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
LDMFD r1!, {
r3} /* pop flag */
#endif
LDMFD r1!, {
r4 - r11} /* pop r4 - r11 register */
;若浮点返回标志是1，则取出压入栈的浮点寄存器d8-d15
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
CMP r3, #0 /* if(flag_r3 != 0) */
VLDMIANE r1!, {
d8 - d15} /* pop FPU register s16~s31 */
#endif
;取出线程栈指针
MSR psp, r1 /* update stack pointer */
;lr寄存器的bit4根据是否为浮点返回标志来置位，是则置位
;BICNE 上一个操作若不等于，则执行BIC位清除操作
#if defined (__VFP_FP__) && !defined(__SOFTFP__)
ORR lr, lr, #0x10 /* lr |= (1 << 4), clean FPCA. */
CMP r3, #0 /* if(flag_r3 != 0) */
BICNE lr, lr, #0x10 /* lr &= ~(1 << 4), set FPCA. */
#endif
pendsv_exit:
;使能全局中断
/* restore interrupt */
MSR PRIMASK, r2
;修改lr寄存器，Return to Thread mode, exception return uses (non-)floating-point state from PSP and execution uses PSP after return
ORR lr, lr, #0x04
BX lr
lr连接寄存器，异常返回
6、睡觉
太晚了，现在是2020-08-13 00:47:32，星期四