ORACLE导出<BLOB>字段图片

--1.在服务器F盘创建一个目录：pic，然后在plsql上执行下边命令：

create or replace directory BLOBDIR
  as 'F:\pic';

--2.创建写出到目录的脚本
create or replace procedure photo_dump(PHOTOID in number,
                                       filename   in varchar2) is
  l_file     UTL_FILE.FILE_TYPE;
  l_buffer   RAW(32767);
  l_amount   BINARY_INTEGER := 32767;
  l_pos      INTEGER := 1;
  l_blob     BLOB;
  l_blob_len INTEGER;
begin
  SELECT PHOTO_DATA INTO l_blob FROM org_emp_sub_photo p WHERE p.PHOTO_ID = PHOTOID;--org_emp_sub_photo 存储照片的表，PHOTO_DATA图片字段
  l_blob_len := DBMS_LOB.GETLENGTH(l_blob);
  l_file     := UTL_FILE.FOPEN('BLOBDIR', filename, 'wb', 32767);-- 使用l_blob_len也会报错
  WHILE l_pos < l_blob_len LOOP
    DBMS_LOB.READ(l_blob, l_amount, l_pos, l_buffer);
    UTL_FILE.PUT_RAW(l_file, l_buffer, TRUE);
    l_pos := l_pos + l_amount;
  END LOOP;
  UTL_FILE.FCLOSE(l_file);
EXCEPTION
  WHEN OTHERS THEN
    dbms_output.put_line(SQLERRM);
    IF UTL_FILE.IS_OPEN(l_file) THEN
      UTL_FILE.FCLOSE(l_file);
    END IF;
    RAISE;
end photo_dump;
/

--3.创建执行导出脚本

create or replace procedure out_put_photo is
  PHOTOID number;
  cursor cur is
    select PHOTO_ID, EMPLOYEE_ID 
      from org_emp_sub_photo t
     where t.employee_id = 21170889 
       and t.photo_data is not null
       and t.sort_index =
           (select max(p.sort_index)
              from org_emp_sub_photo p
             where p.employee_id = t.employee_id);--此处过滤需要导出的图片
  cur_result cur%rowtype;
begin
  if cur%isopen = false then
    open cur;
  end if;
  loop
    fetch cur
      into cur_result;
    exit when cur%notfound;
    PHOTOID := cur_result.PHOTO_ID;
    photo_dump(PHOTOID  => PHOTOID,
               filename => cur_result.EMPLOYEE_ID || '.jpg');
  end loop;
  close cur;
end out_put_photo;
/

--4.调用存储过程导出图片

call out_put_photo();