我国现行使用公民身份证号码有两种尊循两个国家标准，〖GB 11643-1989〗和〖GB 11643-1999〗。
〖GB 11643-1989〗中规定的是15位身份证号码：排列顺序从左至右依次为：六位数字地址码，六位数字出生日期码，三位数字顺序码，其中出生日期码不包含世纪数。
〖GB 11643-1999〗中规定的是18位身份证号码：公民身份号码是特征组合码，由十七位数字本体码和一位数字校验码组成。排列顺序从左至右依次为：六位数字地址码，八位数字出生日期码，三位数字顺序码和一位数字校验码。
地址码表示编码对象常住户口所在县(市、旗、区)的行政区划代码。
生日期码表示编码对象出生的年、月、日，其中年份用四位数字表示，年、月、日之间不用分隔符。
顺序码表示同一地址码所标识的区域范围内，对同年、月、日出生的人员编定的顺序号。顺序码的奇数分给男性，偶数分给女性。
校验码是根据前面十七位数字码，按照ISO 7064:1983.MOD 11-2校验码计算出来的检验码。
公式如下：
∑(a[i]*W[i]) mod 11 ( i = 2, 3, ..., 18 ) (1)
"*" 表示乘号
i--------表示身份证号码每一位的序号，从右至左，最左侧为18，最右侧为1。
a[i]-----表示身份证号码第 i 位上的号码
W[i]-----表示第 i 位上的权值 W[i] = 2^(i-1) mod 11
计算公式 (1) 令结果为 R
根据下表找出 R 对应的校验码即为要求身份证号码的校验码C。
R 0 1 2 3 4 5 6 7 8 9 10
C 1 0 X 9 8 7 6 5 4 3 2
由此看出 X 就是 10，罗马数字中的 10 就是X，所以在新标准的身份证号码中可能含有非数字的字母X。
了解了以上知识后，请试着编写以下函数：
① 判断号码是否为正确的身份证号。要求，传入一个字符串（身份证号码），根据这个参数判断是否为正确的身份证号；如果正确则返回.t.，否则返回.f.。
算法分析：要判断一个身份证号正确与否，第一要从位数上进行判断：是否为15位或18位；第二要从包含的字符上进行判断：15位的全由数字组成，18位的除校验码外，全部也由数字组成；第三是要判断其中的出生日期码是否能转换成正确的日期；第四要判断18位的身份证号最后一位是不是真正的校证码，如果上面四个条件都满足，则是正确的身份证号。
② 从身份证号码中获得出生日期。要求，传入一个字符串（身份证号码），首先判断这个参数是否为正确的身份证号码；若错误则返回空串，否则，再计算出生日期，并以yyyy.mm.dd这种格式返回字符的日期值。
算法分析：判断身份证号码正确后，根据位数取子串，如果是15位的，则取第7至12位，在年份数前加上19(因为只有早期的身份证才是上个世纪的，2000后出生的人一般都是用的18位）；如果是18位的，则直接取第7至14位；最后转换为yyyy.mm.dd的格式。
③ 从身份证号码中获得性别。要求，传入一个字符串（身份证号码），首先判断这个参数是否为正确的身份证号码；若错误则返回空串，否则，再计算其性别；如果是男生，则返回字符”1”，如果是女生则返回字符”0”。
算法分析：判断身份证号码正确后，根据位数取子串，如果是15位的，则取最后一位；如果是18位的号，则取倒数第位；最后判断取出来的数值的奇偶性即可。
④ 将15位身份证号转换成18位身份证号。要求，传入一个字符串（身份证号码），首先判断这个参数是否为正确的15位身份证号；如果错误则返回空串，否则，再计算出正确的18位身份证号码，并返回字符型的号码。
算法分析：关键有三，一是验证是正确的身份证号；二是要把6位日期码转换为8位日期码；三是计算出校证码。
⑤ 最后，把以上数个程序写在一个过程文件中，文件名为：ex15_1.prg。
FUNCTION sfzyn
* 这个函数用来检验是否为合法的身份证号码
LPARAMETERS lstr &&参数:lstr 传入的号码
LOCAL lstr,relyn,tsfz
LOCAL m1,m2,m3,m4,m,i,r,c,ai,wi
SET TALK OFF
SET DATE TO ANSI
SET CENT ON
relyn=.F. &&返回值
tsfz=ALLT(lstr)
*分别用m1,m2,m3,m4表示四个条件是否成立
STOR .T. TO m1,m2,m3,m4
*条件1：只能是15或18位
m1=IIF(LEN(tsfz)=15 OR LEN(tsfz)=18,.T.,.F.)
IF LEN(tsfz)=15 && 15位的号码
FOR i=1 TO 15 &&检查每一位是否为数字
m=ASC(SUBS(tsfz,i,1))
IF m<48 OR m>57 &&数字
m2=.F. &&若有一位不是就不再查
EXIT
ENDIF
ENDFOR
m="19" +SUBS(tsfz, 7,2) &&早期的号都是上个世纪的
m=m+"."+SUBS(tsfz, 9,2)
m=m+"."+SUBS(tsfz,11,2)
m=CTOD(m)
IF ISNULL(m) OR isblank(m)
m3=.F. &&生日不正确
ENDIF
ENDIF
IF LEN(tsfz)=18 && 18位的号码
FOR i=1 TO 17
m=ASC(SUBS(tsfz,i,1))
IF m<48 OR m>57
m2=.F.
EXIT
ENDIF
ENDFOR
m=SUBS(tsfz,7,4)
m=m+"."+SUBS(tsfz,11,2)
m=m+"."+SUBS(tsfz,13,2)
m=CTOD(m)
IF ISNULL(m) OR isblank(m)
m3=.F.
ENDIF
r=0 &&计算校验位
FOR i=18 TO 2 STEP -1
ai=VAL(SUBS(tsfz,19-i,1))
wi=MOD(2^(i-1),11)
r=r+ai*wi
NEXT
r=MOD(r,11)
DO CASE
CASE r=0
c="1"
CASE r=1
c="0"
CASE r=2
c="X"
OTHER
c=ALLTRIM(STR(12-r))
ENDCASE
IF UPPE(SUBS(tsfz,18,1))<>c
m4=.F. &&校验位与原码最末位不同
ENDIF
ENDIF
*四个条件全成立，则返回.t.
relyn=IIF(m1 AND m2 AND m3 AND m4,.T.,.F.)
RETU relyn
ENDFUN
FUNCTION sfzrq
* 这个函数用来获取身份证号中的出生日期
LPARAMETERS lstr &&参数:lstr 传入的号码
SET TALK OFF
LOCAL lstr,relyn,tsfz,m
relyn=""
m=""
tsfz=ALLT(lstr)
IF sfzyn(tsfz) &&是正确的身份证号
IF LEN(tsfz)=15
m="19"+SUBS(tsfz, 7,2)
m=m+"."+SUBS(tsfz, 9,2)
m=m+"."+SUBS(tsfz,11,2)
ELSE
m=SUBS(tsfz,7,4)
m=m+"."+SUBS(tsfz,11,2)
m=m+"."+SUBS(tsfz,13,2)
ENDIF
relyn=m
ENDIF
RETU relyn
ENDFUN
FUNCTION sfzsex
* 这个函数用来获取身份证号中的性别
LPARAMETERS lstr &&参数:lstr 传入的号码
SET TALK OFF
LOCAL lstr,relyn,tsfz,m
relyn=""
m=""
tsfz=ALLT(lstr)
IF sfzyn(tsfz) &&是正确的身份证号 m=IIF(LEN(tsfz)=15,SUBS(tsfz,15,1),SUBS(tsfz,17,1))
m=IIF(m$"24680","0", "1") &&偶数为女性,奇数为男性
relyn=m
ENDIF
RETU relyn
ENDFUN
FUNCTION sfzto18
* 将15位的转换为18位身份证号
LPARAMETERS lstr &&参数:lstr 传入的号码
SET TALK OFF
LOCAL lstr,relyn,tsfz,m
relyn=""
m=""
tsfz=ALLT(lstr)
IF sfzyn(tsfz) &&是正确的身份证号
IF LEN(tsfz)=15
m=SUBS(tsfz,1,6)
m=m+"19"+SUBS(tsfz, 7,2)
m=m+SUBS(tsfz, 9,2)
m=m+SUBS(tsfz,11,2)
m=m+SUBS(tsfz,13,3) &&得到前17位
r=0 &&计算校验位
FOR i=18 TO 2 STEP -1
ai=VAL(SUBS(m,19-i,1))
wi=MOD(2^(i-1),11)
r=r+ai*wi
NEXT
r=MOD(r,11)
DO CASE
CASE r=0
c="1"
CASE r=1
c="0"
CASE r=2
c="X"
OTHER
c=ALLTRIM(STR(12-r))
ENDCASE
m=m+c
ELSE &&如果本身就是18位的身份证号，
m=tsfz &&则就返回原值
ENDIF
relyn=m
ENDIF
RETU relyn
ENDFUN
