oracle存储过程大数据量导出CSV文件（utl-file读写文件包）

1.创建用来存放导出的文件的目录（或者有了也可以不用）

create or replace directory OUT_PATH as 'D:\' ;

--out_path是使用的目录名，'D:\'是实际的目录路径

--这里创建的目录是存在服务器上的，不是在自己的电脑（除非是自己的电脑是oracle服务器）

--如果不小心建了，可以删除的，使用drop directory 目录名;

----查看已经有的目录----

select * from dba_directories;

2.创建过程用来使用utl-file导出csv文件（直接复制这个创建语句，不用修改）

CREATE OR REPLACE PROCEDURE SQL_TO_CSV
(
 P_QUERY IN VARCHAR2, -- PLSQL文
 P_DIR IN VARCHAR2, -- 导出的文件放置目录
 P_FILENAME IN VARCHAR2 -- CSV名
 )
 IS
  L_OUTPUT UTL_FILE.FILE_TYPE;
  L_THECURSOR INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;
  L_COLUMNVALUE VARCHAR2(4000);
  L_STATUS INTEGER;
  L_COLCNT NUMBER := 0;
  L_SEPARATOR VARCHAR2(1);
  L_DESCTBL DBMS_SQL.DESC_TAB;
  P_MAX_LINESIZE NUMBER := 32000;
BEGIN
  --OPEN FILE
  L_OUTPUT := UTL_FILE.FOPEN(P_DIR, P_FILENAME, 'W', P_MAX_LINESIZE);
  --DEFINE DATE FORMAT
  EXECUTE IMMEDIATE 'ALTER SESSION SET NLS_DATE_FORMAT=''YYYY-MM-DD HH24:MI:SS''';
  --OPEN CURSOR
  DBMS_SQL.PARSE(L_THECURSOR, P_QUERY, DBMS_SQL.NATIVE);
  DBMS_SQL.DESCRIBE_COLUMNS(L_THECURSOR, L_COLCNT, L_DESCTBL);
  --DUMP TABLE COLUMN NAME
  FOR I IN 1 .. L_COLCNT LOOP
    UTL_FILE.PUT(L_OUTPUT,L_SEPARATOR || '"' || L_DESCTBL(I).COL_NAME || '"'); --输出表字段
    DBMS_SQL.DEFINE_COLUMN(L_THECURSOR, I, L_COLUMNVALUE, 4000);
    L_SEPARATOR := ',';
  END LOOP;
  UTL_FILE.NEW_LINE(L_OUTPUT); --输出表字段
  --EXECUTE THE QUERY STATEMENT
  L_STATUS := DBMS_SQL.EXECUTE(L_THECURSOR);

  --DUMP TABLE COLUMN VALUE
  WHILE (DBMS_SQL.FETCH_ROWS(L_THECURSOR) > 0) LOOP
    L_SEPARATOR := '';
    FOR I IN 1 .. L_COLCNT LOOP
      DBMS_SQL.COLUMN_VALUE(L_THECURSOR, I, L_COLUMNVALUE);
      UTL_FILE.PUT(L_OUTPUT,
                  L_SEPARATOR || '"' ||
                  TRIM(BOTH ' ' FROM REPLACE(L_COLUMNVALUE, '"', '""')) || '"');
      L_SEPARATOR := ',';
    END LOOP;
    UTL_FILE.NEW_LINE(L_OUTPUT);
  END LOOP;
  --CLOSE CURSOR
  DBMS_SQL.CLOSE_CURSOR(L_THECURSOR);
  --CLOSE FILE
  UTL_FILE.FCLOSE(L_OUTPUT);
EXCEPTION
  WHEN OTHERS THEN
    RAISE;
END;

3.调用这个过程，传入参数，生成csv文件

P_QUERY IN VARCHAR2, -- 传入plsql语句，这个是写了输入的字段的

P_DIR IN VARCHAR2, -- 导出的文件放置目录,目录名称，不是真实路径

P_FILENAME IN VARCHAR2 -- CSV名，生成的文件名称

在命令窗口执行：

exec sql_to_csv( 'select * from test' , 'OUT_PATH ',' test.csv ');

如果传入的sql语句里有特殊字符，要用转义字符转义，如：to_date('2017-01-10 13:14:20','yyyy-MM-dd HH24:mi:ss')要写成to_date(''2017-01-10 13:14:20'',''yyyy-MM-dd HH24:mi:ss'')

oracle存储过程大数据量导出CSV文件（utl-file读写文件包）

猜你喜欢