Hive性能调优
一、合理控制maptask/reducetask数量
1.1、maptask数量
maptask的数量在新版本中由以下因素决定
#mapred-site.xml
minSplitSize = set mapred.min.split.size
maxSplitSize = mapred.max.split.size
#hdfs-site.xml 默认128M
blockSize = dfs.blocksize
#公式
inputSplitSize = Math.max(minSplitSize,Math.min(maxSplitSize,blockSize))
maptaskCount = Math.ceil(fileSize/inputSplitSize)
默认情况下，输入分片大小和 HDFS 集群默认数据块大小一致，也就是默认一个数据块，启用一个 MapTask 进行处理，这样做的好处是避免了服务器节点之间的数据传输，提高 job 处理效率。
（1）是不是map数越多越好？（Map 数过大）
答案是否定的。如果一个任务有很多小文件（远远小于块大小128m），则每个小文件也会被当做一个块，用一个map任务来完成，而一个map任务启动和初始化的时间远远大于逻辑处理的时间，就会造成很大的资源浪费。而且，同时可执行的map数是受限的。解决方法减少map数
（2）是不是保证每个map处理接近128m的文件块，就高枕无忧了？（Map 数过小）
答案也是不一定。比如有一个127m的文件，正常会用一个map去完成，但这个文件只有一个或者两个小字段，却有几千万的记录，如果map处理的逻辑比较复杂，用一个map任务去做，肯定也比较耗时。增加map数
1.2、reducetask数量
Hive 的估计机制很弱，不指定 reducer 个数的情况下，Hive 会猜测并决定 reducer 个数，基于以下两个设定：
# 每个reducer处理的数据量默认是256M
1、hive.exec.reducers.bytes.per.reducer（默认为 256000000）
# 每个任务最大的reducer数，默认1009个
2、hive.exec.reducers.max（默认为 1009）
# 设置每个job的reducer数
3、mapreduce.job.reduces=1（设置一个常量 reducetask 数量）
# 计算reducer数的公式
N=min(hive.exec.reducers.max，总输入数据量/hive.exec.reducers.bytes.per.reducer)
reduce个数并不是越多越好
1）过多的启动和初始化reduce也会消耗时间和资源；
2）另外，有多少个reduce，就会有多少个输出文件，如果生成了很多个小文件，那么如果这些小文件作为下一个任务的输入，则也会出现小文件过多的问题；
在设置reduce个数的时候也需要考虑这两个原则
1）处理大数据量利用合适的reduce数；
2）使单个reduce任务处理数据量大小要合适；
二、查询优化
2.1、行列过滤
1、列处理：在查询数据时，只查需要的列，如果有分区，尽量使用分区过滤，少用SELECT *查询
2、行处理：在分区剪裁中，当使用外关联时，如果将副表的过滤条件写在where后面，那么就会先全表关联，之后再过滤，比如：
- 测试先关联两张表，再用where条件过滤
hive> select o.id from bigtable b
join ori o on o.id = b.id
where o.id <= 10;
Time taken: 63.316 seconds, Fetched: 100 row(s)
- 通过子查询后，再关联表
hive (default)> select b.id from bigtable b
join (select id from ori where id <= 10 ) o on b.id = o.id;
Time taken: 61.106 seconds, Fetched: 100 row(s)
2.2、动态分区调整
1、分区的作用
表进行分区后，逻辑上表仍然是一张完整的表，只是将表中的数据存放到多个表空间（物理文件上），这样查询数据时，就不必要每次都扫描整张表，从而提升查询性能。
1.一个分区对应一个文件
2.分区的目的是为了让数据根据计算要求进行分布
3.分区的好处是分布式计算过程中减少数据迁移 —> 减少I/O开销
4.业务中如果有些字段常用于分组，最好将它设为分区
2、动态分区
往hive分区表中插入数据时，如果需要创建的分区很多，比如以表中某个字段进行分区存储，则需要复制粘贴修改很多sql去执行，效率低。因为hive是批处理系统，所以hive提供了一个动态分区功能，其可以基于查询参数的位置去推断分区的名称，从而建立分区。
批量导入数据到分区
3、开启动态分区参数
# 开启动态分区功能（默认true，开启）
hive.exec.dynamic.partition=true
# 设置为非严格模式（动态分区的模式，默认strict，表示必须指定至少一个分区为静态分区，nonstrict模式表示允许所有的分区字段都可以使用动态分区）
hive.exec.dynamic.partition.mode=nonstrict
# 在所有执行MR的节点上，最大一共可以创建多少个动态分区
hive.exec.max.dynamic.partitions=1000
# 在每个执行MR的节点上，最大可以创建多少个动态分区。该参数需要根据实际的数据来设定。比如：源数据中包含了一年的数据，即day字段有365个值，那么该参数就需要设置成大于365，如果使用默认值100，则会报错
hive.exec.max.dynamic.partitions.pernode=100
# 整个MR Job中，最大可以创建多少个HDFS文件
hive.exec.max.created.files=100000
# 当有空分区生成时，是否抛出异常。一般不需要设置
hive.error.on.empty.partition=false
2.3、合理利用分桶、分桶抽样
1、分区和分桶差异
分区提供了一个隔离数据和优化查询的可行方案，但是并非所有的数据集都可以形成合理的分区，分区的数量也不是越多越好，过多的分区条件可能会导致很多分区上没有数据。同时 Hive 会限制动态分区可以创建的最大分区数，用来避免过多分区文件对文件系统产生负担。鉴于以上原因，Hive 还提供了一种更加细粒度的数据拆分方案：分桶表 (bucket Table)。
2、分桶的作用
分桶表会将指定列的值进行哈希散列，并对 bucket（桶数量）取余，然后存储到对应的 bucket（桶）中。
3、分桶抽样（Sampling）
4、开启分桶
SET hive.enforce.bucketing=true;
2.4、笛卡尔积
尽量避免笛卡尔积，join的时候不加on条件，或者无效的on条件都有可能会产生笛卡尔积。
Hive只能使用1个reducer来完成笛卡尔积，会导致计算性能较低。
笛卡尔积具体描述 怎样做笛卡尔积
三、Fetch抓取（默认已开启）
1、含义
Fetch抓取是指，Hive中对某些情况的查询可以不必使用MapReduce计算。例如：SELECT * FROM employees;在这种情况下，Hive可以简单地读取employee对应的存储目录下的文件，然后输出查询结果到控制台。
2、体现
在hive-default.xml.template文件中hive.fetch.task.conversion默认是more，老版本hive默认是minimal，该属性修改为more以后，在全局查找、字段查找、limit查找等都不走mapreduce。
<property>
<name>hive.fetch.task.conversion</name>
<value>more</value>
<description>
Expects one of [none, minimal, more].
Some select queries can be converted to single FETCH task minimizing latency.
Currently the query should be single sourced not having any subquery and should not have
any aggregations or distincts (which incurs RS), lateral views and joins.
0. none : disable hive.fetch.task.conversion
1. minimal : SELECT STAR, FILTER on partition columns, LIMIT only
2. more : SELECT, FILTER, LIMIT only (support TABLESAMPLE and virtual columns)
</description>
</property>
3、测试
- 关闭fetch时
hive> set hive.fetch.task.conversion=none;
很明显可以看到查询走了mapreduce，简单的查询耗时13秒
- 开启fetch时
hive> set hive.fetch.task.conversion=more;
查询没有走mapreduce，查询结果直接出现
四、文件处理
4.1、本地模式（少量小文件，默认未开启）
1、含义
大多数的 Hadoop Job 是需要 Hadoop 提供的完整可扩展性来处理大数据集的。但是当 Hive 查询处理的数据量比较小时，其实没有必要启动分布式模式去执行，因为以分布式方式执行就涉及到跨网络传输、多节点协调等，并且消耗资源。对于小数据集，使用本地模式，明显缩短执行时间。
2、命令
set hive.exec.mode.local.auto=true; //让hive决定是否在本地模式自动运行，默认false
set hive.exec.mode.local.auto.inputbytes.max=50000000; //不启动本地模式的最大输入文件大小，默认是128M
set hive.exec.mode.local.auto.input.files.max=8; //不启动本地模式的task最大个数，默认是4
3、测试
（1）开启本地模式，并执行查询语句
hive> set hive.exec.mode.local.auto=true;
hive> select * from emp cluster by deptno;
Time taken: 1.328 seconds, Fetched: 14 row(s)
（2）关闭本地模式，并执行查询语句
hive> set hive.exec.mode.local.auto=false;
hive> select * from emp cluster by deptno;
Time taken: 20.09 seconds, Fetched: 14 row(s)；
4.2、合并小文件（大量小文件，减少map数）
在map执行前合并小文件，减少map数
set hive.merge.mapfiles=true; #在maponly的任务结束时合并小文件
set hive.merge.mapred.files=true #true时在MapReduce的任务结束时合并小文件
set hive.merge.size.per.task=256*1000*1000 #合并文件的大小
set mapred.max.split.size=256*1024*1024 #每个Map最大分割大小
set mapred.min.split.size=128*1024*1024 #每个Map最小分割大小
set mapred.min.split.size.per.node=1 #一个节点上split的最少值
set hive.input.format=org.apache.hadoop.hive.ql.io.CombineHiveInputFormat #执行Map前进行小文件合并
CombineHiveInputFormat具有对小文件进行合并的功能（系统默认的格式）。HiveInputFormat没有对小文件合并功能。
4.3、复杂文件（增加map数）
1、处理方法
当input的文件都很大，任务逻辑复杂，map执行非常慢的时候，可以考虑增加Map数，来使得每个map处理的数据量减少，从而提高任务的执行效率。
增加map的方法为：根据computeSliteSize(Math.max(minSize,Math.min(maxSize,blocksize)))=blocksize=128M公式，调整maxSize最大值。让maxSize最大值低于blocksize就可以增加map的个数。
2、示例
# 未增加map数
hive> select count(*) from emp;
Hadoop job information for Stage-1: number of mappers: 1; number of reducers: 1
# 增加map数
hive> set mapreduce.input.fileinputformat.split.maxsize=100;
hive> select count(*) from emp;
Hadoop job information for Stage-1: number of mappers: 6; number of reducers: 1
五、采用压缩和适当的文件格式
1、合理利用文件存储格式
创建表时，尽量使用 orc、parquet 这些列式存储格式，因为列式存储的表，每一列的数据在物理上是存储在一起的，Hive查询时会只遍历需要列数据，大大减少处理的数据量。
2、压缩的原因
Hive 最终是转为 MapReduce 程序来执行的，而MapReduce 的性能瓶颈在于网络 IO 和 磁盘 IO，要解决性能瓶颈，最主要的是减少数据量，对数据进行压缩是个好的方式。压缩虽然是减少了数据量，但是压缩过程要消耗CPU的，但是在Hadoop中， 往往性能瓶颈不在于CPU，CPU压力并不大，所以压缩充分利用了比较空闲的 CPU
针对IO密集型的jobs(非计算密集型)可以使用压缩的方式提高性能
3、常用压缩方法对比
4、压缩的使用
- Job 输出文件按照 block 以 GZip 的方式进行压缩：
set mapreduce.output.fileoutputformat.compress=true // 默认值是 false
set mapreduce.output.fileoutputformat.compress.type=BLOCK // 默认值是 Record
set mapreduce.output.fileoutputformat.compress.codec=org.apache.hadoop.io.compress.GzipCodec // 默认值是 org.apache.hadoop.io.compress.DefaultCodec
- Map 输出结果也以 Gzip 进行压缩：
set mapred.map.output.compress=true
set mapreduce.map.output.compress.codec=org.apache.hadoop.io.compress.GzipCodec // 默认值是 org.apache.hadoop.io.compress.DefaultCodec
- 对 Hive 输出结果和中间都进行压缩：
set hive.exec.compress.output=true // 默认值是 false，不压缩
set hive.exec.compress.intermediate=true // 默认值是 false，为 true 时 MR 设置的压缩才启用
六、串行化（JVM重用）/并行化
6.1、JVM重用（串行化）
JVM重用是Hadoop调优参数的内容，其对Hive的性能具有非常大的影响，特别是对于很难避免小文件的场景或task特别多的场景，这类场景大多数执行时间都很短。
Hadoop的默认配置通常是使用派生JVM来执行map和Reduce任务的。这时JVM的启动过程可能会造成相当大的开销，尤其是执行的job包含有成百上千task任务的情况。JVM重用可以使得JVM实例在同一个job中重新使用N次。N的值可以在Hadoop的mapred-site.xml文件中进行配置。通常在10-20之间，具体多少需要根据具体业务场景测试得出。
有些文件很小，任务执行时间很短，如果为了执行规模较小的job而频繁地开启和关闭JVM，会浪费系统资源和时间
<property>
<name>mapreduce.job.jvm.numtasks</name>
<value>10</value>
<description>How many tasks to run per jvm. If set to -1, there is
no limit.
</description>
</property>
这个功能的缺点是，开启JVM重用将一直占用使用到的task插槽，以便进行重用，直到任务完成后才能释放。如果某个“不平衡的”job中有某几个reduce task执行的时间要比其他Reduce task消耗的时间多的多的话，那么保留的插槽就会一直空闲着却无法被其他的job使用，直到所有的task都结束了才会释放。
6.2、并行化
默认情况下，Hive一次只会执行一个阶段。不过，某个特定的job可能包含众多的阶段，而这些阶段可能并非完全互相依赖的，也就是说有些阶段是可以并行执行的，这样可能使得整个job的执行时间缩短。不过，如果有更多的阶段可以并行执行，那么job可能就越快完成。
一个总任务里存在N个小任务，而且这些小任务之间没有相互依赖关系，此时可以开启并行执行，缩短执行时间。系统资源比较空闲的时候才有优势，否则，没资源，并行也起不来。
通过设置参数hive.exec.parallel值为true，就可以开启并发执行。不过，在共享集群中，需要注意下，如果job中并行阶段增多，那么集群利用率就会增加。
set hive.exec.parallel=true; //打开任务并行执行
set hive.exec.parallel.thread.number=16; //同一个sql允许最大并行度，默认为8。
七、严格模式
Hive提供了一个严格模式，可以防止用户执行那些可能意向不到的不好的影响的查询。
通过设置属性hive.mapred.mode值为默认是非严格模式nonstrict 。开启严格模式需要修改hive.mapred.mode值为strict，开启严格模式可以禁止3种类型的查询。
<property>
<name>hive.mapred.mode</name>
<value>strict</value>
<description>
The mode in which the Hive operations are being performed.
In strict mode, some risky queries are not allowed to run. They include:
Cartesian Product.
No partition being picked up for a query.
Comparing bigints and strings.
Comparing bigints and doubles.
Orderby without limit.
</description>
</property>
1）对于分区表，除非where语句中含有分区字段过滤条件来限制范围，否则不允许执行。换句话说，就是用户不允许扫描所有分区。进行这个限制的原因是，通常分区表都拥有非常大的数据集，而且数据增加迅速。没有进行分区限制的查询可能会消耗令人不可接受的巨大资源来处理这个表。
2）对于使用了order by语句的查询，要求必须使用limit语句。因为order by为了执行排序过程会将所有的结果数据分发到同一个Reducer中进行处理，强制要求用户增加这个LIMIT语句可以防止Reducer额外执行很长一段时间。
3）限制笛卡尔积的查询。对关系型数据库非常了解的用户可能期望在执行JOIN查询的时候不使用ON语句而是使用where语句，这样关系数据库的执行优化器就可以高效地将WHERE语句转化成那个ON语句。不幸的是，Hive并不会执行这种优化，因此，如果表足够大，那么这个查询就会出现不可控的情况。
八、数据倾斜
8.1、小表、大表join
1、理论
将key相对分散，并且数据量小的表放在join的左边，这样可以有效减少内存溢出错误发生的几率；再进一步，可以使用Group让小的维度表（1000条以下的记录条数）先进内存。在map端完成reduce。
实际测试发现：新版的hive已经对小表JOIN大表和大表JOIN小表进行了优化。小表放在左边和右边已经没有明显区别。
2、示例演示
测试大表JOIN小表和小表JOIN大表的效率
# 建大表
create table bigtable(id bigint, time bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
# 建小表
create table smalltable(id bigint, time bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
# 建join后的表
create table jointable(id bigint, time bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
# 导入数据
hive> load data local inpath '/opt/datas/bigtable' into table bigtable;
hive> load data local inpath '/opt/datas/smalltable' into table smalltable;
# 关闭mapjoin功能（默认是打开的）
hive> set hive.auto.convert.join = false;
# 执行小表JOIN大表语句
insert overwrite table jointable
select b.id, b.time, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from smalltable s
left join bigtable b
on b.id = s.id;
----------------------------------------
Time taken: 35.921 seconds
----------------------------------------
# 执行大表JOIN小表语句
insert overwrite table jointable
select b.id, b.time, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from bigtable b
left join smalltable s
on s.id = b.id;
----------------------------------------
Time taken: 34.196 seconds；
----------------------------------------
8.2、大表join大表
1、空KEY过滤
有时join超时是因为某些key对应的数据太多，而相同key对应的数据都会发送到相同的reducer上，从而导致内存不够。此时我们应该仔细分析这些异常的key，很多情况下，这些key对应的数据是异常数据，我们需要在SQL语句中进行过滤。例如key对应的字段为空，操作如下：
（1）配置历史服务器
- 配置mapred-site.xml
<property>
<name>mapreduce.jobhistory.address</name>
<value>single:10020</value>
</property>
<property>
<name>mapreduce.jobhistory.webapp.address</name>
<value>single:19888</value>
</property>
- 启动历史服务器
[root@single sbin]# mr-jobhistory-daemon.sh start historyserver
- 查看jobhistory
浏览器输入 http://192.168.247.130:19888/jobhistory 进行访问
（2）创建原始数据表、空id表、合并后数据表
# 原始数据表
create table ori(id bigint, time bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
# 空id表
create table nullidtable(id bigint, time bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
# 合并后数据表
create table jointable(id bigint, time bigint, uid string, keyword string, url_rank int, click_num int, click_url string) row format delimited fields terminated by '\t';
# 加载数据
hive> load data local inpath '/opt/module/datas/ori' into table ori;
hive> load data local inpath '/opt/module/datas/nullid' into table nullidtable;
# 测试不过滤空id
hive> insert overwrite table jointable
select n.* from nullidtable n left join ori o on n.id = o.id;
---------------------------------------
Time taken: 42.038 seconds
# 测试过滤空id
hive> insert overwrite table jointable
select n.* from (select * from nullidtable where id is not null ) n left join ori o on n.id = o.id;
---------------------------------------
Time taken: 31.725 seconds
2、空KEY转换
有时虽然某个key为空对应的数据很多，但是相应的数据不是异常数据，必须要包含在join的结果中，此时我们可以表a中key为空的字段赋一个随机的值，使得数据随机均匀地分不到不同的reducer上。例如：
- 不随机分布空null值：
（1）设置5个reduce个数
set mapreduce.job.reduces = 5;
（2）JOIN两张表
insert overwrite table jointable
select n.* from nullidtable n left join ori b on n.id = b.id;
根据结果发现，出现了数据倾斜，某些reducer的资源消耗远大于其他reducer
- 随机分布空null值
（1）设置5个reduce个数
set mapreduce.job.reduces = 5;
（2）JOIN两张表
insert overwrite table jointable
select n.* from nullidtable n full join ori o on
case when n.id is null then concat('hive', rand()) else n.id end = o.id;
根据结果发现，消除了数据倾斜，负载均衡reducer的资源消耗
8.3、map join（默认已开启）
如果不指定MapJoin或者不符合MapJoin的条件，那么Hive解析器会将Join操作转换成Common Join，即：在Reduce阶段完成join，容易发生数据倾斜。可以用MapJoin把小表全部加载到内存在map端进行join，避免reducer处理。
MapJoin不走Reduce，数据在Map阶段落盘
（1）开启MapJoin参数设置：
- 设置自动选择Mapjoin
set hive.auto.convert.join = true; 默认为true
- 大表小表的阀值设置（默认25M以下认为是小表）：
set hive.mapjoin.smalltable.filesize=25000000;
（2）MapJoin工作机制
首先是Task A，它是一个Local Task（在客户端本地执行的Task），负责扫描小表b的数据，将其转换成一个HashTable的数据结构，并写入本地的文件中，之后将该文件加载到DistributeCache中。
接下来是Task B，该任务是一个没有Reduce的MR，启动MapTasks扫描大表a,在Map阶段，根据a的每一条记录去和DistributeCache中b表对应的HashTable关联，并直接输出结果。
由于MapJoin没有Reduce，所以由Map直接输出结果文件，有多少个Map Task，就有多少个结果文件。
（3）实例操作
- 开启Mapjoin功能
set hive.auto.convert.join = true; 默认为true
- 执行小表JOIN大表语句
insert overwrite table jointable
select b.id, b.time, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from smalltable s
join bigtable b
on s.id = b.id;
-----------------------------------------
Time taken: 24.594 seconds
- 执行大表JOIN小表语句
insert overwrite table jointable
select b.id, b.time, b.uid, b.keyword, b.url_rank, b.click_num, b.click_url
from bigtable b
join smalltable s
on s.id = b.id;
-----------------------------------------
Time taken: 24.315 seconds
8.4、Group By & 负载均衡
默认情况下，Map阶段同一Key数据分发给一个reduce，当一个key数据过大时就倾斜了。并不是所有的聚合操作都需要在Reduce端完成，很多聚合操作都可以先在Map端进行部分聚合，最后在Reduce端得出最终结果。
# 是否在Map端进行聚合，默认为True
set hive.map.aggr = true;
# 在Map端进行聚合操作的条目数目
set hive.groupby.mapaggr.checkinterval = 100000;
# 有数据倾斜的时候进行负载均衡（默认是false）
set hive.groupby.skewindata = true;
当选项设定为 true，生成的查询计划会有两个MR Job。第一个MR Job中，Map的输出结果会随机分布到Reduce中，每个Reduce做部分聚合操作，并输出结果，这样处理的结果是相同的Group By Key有可能被分发到不同的Reduce中，从而达到负载均衡的目的；第二个MR Job再根据预处理的数据结果按照Group By Key分布到Reduce中（这个过程可以保证相同的Group By Key被分布到同一个Reduce中），最后完成最终的聚合操作。
总而言之，第一个MR是做预汇总，第二个MR做最终汇总
—————————————————————————————————————
我们通过一个小案例来体会一下，当一个key数据过大时如何处理
hive> create table wordtest(word string,num int);
hive> insert into wordtest(word,num) values('a',1),('a',1),('a',1),('b',1),('b',1),('c',1),('c',1),('c',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1),('d',1);
如图可以看出，字段 word 中 ‘d’ 的数据量明显多于其他key
测试语句如下
with
alld as (select word,num,row_number() over() rn from wordtest where word='d'),
partd as (select rn%3 p,sum(num) total from alld group by rn%3),
joind as (select 'd' word,sum(total) from partd),
notd as (select word,sum(num) from wordtest where word<>'d' group by word)
select * from joind union all select * from notd;
查询结果
由于数据规模太小，体会不到优化，这个案例主要是了解一下如何实现group by优化
8.5、Count(Distinct)
数据量小的时候无所谓，数据量大的情况下，由于COUNT DISTINCT操作需要用一个Reduce Task来完成，这一个Reduce需要处理的数据量太大，就会导致整个Job很难完成，一般COUNT DISTINCT用sum…group by的方式替换
示例：
如果数据量非常大，执行如 ：
select a,count(distinct b) from t group by a;
可以使用 sum...group by 代替。
select a,sum(1) from (select a, b from t groupby a,b) group by a;
8.6、字段null值
在日志中，常会有信息丢失的问题，比如日志中的 user_id，如果取其中的 user_id 和用户表中的 user_id 相关联，就会碰到数据倾斜的问题。
解决方案 1：user_id 为空的不参与关联
select * from log a join user b on a.user_id is not null and a.user_id = b.user_id
解决方案 2： 赋予空值新的 key 值
select * from log a left outer join user b on
case when a.user_id is null then concat('hive',rand()) else a.user_id end = b.user_id
把空值的 key 变成一个字符串加上一个随机数，就能把造成数据倾斜的 数据分到不同的 reduce 上解决数据倾斜的问题。
8.7、数据类型不同
用户表中 user_id 字段为 int，log 表中 user_id 为既有 string 也有 int 的类型， 当按照两个表的 user_id 进行 join 操作的时候，默认的 hash 操作会按照 int 类型的 id 进 行分配，这样就会导致所有的 string 类型的 id 就被分到同一个 reducer 当中
解决方案：数据转型
select * from user a left outer join log b on b.user_id = cast(a.user_id as string)