前言
刚修复了一个demo的安装程序卸载不干净的bug,安装程序是NSIS做的。
整理了一个NSIS工程模板,以后留着玩。
NSIS帮助文件做的挺好的,API的用法也是各种例子。
NSIS比installshield用起来简单多了。只需要编辑安装脚本的.nsi文件,不需要IDE支持。
NSIS模板
; @file NSIS_project_template.nsi
; @brief NSIS工程模板, build ok on NSIS_3.03
; 安装程序初始定义常量
!define PRODUCT_NAME "my_proc"
!define PRODUCT_VERSION "1.0.0.1"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"
SetCompressor lzma
!include "MUI.nsh"
; MUI 预定义常量
!define MUI_ABORTWARNING
!define MUI_ICON "${NSISDIR}\Contrib\Graphics\Icons\modern-install.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"
; 欢迎页面
!insertmacro MUI_PAGE_WELCOME
; 安装目录选择页面
!insertmacro MUI_PAGE_DIRECTORY
; 安装过程页面
!insertmacro MUI_PAGE_INSTFILES
; 安装完成页面
!insertmacro MUI_PAGE_FINISH
; 安装卸载过程页面
!insertmacro MUI_UNPAGE_INSTFILES
; 安装界面包含的语言设置
!insertmacro MUI_LANGUAGE "SimpChinese"
; 安装预释放文件
!insertmacro MUI_RESERVEFILE_INSTALLOPTIONS
Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "install_${PRODUCT_NAME}_${PRODUCT_VERSION}.exe"
InstallDir "$PROGRAMFILES\${PRODUCT_NAME}"
ShowInstDetails show
ShowUnInstDetails show
Section "MainSection" SEC01
SetOutPath "$INSTDIR"
SetOverwrite on
File /r ".\for_install\*.*"
SectionEnd
Section -AdditionalIcons
CreateDirectory "$INSTDIR"
CreateShortCut "$INSTDIR\Uninstall.lnk" "$INSTDIR\uninst.exe"
SectionEnd
Section -Post
WriteUninstaller "$INSTDIR\uninst.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
ExecWait "$INSTDIR\my_service.exe"
Sleep 100
ExecWait "$INSTDIR\3rd_install.exe -i"
Sleep 100
ExecWait "$INSTDIR\3rd_install.exe -s"
Sleep 100
SectionEnd
Section Uninstall
; 停掉服务
ExecWait "$INSTDIR\my_service.exe -k"
Sleep 1000
ExecWait "$INSTDIR\my_service.exe -u"
Sleep 1000
; 停掉已经运行的程序
ExecWait "$INSTDIR\process_killer.exe my_service.exe"
Sleep 10
ExecWait "$INSTDIR\process_killer.exe my_prog.exe"
Sleep 10
; 卸载第三方的组件, 卸载程序的全路径在注册表里面
; key = 计算机\HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\3rd_install
; value = UninstallString REG_SZ
; data = C:\Program Files (x86)\3rd\uninstall.exe
; Usage: ReadRegStr $(user_var: output) rootkey subkey entry root_key=(HKCR[32|64]|HKLM[32|64]|HKCU[32|64]|HKU|HKCC|HKDD|HKPD|SHCTX)
ReadRegStr $0 HKLM SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\3rd_install UninstallString
ExecWait $0
Sleep 1000
Delete "$INSTDIR\Uninstall.lnk"
Delete "$INSTDIR\readme.txt"
Delete "$INSTDIR\process_killer.exe"
; Delete other files on $INSTDIR
RMDir /r "$INSTDIR"
DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"
SetAutoClose true
SectionEnd
Function un.onInit
; (MB_ABORTRETRYIGNORE|MB_OK|MB_OKCANCEL|MB_RETRYCANCEL|MB_YESNO|MB_YESNOCANCEL|MB_ICONEXCLAMATION|MB_ICONINFORMATION|MB_ICONQUESTION|MB_ICONSTOP|MB_USERICON|MB_TOPMOST|MB_SETFOREGROUND|MB_RIGHT
MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "您确实要完全移除 $(^Name) ,及其所有的组件?" IDYES +2
Abort
FunctionEnd
Function un.onUninstSuccess
HideWindow
MessageBox MB_ICONINFORMATION|MB_OK "$(^Name) 已成功地从您的计算机移除。"
FunctionEnd