转:http://blog.sina.com.cn/s/blog_4ca24203010128oe.html
ORA-24247: 网络访问被访问控制列表 (ACL) 拒绝
需要先使用 DBMS_NETWORK_ACL_ADMIN.CREATE_ACL 创建访问控制列表(ACL),
再使用 DBMS_NETWORK_ACL_ADMIN.ASSIGN_ACL 将此 ACL 与邮件服务器相关联,
最后使用 DBMS_NETWORK_ACL_ADMIN.ADD_PRIVILEGE 在此 ACL 为用户授与连接邮件服务器的权限。
BEGIN
DBMS_NETWORK_ACL_ADMIN.CREATE_ACL (
acl => 'email_server_permissions.xml',
description => 'Enables network permissions for the e-mail server',
principal => 'STAT',
is_grant => TRUE,
privilege => 'connect');
END;
/
BEGIN
DBMS_NETWORK_ACL_ADMIN.assign_acl (
acl => 'email_server_permissions.xml',
host => *.*.*.*, --SMTP服务器地址
lower_port => 25,
upper_port => NULL);
COMMIT;
END;
/
--drop
BEGIN
DBMS_NETWORK_ACL_ADMIN.drop_acl (
acl => 'email_server_permissions.xml');
COMMIT;
END;
/
--查询
SELECT host, lower_port, upper_port, acl
FROM dba_network_acls;
SELECT acl,
principal,
privilege,
is_grant,
TO_CHAR(start_date, 'DD-MON-YYYY') AS start_date,
TO_CHAR(end_date, 'DD-MON-YYYY') AS end_date
FROM dba_network_acl_privileges;
下面一个Oracle存储过程示例:
CREATE OR REPLACE PROCEDURE send_mail(p_recipient VARCHAR2 default '*', -- 邮件接收人
p_subject VARCHAR2 default 'Oracle邮件:'||to_char(sysdate,'yyyy-mm-dd hh24:mi:ss'),-- 邮件标题
p_message VARCHAR2 default 'Oracle邮件正文'
) IS
--下面四个变量请根据实际邮件服务器进行赋值
v_mailhost VARCHAR2(30) := '*.*.*'; --SMTP服务器地址
v_user VARCHAR2(30) := '*'; --登录SMTP服务器的用户名
v_pass VARCHAR2(20) := '*'; --登录SMTP服务器的密码
v_sender VARCHAR2(50) := '*'; --发送者邮箱,一般与 ps_user 对应
v_conn UTL_SMTP.connection; --到邮件服务器的连接
v_msg VARCHAR2(4000); --邮件内容
BEGIN
v_conn := UTL_SMTP.open_connection(v_mailhost, 25);
UTL_SMTP.helo(v_conn, v_mailhost); --有些服务器要用UTL_SMTP.ehlo() 来与服务器打招呼
UTL_SMTP.command(v_conn, 'AUTH LOGIN'); -- smtp服务器登录校验
UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_user))));
UTL_SMTP.command(v_conn,UTL_RAW.cast_to_varchar2(UTL_ENCODE.base64_encode(UTL_RAW.cast_to_raw(v_pass))));
UTL_SMTP.mail(v_conn, '<' || v_sender || '>'); --设置发件人
UTL_SMTP.rcpt(v_conn, '<' || p_recipient || '>'); --设置收件人
-- 创建要发送的邮件内容 注意报头信息和邮件正文之间要空一行
v_msg :='Date:'|| to_char(sysdate,'yyyy-mm-dd hh24:mi:ss')
|| UTL_TCP.CRLF || 'From: '|| v_sender || ''
|| UTL_TCP.CRLF || 'To: ' || p_recipient || ''
|| UTL_TCP.CRLF || 'Subject: ' || p_subject
|| UTL_TCP.CRLF || UTL_TCP.CRLF -- 这前面是报头信息
|| p_message; -- 这个是邮件正文
UTL_SMTP.open_data(v_conn); --打开流
UTL_SMTP.write_raw_data(v_conn, UTL_RAW.cast_to_raw(v_msg)); --这样写标题和内容都能用中文
UTL_SMTP.close_data(v_conn); --关闭流
UTL_SMTP.quit(v_conn); --关闭连接
dbms_output.put_line('邮件发送成功!');
EXCEPTION
WHEN OTHERS THEN
dbms_output.put_line('邮件发送失败!');
DBMS_OUTPUT.put_line(DBMS_UTILITY.format_error_stack);
DBMS_OUTPUT.put_line(DBMS_UTILITY.format_call_stack);
END send_mail;