PL/SQL Record数据类型

Oracle PL / SQL语言旨在成为一种可移植的高性能事务处理语言，与SQL语言紧密集成。实际上，很难找到一个PL / SQL程序，它既不会读取数据库中的表，也不会对数据库中的表进行更改。表由数据行组成，每行包含一列或多列，因此Oracle数据库可以尽可能简单地使用PL / SQL程序中的那些数据行。它正是通过实施记录来实现的。

Record是一种复合数据类型，这意味着与标量数据类型（如数字或字符串）相比，它可以容纳多条信息。事实上，很少有您使用的数据只是一个值，因此Record和其他复合数据类型可能在您的PL / SQL程序中占据显着位置。

使用％ROWTYPE声明Record

PL / SQL通过提供％ROWTYPE属性，可以很容易地声明与游标的表，视图或结果集具有相同结构的记录。

假设我在应用程序中有一个雇员表，如下所示：

SQL> DESCRIBE omag_employees
 Name         Null?      Type
 ———————————  —————————— —————————————————
 EMPLOYEE_ID  NOT NULL   NUMBER(38)
 LAST_NAME               VARCHAR2(100)
 SALARY                  NUMBER

表中的每一行由三列组成，每列都有自己的数据类型。以下查询检索表中所有行的所有列：

SELECT employee_id，last_name，salary FROM omag_employees

编写一个代码块，从omag_employees中检索员工ID的单行数据，然后使用该行中的列值。可以为每列声明一个变量，然后获取这些变量，如下所示：

CREATE PROCEDURE process_employee (
  employee_id_in IN 
    omag_employees.employee_id%TYPE)
IS
  l_employee_id   
     omag_employees.employee_id%TYPE;
  l_last_name     
     omag_employees.last_name%TYPE;
  l_salary        
     omag_employees.salary%TYPE;
BEGIN
  SELECT employee_id,
         last_name,
         salary
    INTO l_employee_id,
         l_last_name,
         l_salary
    FROM omag_employees
  WHERE employee_id = employee_id_in;
END;
    注意:在参数中使用后缀来表示它们的模式。这里_in表示IN参数。

然而，这是一大堆用于编写，读取和维护的代码。更好的方法是将该行数据提取到记录中，声明该记录的最佳方法如下：

CREATE PROCEDURE process_employee (
  employee_id_in IN 
     omag_employees.employee_id%TYPE)
IS
  l_employee   omag_employees%ROWTYPE;
BEGIN
  SELECT employee_id,
         last_name,
         salary
    INTO l_employee
    FROM omag_employees
  WHERE employee_id = employee_id_in;
END;

编译此过程时，PL / SQL将查找omag_employees表的结构，并定义一个记录，该记录具有表中每列的字段，具有相同的名称和数据类型。通过使用％ROWTYPE来声明记录，我还告诉Oracle数据库该过程依赖于 omag_employees表。例如，如果数据库管理员将last_name列的最大长度更改为200，则此Procedure的状态将更改为INVALID。重新编译Procedure时，编译器将更新此Procedure中记录的定义以匹配表的新结构。

甚至可以进一步缩短和写作:

CREATE PROCEDURE process_employee (
  employee_id_in IN 
     omag_employees.employee_id%TYPE)
IS
  l_employee   omag_employees%ROWTYPE;
BEGIN
  SELECT *
    INTO l_employee
    FROM omag_employees
   WHERE employee_id = employee_id_in;
END;

SELECT *语法告诉Oracle数据库获取表中的所有列。

还可以使用％ROWTYPE声明一个与游标中的SELECT语句具有相同结构的记录。这对于从表中获取列的子集或从多个表中获取列特别有用。这是一个例子：

DECLARE
   CURSOR no_ids_cur
   IS
      SELECT last_name, salary
        FROM omag_employees;

   l_employee   no_ids_cur%ROWTYPE;
    注意:通常在明确声明的游标的名称后面添加一个“_cur”后缀。

无论何时从光标向PL / SQL变量中提取数据，都应该使用％ROWTYPE基于该游标声明记录并获取该记录。这样，当光标的SELECT列表发生变化时，记录中字段的数量和类型将相应地改变，一切都将保持同步。

为何生存

发布了50 篇原创文章 · 获赞 64 · 访问量 4万+

私信关注

PL/SQL Record数据类型

猜你喜欢