hive表导入数据的几种方式

今天在做hive数据迁移到hbase的测试的时候，建了hive表，然后将HDFS中的数据导入hive表中，后面还需要用到该数据，却发现原来HDFS路径下的文件消失了，当时一脸懵B，琢磨了好久，还是没想明白是怎么回事。于是上网百度了一波，最后发现原来是hive内部表导入hdfs数据的时候执行的是移动操作，就是将原来hdfs路径下的数据文件移动到hive的warehouse目录下。

以前学习hive的时候这些知识点应该是涉及到的，但是时间久了没有用就会忘记，今天借这个机会来复习一下相关知识。

下面总结一下hive表导入数据的四种方式：

（1）、从本地文件系统中导入数据到Hive表；
（2）、从HDFS上导入数据到Hive表；
（3）、从别的表中查询出相应的数据并导入到Hive表中；
（4）、在创建表的时候通过从别的表中查询出相应的记录并插入到所创建的表中。

一、从本地文件系统中导入数据到Hive表

先在hive里面创建好表，脚本如下：

hive> create table test1
    > (
    > id int,
    > name string,
    > age int,
    > ROW FORMAT DELIMITED
    > FIELDS TERMINATED BY '\t'
    > STORED AS TEXTFILE;
OK
Time taken: 2.802 seconds

本地文件系统中test1的路径为：/home/test/test1.txt

导入数据到test1表中的语句如下：

hive> load data local inpath '/home/test/test1.txt' into table test1;

Copying data from file:/home/test/test1.txt
Copying file: file:/home/test/test1.txt
Loading data to table default.test1
Table default.test1 stats:
[num_partitions: 0, num_files: 1, num_rows: 0, total_size: 67]
OK
Time taken: 5.967 seconds

从本地文件系统中将数据导入到Hive表的过程中，其实是先将数据临时复制到HDFS的一个目录下（典型的情况是复制到上传用户的HDFS home目录下,比如/home/test/），然后再将数据从那个临时目录下移动（注意，这里说的是移动，不是复制！）到对应的Hive表的数据目录里面。

需要注意的是：

和我们熟悉的关系型数据库不一样，Hive现在还不支持在insert语句里面直接给出一组记录的文字形式，也就是说，Hive并不支持INSERT INTO …. VALUES形式的语句。

二、HDFS上导入数据到Hive表

文件是存放在HDFS上/home/test目录（和一中提到的不同，一中提到的文件是存放在本地文件系统上）里面，我们可以通过下面的命令将这个文件里面的内容导入到Hive表中，具体操作如下：

hive> load data inpath '/home/test/test1.txt' into table test1;

Loading data to table default.test1
Table default.test1 stats:
[num_partitions: 0, num_files: 2, num_rows: 0, total_size: 215]
OK
Time taken: 0.47 seconds

执行完导入数据的操作之后，你会发现原来的hdfs目录下的test1.txt文件消失了。原因是hive内部表导入hdfs数据文件的时候执行的是移动操作，而不是复制操作。

如果需要保留原来hdfs目录下的文件，那么就只能在创建hive表的时候将其创建为外部表，外部表在导入hdfs目录下的数据的时候只是将hdfs路径保存到hive表的元数据信息中，并没有真正的移动数据。

三、从别的表中查询出相应的数据并导入到Hive表中

假设Hive中有test表，其建表语句如下所示：

hive> create table test(
    > id int, 
    > name string
    > )
    > partitioned by
    > (age int)
    > ROW FORMAT DELIMITED
    > FIELDS TERMINATED BY '\t'
    > STORED AS TEXTFILE;
OK
Time taken: 0.261 seconds

大体和test1表的建表语句类似，只不过test表里面用age作为了分区字段。对于分区，这里在做解释一下：

分区：在Hive中，表的每一个分区对应表下的相应目录，所有分区的数据都是存储在对应的目录中。比如wyp表有dt和city两个分区，则对应dt=20131218,city=BJ对应表的目录为/user/hive/warehouse/dt=20131218/city=BJ，所有属于这个分区的数据都存放在这个目录中。

下面语句就是将test1表中的查询结果并插入到test表中：

hive> insert into table test
    > partition (age='25')
    > select id, name
    > from test1;

通过上面的输出，我们可以看到从test1表中查询出来的东西已经成功插入到test表中去了！如果目标表（test）中不存在分区字段，可以去掉partition (age=’25′)语句。当然，我们也可以在select语句里面通过使用分区值来动态指明分区：

hive> set hive.exec.dynamic.partition.mode=nonstrict;
hive> insert into table test
    > partition (age)
    > select id, name,age
    > from test1;

这种方法叫做动态分区插入，但是Hive中默认是关闭的，所以在使用前需要先把hive.exec.dynamic.partition.mode设置为nonstrict。当然，Hive也支持insert overwrite方式来插入数据，从字面我们就可以看出，overwrite是覆盖的意思，是的，执行完这条语句的时候，相应数据目录下的数据将会被覆盖！而insert into则不会，注意两者之间的区别。例子如下：

hive> insert overwrite table test
    > PARTITION (age)
    > select id, name, age
    > from test1;

更可喜的是，Hive还支持多表插入，什么意思呢？在Hive中，我们可以把insert语句倒过来，把from放在最前面，它的执行效果和放在后面是一样的，如下：

hive> show create table test3;
OK
CREATE  TABLE test3(
  id int,
  name string)
Time taken: 0.277 seconds, Fetched: 18 row(s)

hive> from test1
    > insert into table test
    > partition(age)
    > select id, name, age
    > insert into table test3
    > select id, name
    > where age>25;

可以在同一个查询中使用多个insert子句，这样的好处是我们只需要扫描一遍源表就可以生成多个不相交的输出。

四、在创建表的时候通过从别的表中查询出相应的记录并插入到所创建的表中

在实际情况中，表的输出结果可能太多，不适于显示在控制台上，这时候，将Hive的查询输出结果直接存在一个新的表中是非常方便的，我们称这种情况为CTAS（create table .. as select）如下：

hive> create table test4
    > as
    > select id, name
    > from test1;

数据就插入到test4表中去了，CTAS操作是原子的，因此如果select查询由于某种原因而失败，新表是不会创建的！