模型身上流光效果有两种实现方式
1.用摄像机来算流光位置，不过这种比较固定，而且只能在展示用，战斗里面不太适用
2.用一张流光图来进行uv位置计算发光位置和原来的贴图进行颜色叠加，这个不用管摄像机位置，不过对uv要求高，所以做之前确定效果再来进行uv布局，不然效果和你想象不一样
我这里主要说第二种的实现方式
先看看效果图这个有mask图的流光效果，这个mask图是来区分那些部位要流光
下面是没有mask图，因为这些资源都是官网下载的美术资源所以uv布局不是一个方向，所以整个流光感觉很乱
这个是我项目的效果图，要流光效果好就加个bloom效果
实现
1.流光图
以这张流光图为例，根据时间偏移uv的x轴获取对应的颜色（因为这里是黑白图所以获取rgb随意一个通道出来进行处理）和模型原图叠加就可以实现颜色变亮
2.遮罩图（用于显示流光部分）
这个遮罩图用于区分哪些地方显示流光，我这里用蓝色通道作为流光显示部位（没理由一种效果一张图，流光用蓝色通道，其他效果用其他通道来进行判断，这样子不会有太多图片导致内存问题）
最终输出颜色 = 原图颜色 + 流光图蓝色通道值*流光颜色*遮罩图蓝色通道值
3.shader
我这个流光是用标准材质球写的
主要算法
//计算流光宽度uv坐标越少，则获取白色流光图白色区域越大，就等于流光长度
float2 uv = IN.uv_MainTex / _LightWidth;
//流光图y轴偏移
uv.y += _Time.y * _SpeedY;
//流光图x轴偏移
uv.x += _Time.y * _SpeedX;
//获取流光图的蓝色通道，因为流光图都是黑白，获取红色绿色通道都可以
fixed light = tex2D(_LightTex, uv).b;
//获取要显示流光的位置，我这里使用蓝色通道来处理，我这边不用alpha来处理，因为透明图占内存
fixed maskb = tex2D(_MaskTex, IN.uv_MainTex).b;
//这里算出要流光的地方叠加颜色
fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color + light * _MoveLightColor * maskb;完整shader
Shader "Custom/moveLight 1" {
Properties {
_Color ("Color", Color) = (1,1,1,1)
_MainTex ("Albedo (RGB)", 2D) = "white" {}
_Glossiness ("Smoothness", Range(0,1)) = 0.5
_Metallic ("Metallic", Range(0,1)) = 0.0
//流光图
_LightTex("Light Texture",2D) = "white"{}
//遮罩图
_MaskTex("Mask Texture",2D) = "white"{}
//流光颜色
_MoveLightColor("MoveLightColor", Color) = (1,1,1,1)
//流光uv x轴速度
_SpeedX("SpeedX", Range(-1,1)) = 0.0
//流光uv y轴速度
_SpeedY("SpeedY", Range(-1,1)) = 0.0
//流光宽度
_LightWidth("LightWidth",Range(1,20)) = 1
}
SubShader {
Tags { "RenderType"="Opaque" }
LOD 200
CGPROGRAM
// Physically based Standard lighting model, and enable shadows on all light types
#pragma surface surf Standard fullforwardshadows
// Use shader model 3.0 target, to get nicer looking lighting
#pragma target 3.0
sampler2D _MainTex;
sampler2D _LightTex;
sampler2D _MaskTex;
float4 _MoveLightColor;
float _SpeedY;
float _SpeedX;
float _LightWidth;
struct Input
{
float2 uv_MainTex;
};
half _Glossiness;
half _Metallic;
fixed4 _Color;
// Add instancing support for this shader. You need to check 'Enable Instancing' on materials that use the shader.
// See https://docs.unity3d.com/Manual/GPUInstancing.html for more information about instancing.
// #pragma instancing_options assumeuniformscaling
UNITY_INSTANCING_BUFFER_START(Props)
// put more per-instance properties here
UNITY_INSTANCING_BUFFER_END(Props)
void surf (Input IN, inout SurfaceOutputStandard o)
{
//计算流光宽度uv坐标越少，则获取白色流光图白色区域越大，就等于流光长度
float2 uv = IN.uv_MainTex / _LightWidth;
//流光图y轴偏移
uv.y += _Time.y * _SpeedY;
//流光图x轴偏移
uv.x += _Time.y * _SpeedX;
//获取流光图的蓝色通道，因为流光图都是黑白，获取红色绿色通道都可以
fixed light = tex2D(_LightTex, uv).b;
//获取要显示流光的位置，我这里使用蓝色通道来处理，我这边不用alpha来处理，因为透明图占内存
fixed maskb = tex2D(_MaskTex, IN.uv_MainTex).b;
//这里算出要流光的地方叠加颜色
fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color + light * _MoveLightColor * maskb;
o.Albedo = c.rgb;
// Metallic and smoothness come from slider variables
o.Metallic = _Metallic;
o.Smoothness = _Glossiness;
o.Alpha = c.a;
}
ENDCG
}
FallBack "Diffuse"
}
下面是工程地址
链接：https://pan.baidu.com/s/10Uq_hd6oHWA-35FtX8EzTA
提取码：9hal