一.保护模式中的特权级(上)
A.保护模式小结
a.使用选择子访问段描述符表时,索引值的合法性检测
1.当索引值越界时,引发+异常
2.判断的规则是:索引值 x8+7<=段描述表界限值
b.内存段类型合法检测性
1.具备可执行属性的段(代码段)只能加载到CS寄存器
2.具备可写属性的段(数据段)才能加载到SS寄存器
3.具备只读属性的段才能加载到DS,ES,FS,GS寄存器
c.代码段和数据段的保护
1.处理器每访问一个地址都要确认该地址不超过界限值
2.判断规则:代码段:IP+指令长度<=代码段界限;数据段:访问起始地址+访问数据长度<=数据段界限
在这里需要注意的是:保护模式中代码中定义的界限值通常为:最大偏移地址值(相对于段基地址)
d.代码示例
%include "inc.asm"
org 0x9000
jmp ENTRY_SEGMENT
[section .gdt]
; GDT definition
; ¶Î»ùÖ·£¬ ¶ÎœçÏÞ£¬ ¶ÎÊôÐÔ
GDT_ENTRY : Descriptor 0, 0, 0
CODE32_DESC : Descriptor 0, Code32SegLen - 1, DA_C + DA_32
VIDEO_DESC : Descriptor 0xB8000, 0x07FFF, DA_DRWA + DA_32
DATA32_DESC : Descriptor 0, Data32SegLen - 1, DA_DR + DA_32
STACK32_DESC : Descriptor 0, TopOfStack32, DA_DRW + DA_32
; GDT end
GdtLen equ $ - GDT_ENTRY
GdtPtr:
dw GdtLen - 1
dd 0
; GDT Selector
Code32Selector equ (0x0001 << 3) + SA_TIG + SA_RPL0
VideoSelector equ (0x0002 << 3) + SA_TIG + SA_RPL0
Data32Selector equ (0x0003 << 3) + SA_TIG + SA_RPL0
Stack32Selector equ (0x0004 << 3) + SA_TIG + SA_RPL0
ExceptionSelector equ (0x0005 << 3) + SA_TIG + SA_RPL0
; end of [section .gdt]
TopOfStack16 equ 0x7c00
[section .dat]
[bits 32]
DATA32_SEGMENT:
DTOS db "D.T.OS!", 0
DTOS_OFFSET equ DTOS - $$
Data32SegLen equ $ - DATA32_SEGMENT
[section .s16]
[bits 16]
ENTRY_SEGMENT:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, TopOfStack16
; initialize GDT for 32 bits code segment
mov esi, CODE32_SEGMENT
mov edi, CODE32_DESC
call InitDescItem
mov esi, DATA32_SEGMENT
mov edi, DATA32_DESC
call InitDescItem
mov esi, STACK32_SEGMENT
mov edi, STACK32_DESC
call InitDescItem
; initialize GDT pointer struct
mov eax, 0
mov ax, ds
shl eax, 4
add eax, GDT_ENTRY
mov dword [GdtPtr + 2], eax
; 1. load GDT
lgdt [GdtPtr]
; 2. close interrupt
cli
; 3. open A20
in al, 0x92
or al, 00000010b
out 0x92, al
; 4. enter protect mode
mov eax, cr0
or eax, 0x01
mov cr0, eax
; 5. jump to 32 bits code
jmp dword ExceptionSelector : 0
; esi --> code segment label
; edi --> descriptor label
InitDescItem:
push eax
mov eax, 0
mov ax, cs
shl eax, 4
add eax, esi
mov word [edi + 2], ax
shr eax, 16
mov byte [edi + 4], al
mov byte [edi + 7], ah
pop eax
ret
[section .s32]
[bits 32]
CODE32_SEGMENT:
mov ax, VideoSelector
mov gs, ax
mov ax, Stack32Selector
mov ss, ax
mov eax, TopOfStack32
mov esp, eax
mov ax, Data32Selector
mov ds, ax
mov ebp, DTOS_OFFSET
mov bx, 0x0C
mov dh, 12
mov dl, 33
call PrintString
jmp $
; ds:ebp --> string address
; bx --> attribute
; dx --> dh : row, dl : col
PrintString:
push ebp
push eax
push edi
push cx
push dx
print:
mov cl, [ds:ebp]
cmp cl, 0
je end
mov eax, 80
mul dh
add al, dl
shl eax, 1
mov edi, eax
mov ah, bl
mov al, cl
mov [gs:edi], ax
inc ebp
inc dl
jmp print
end:
pop dx
pop cx
pop edi
pop eax
pop ebp
ret
Code32SegLen equ $ - CODE32_SEGMENT
[section .gs]
[bits 32]
STACK32_SEGMENT:
times 1024 * 4 db 0
Stack32SegLen equ $ - STACK32_SEGMENT
TopOfStack32 equ Stack32SegLen - 1
对之前的代码进行修改
可以看出增加了一个选择子,而在全局段描述表中没有相对应得小标为5得段描述符,然后在进入32位保护模式下使用这个选择子,运行得结果如图所示
会发现在运行bochs并没有打印出之前的打印结果,同时还出现了错误,出现错误的原因是在进入保护模式时会选择ExceptionSelector这个选择子所对应的描述符来找到跳转目标,在跳转之前,处理器将索引值进行判断是否在段描述符表界限值之内,发现大于界限值,产生了异常
e.接下来对段描述定的DA_C可执行属性改成DA_DR只读属性
会发现运结果没有打印同时出现了异常,出现错误的原因是对加载到CS寄存器的段要有可执行属性,在这里将其改成了只读属性,所以出现错误。
B.保护模式中的特权级
1.x86架构中的保护模式提供了4个特权级(0,1,2,3)
2.特权级从高到底分别是0,1,2,3(数字越大特权级越低)
a.特权级的表现形式
CPL-当前可执行代码段的特权级,由CS寄存器最低2位定义
DPL-内存段的特权级,在段描述符表中定义
RPL-选择子的特权级,由选择子最低2位定义
段描述符表中的DPL用于标识内存段的特权级,可执行代码访问内存段时必须满足一定特权级(CPL),否则,处理器将产生异常
b.CPL和DPL的关系
1.保护模式下,每一个代码段都定义了一个DPL
2.当处理器从A代码段成功跳转到B代码段执行
3.保护模式中,每一个数据段都定义了一个DPL,当处理器指向过程中需要访问数据段时
段描述符中的DPL常量定义
实验-保护模式特权级初探
首先将代码中加入一个特权级如下图所示
运行结果如图所示,发现出现错误,出现错误的原因是如图所示会发现上图提示的错误是dpl!=cpl,dpl=3,cpl=0,可以推出进入保护模式之后cpl=0,从cpl=0跳转到dpl=3的代码段出现错误
可以看到将DPL特权级改为0发现代码通过从cpl=0跳转到dpl=0的代码是可行的
接下来在选择子中进行改变看代码是否通过
会发现出现错误,在这里可以知道处理器进行保护判断时会考虑RPL
实验结论
1.处理器进入保护模式后CPL=0
2.处理器不能直接从高特权级转换到底特权级执行
3.选择子RPL大于对应段描述符的DPL时,产生异常
从这几次的实验引出的问题
1.如何在不同特权级的代码段之间跳转执行?
2.高特权级代码为什么不能使用底特权级?
3.选择子的RPL具体有什么用?
小结
1.保护模式对内存的访问范围有严格定义
2.保护模式定义了内存段的特权级(0,1,2,3)
a.每个内存段都有固定的特权级
b.不同代码之间成功跳转后CPL可能发生改变
c.CPL小于或等于数据段DPL才能成功访问数据