Hive 数据定义DDL详解

版权声明：本文为博主原创文章，未经博主允许不得转载。 https://blog.csdn.net/Luomingkui1109/article/details/82056623

1.创建数据库

(1) 创建一个数据库，数据库在HDFS上的默认存储路径是/user/hive/warehouse/*.db。

    hive (default)> create database db_hive;

(2) 避免要创建的数据库已经存在错误，增加if not exists判断。（标准写法）

hive> create database db_hive;

FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. Database db_hive already exi

Sts

hive (default)> create database if not exists db_hive;

(3) 创建一个数据库，指定数据库在HDFS上存放的位置

hive (default)> create database db_hive2 location '/db_hive2.db';

2.修改数据库

    用户可以使用ALTER DATABASE命令为某个数据库的DBPROPERTIES设置键-值对属性值，来描述这个数据库的属性信息。数据库的其他元数据信息都是不可更改的，包括数据库名和数据库所在的目录位置。

    hive (default)> alter database db_hive set dbproperties('createtime'='20170825');

    在hive中查看修改结果

hive (default)> desc database extended db_hive;

OK

db_name    comment    location    owner_name    owner_type    parameters

db_hive        hdfs://hadoop103:9000/user/hive/warehouse/db_hive.db    luomk    USER    {createtime=20170825}

Time taken: 0.012 seconds, Fetched: 1 row(s)

3.查询数据库

(1) 显示数据库

    hive> show databases;

(2) 过滤显示查询的数据库

hive (default)>  show databases like 'db_hive*';

OK

database_name

db_hive

db_hive2

Time taken: 0.024 seconds, Fetched: 2 row(s)

(3) 查看数据库详情

    ① 显示数据库信息

hive (default)>  desc database db_hive;

OK

db_name    comment    location    owner_name    owner_type    parameters

db_hive        hdfs://hadoop103:9000/user/hive/warehouse/db_hive.db    luomk    USER

Time taken: 0.01 seconds, Fetched: 1 row(s)

    ② 显示数据库详细信息，extended

> desc database extended db_hive;

OK

db_name    comment    location    owner_name    owner_type    parameters

db_hive        hdfs://hadoop103:9000/user/hive/warehouse/db_hive.db    luomk    USER    {createtime=20170830}

Time taken: 0.814 seconds, Fetched: 1 row(s)

(4) 切换当前数据库

    hive (default)> use db_hive;

4.删除数据库

(1) 删除空数据库

    hive>drop database db_hive2;

(2) 如果删除的数据库不存在，最好采用 if exists判断数据库是否存在

hive> drop database db_hive;

FAILED: SemanticException [Error 10072]: Database does not exist: db_hive

hive> drop database if exists db_hive2;

(3) 如果数据库不为空，可以采用cascade命令，强制删除

hive> drop database db_hive;

FAILED: Execution Error, return code 1 from org.apache.hadoop.hive.ql.exec.DDLTask. InvalidOperationException(message:Database db_hive is not empty. One or more tables exist.)

hive> drop database db_hive cascade;

5.创建表

CREATE [EXTERNAL] TABLE [IF NOT EXISTS] table_name

[(col_name data_type [COMMENT col_comment], ...)]

[COMMENT table_comment]

[PARTITIONED BY (col_name data_type [COMMENT col_comment], ...)]

[CLUSTERED BY (col_name, col_name, ...)

[SORTED BY (col_name [ASC|DESC], ...)] INTO num_buckets BUCKETS]

[ROW FORMAT row_format]

[STORED AS file_format]

[LOCATION hdfs_path]

字段解释说明:

（1）CREATE TABLE 创建一个指定名字的表。如果相同名字的表已经存在，则抛出异常；用户可以用 IF NOT EXISTS 选项来忽略这个异常。

（2）EXTERNAL关键字可以让用户创建一个外部表，在建表的同时指定一个指向实际数据的路径（LOCATION），Hive创建内部表时，会将数据移动到数据仓库指向的路径；若创建外部表，仅记录数据所在的路径，不对数据的位置做任何改变。在删除表的时候，内部表的元数据和数据会被一起删除，而外部表只删除元数据，不删除数据。

（3）COMMENT：为表和列添加注释。

（4）PARTITIONED BY创建分区表

（5）CLUSTERED BY创建分桶表

（6）SORTED BY不常用

（7）ROW FORMAT

    DELIMITED [FIELDS TERMINATED BY char] [COLLECTION ITEMS TERMINATED BY char]

    [MAP KEYS TERMINATED BY char] [LINES TERMINATED BY char]

   | SERDE serde_name [WITH SERDEPROPERTIES (property_name=property_value, property_name=property_value, ...)]

    用户在建表的时候可以自定义 SerDe 或者使用自带的 SerDe。如果没有指定 ROW FORMAT 或者 ROW FORMAT DELIMITED，将会使用自带的 SerDe。在建表的时候，用户还需要为表指定列，用户在指定表的列的同时也会指定自定义的 SerDe，Hive 通过 SerDe 确定表的具体的列的数据。

    SerDe是Serialize/Deserilize的简称，目的是用于序列化和反序列化。

（8）STORED AS指定存储文件类型

常用的存储文件类型：SEQUENCEFILE（二进制序列文件）、TEXTFILE（文本）、RCFILE（列式存储格式文件）

如果文件数据是纯文本，可以使用STORED AS TEXTFILE。如果数据需要压缩，使用 STORED AS SEQUENCEFILE。

（9）LOCATION ：指定表在HDFS上的存储位置。

（10）LIKE允许用户复制现有的表结构，但是不复制数据。

(1) 管理表

① 理论

    默认创建的表都是所谓的管理表，有时也被称为内部表。因为这种表，Hive会（或多或少地）控制着数据的生命周期。Hive默认情况下会将这些表的数据存储在由配置项hive.metastore.warehouse.dir(例如，/user/hive/warehouse)所定义的目录的子目录下。    当我们删除一个管理表时，Hive也会删除这个表中数据。管理表不适合和其他工具共享数据。

② 案例实操

    a.普通创建表

create table if not exists student2(

id int,

name string

)

row format delimited fields terminated by '\t'

stored as textfile

location '/user/hive/warehouse/student2';

    b.根据查询结果创建表（查询的结果会添加到新创建的表中）

create table if not exists student3 as select id, name from student;

    c.根据已经存在的表结构创建表

create table if not exists student4 like student;

    d.查询表的类型

> desc formatted student2;

OK

col_name    data_type    comment

# col_name                data_type               comment

id                      int

name                    string

# Detailed Table Information

Database:               default

Owner:                  luomk

CreateTime:             Tue May 15 21:07:34 CST 2018

LastAccessTime:         UNKNOWN

Protect Mode:           None

Retention:              0

Location:               hdfs://hadoop103:9000/user/hive/warehouse/student2

Table Type:             MANAGED_TABLE

Table Parameters:

    transient_lastDdlTime    1526389654

# Storage Information

SerDe Library:          org.apache.hadoop.hive.serde2.lazy.LazySimpleSerDe

InputFormat:            org.apache.hadoop.mapred.TextInputFormat

OutputFormat:           org.apache.hadoop.hive.ql.io.HiveIgnoreKeyTextOutputFormat

Compressed:             No

Num Buckets:            -1

Bucket Columns:         []

Sort Columns:           []

Storage Desc Params:

    field.delim             \t

    serialization.format    \t

Time taken: 0.056 seconds, Fetched: 28 row(s)

(2) 外部表

① 理论

    因为表是外部表，所以Hive并非认为其完全拥有这份数据。删除该表并不会删除掉这份数据，不过描述表的元数据信息会被删除掉(补：删除表后在恢复同名同字段的表，仍能查询)。

② 管理表和外部表的使用场景    

    每天将收集到的网站日志定期流入HDFS文本文件。在外部表（原始日志表）的基础上做大量的统计分析，用到的中间表、结果表使用内部表存储，数据通过SELECT+INSERT进入内部表。

③ 案例实操

    分别创建部门和员工外部表，并向表中导入数据。

    a.准备原始数据

    b.建表语句

        创建部门表

create external table if not exists default.dept(

deptno int,

dname string,

loc int

)

row format delimited fields terminated by '\t';

        创建员工表

create external table if not exists default.emp(

empno int,

ename string,

job string,

mgr int,

hiredate string,

sal double,

comm double,

deptno int)

row format delimited fields terminated by '\t';

    c.查看创建的表

hive (default)> show tables;

OK

tab_name

dept

emp

    d.向外部表中导入数据

hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept;

hive (default)> load data local inpath '/opt/module/datas/emp.txt' into table default.emp;

    e.查询结果

hive (default)> select * from emp;

OK

emp.empno    emp.ename    emp.job    emp.mgr    emp.hiredate    emp.sal    emp.comm    emp.deptno

7369    SMITH    CLERK    7902    1980-12-17    800.0    NULL    20

7499    ALLEN    SALESMAN    7698    1981-2-20    1600.0    300.0    30

7521    WARD    SALESMAN    7698    1981-2-22    1250.0    500.0    30

7566    JONES    MANAGER    7839    1981-4-2    2975.0    NULL    20

7654    MARTIN    SALESMAN    7698    1981-9-28    1250.0    1400.0    30

7698    BLAKE    MANAGER    7839    1981-5-1    2850.0    NULL    30

7782    CLARK    MANAGER    7839    1981-6-9    2450.0    NULL    10

7788    SCOTT    ANALYST    7566    1987-4-19    3000.0    NULL    20

7839    KING    PRESIDENT    NULL    1981-11-17    5000.0    NULL    10

7844    TURNER    SALESMAN    7698    1981-9-8    1500.0    0.0    30

7876    ADAMS    CLERK    7788    1987-5-23    1100.0    NULL    20

7900    JAMES    CLERK    7698    1981-12-3    950.0    NULL    30

7902    FORD    ANALYST    7566    1981-12-3    3000.0    NULL    20

7934    MILLER    CLERK    7782    1982-1-23    1300.0    NULL    10

Time taken: 0.066 seconds, Fetched: 14 row(s)

hive (default)> select * from dept;

OK

dept.deptno    dept.dname    dept.loc

10    ACCOUNTING    1700

20    RESEARCH    1800

30    SALES    1900

40    OPERATIONS    1700

Time taken: 0.068 seconds, Fetched: 4 row(s)

    f.查看表格式化数据

hive (default)> desc formatted dept;

OK

col_name    data_type    comment

# col_name                data_type               comment

deptno                  int

dname                   string

loc                     int

# Detailed Table Information

Database:               default

Owner:                  luomk

CreateTime:             Wed May 16 11:24:36 CST 2018

LastAccessTime:         UNKNOWN

Protect Mode:           None

Retention:              0

Location:               hdfs://hadoop103:9000/user/hive/warehouse/dept

Table Type:             EXTERNAL_TABLE

Table Parameters:

    COLUMN_STATS_ACCURATE    true

    EXTERNAL                TRUE

    numFiles                1

    totalSize               69

    transient_lastDdlTime    1526441119

# Storage Information

SerDe Library:          org.apache.hadoop.hive.serde2.lazy.LazySimpleSerDe

InputFormat:            org.apache.hadoop.mapred.TextInputFormat

OutputFormat:           org.apache.hadoop.hive.ql.io.HiveIgnoreKeyTextOutputFormat

Compressed:             No

Num Buckets:            -1

Bucket Columns:         []

Sort Columns:           []

Storage Desc Params:

    field.delim             \t

    serialization.format    \t

Time taken: 0.073 seconds, Fetched: 33 row(s)

(3) 管理表与外部表的互相转换

    ① 查询表的类型

        hive (default)> desc formatted student2;

        Table Type:             MANAGED_TABLE

    ② 修改内部表student2为外部表

        alter table student2 set tblproperties('EXTERNAL'='TRUE');

    ③ 查询表的类型

        hive (default)> desc formatted student2;

        Table Type:             EXTERNAL_TABLE

    ④ 修改外部表student2为内部表

        alter table student2 set tblproperties('EXTERNAL'='FALSE');

    ⑤ 查询表的类型

        hive (default)> desc formatted student2;

        Table Type:             MANAGED_TABLE

    注意：('EXTERNAL'='TRUE')和('EXTERNAL'='FALSE')为固定写法，区分大小写！

6.分区表

    分区表实际上就是对应一个HDFS文件系统上的独立的文件夹，该文件夹下是该分区所有的数据文件。Hive中的分区就是分目录，把一个大的数据集根据业务需要分割成小的数据集。在查询时通过WHERE子句中的表达式选择查询所需要的指定的分区，这样的查询效率会提高很多。

(1) 分区表基本操作

    ① 引入分区表（需要根据日期对日志进行管理）

    ② 创建分区表语法

hive (default)> create table dept_partition(

                deptno int, 

                dname string, 

                loc string

               )

               partitioned by (month string)

               row format delimited fields terminated by '\t';

    ③ 加载数据到分区表中

hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201805');

hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201806');

hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201807’);

hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition partition(month='201808’);

    加载数据到分区表

    ④ 查询分区表中数据

        单分区查询

 hive (default)> select * from dept_partition where month='201805';

        多分区联合查询

hive (default)>  select * from dept_partition where month='201805'

              >               union

              >               select * from dept_partition where month='201806'

              >               union

              >               select * from dept_partition where month='201807’;

_u3.deptno    _u3.dname    _u3.loc    _u3.month

10    ACCOUNTING    1700    201805

10    ACCOUNTING    1700    201806

10    ACCOUNTING    1700    201807

20    RESEARCH    1800    201805

20    RESEARCH    1800    201806

20    RESEARCH    1800    201807

30    SALES    1900    201805

30    SALES    1900    201806

30    SALES    1900    201807

40    OPERATIONS    1700    201805

40    OPERATIONS    1700    201806

40    OPERATIONS    1700    201807

    ⑤ 增加分区

    创建单个分区

hive (default)> alter table dept_partition add partition(month='201809') ;

    同时创建多个分区

hive (default)> alter table dept_partition add partition(month='201810') partition(month='201811');

    ⑥ 删除分区

    删除单个分区

hive (default)> alter table dept_partition drop partition (month='201809');

    同时删除多个分区

hive (default)> alter table dept_partition drop partition (month='201810'), partition (month='201811');

    ⑦ 查看分区表有多少分区

hive> show partitions dept_partition;

    ⑧ 查看分区表结构

    hive> desc formatted dept_partition;

hive (default)> desc formatted dept_partition;

OK

col_name    data_type    comment

# col_name                data_type               comment

deptno                  string

dname                   string

loc                     string

# Partition Information

# col_name                data_type               comment

month                   string

(2) 分区表注意事项

     ① 创建二级分区表

hive (default)>  create table dept_partition2(

              >                deptno int, dname string, loc string

              >                )

              >                partitioned by (month string, day string)

              >                row format delimited fields terminated by '\t';

OK

Time taken: 0.094 seconds

    ② 正常的加载数据

    a.加载数据到二级分区表中

        hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table default.dept_partition2 partition(month='201709', day='13');

    b.查询分区数据

        hive (default)> select * from dept_partition2 where month='201709' and day='13’;

    ③ 把数据直接上传到分区目录上，让分区表和数据产生关联的三种方式

方式一：上传数据后修复

    上传数据

        hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=12;

        hive (default)> dfs -put /opt/module/datas/dept.txt  /user/hive/warehouse/dept_partition2/month=201709/day=12;

    查询数据（查询不到刚上传的数据）

        hive (default)> select * from dept_partition2 where month='201709' and day='12';

执行修复命令

        hive> msck repair table dept_partition2;

再次查询数据

        hive (default)> select * from dept_partition2 where month='201709' and day='12';

方式二：上传数据后添加分区

    上传数据

        hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=11;

        hive (default)> dfs -put /opt/module/datas/dept.txt  /user/hive/warehouse/dept_partition2/month=201709/day=11;

    执行添加分区

        hive (default)> alter table dept_partition2 add partition(month='201709',day='11');

    查询数据

        hive (default)> select * from dept_partition2 where month='201709' and day='11';

方式三：上传数据后load数据到分区

    创建目录

        hive (default)> dfs -mkdir -p /user/hive/warehouse/dept_partition2/month=201709/day=10;

    上传数据

        hive (default)> load data local inpath '/opt/module/datas/dept.txt' into table dept_partition2 partition(month='201709',day='10');

    查询数据

        hive (default)> select * from dept_partition2 where month='201709' and day='10';

7.修改表

(1) 重命名表

    ALTER TABLE table_name RENAME TO new_table_name

(2) 增加/修改/替换列信息

    ① 查询表结构

        hive> desc dept_partition;

    ② 添加列    

        hive (default)> alter table dept_partition add columns(deptdesc string);

    ③ 查询表结构

        hive> desc dept_partition;

    ④ 更新列

        hive (default)> alter table dept_partition change column deptdesc desc int;

    ⑤ 查询表结构

        hive> desc dept_partition;

    ⑥ 替换列

        hive (default)> alter table dept_partition replace columns(deptno string, dname string, loc string);

    ⑦ 查询表结构

        hive> desc dept_partition;

8.删除表

    hive (default)> drop table dept_partition;