文章目录

结构
两者优劣对比
unity shader实现

（23.3.16今天重新捡起知识，从phong开始复习）

reference:
learn opengl
《unityshader入门精要》

结构

注意本文所有的公式都是光线强度，不能直接用到shader中，因为还需要反射颜色的计算

为了更好的记住，将两种光照结合对比记忆

phong 光照由三部分构成，如图

在这里插入图片描述

Ambient 环境光

略

Diffuse 漫反射光

漫反射光与视线无关，仅与光线和表面法线有关，因此其结果像是一张贴图

漫反射的作用仅是根据入射角度来计算削弱光线强度，仅此而已：
在这里插入图片描述

$C = - L \cdot N$
L为光线向量，N为法线向量

扫描二维码关注公众号，回复： 15011787 查看本文章

diff = max(dot(norm, lightDir), 0.0)
（max函数将点积限制在 [0, 1]，大于90度是照不到的，同时也避免了负数出现）

即，漫反射强度与LN的余弦值成正比

Specular 高光

Phong

高光，仅关乎到两个向量：视线方向和反射方向（但是反射向量也要计算得来）

在这里插入图片描述
如图，看似很多向量，真正需要的只有两个，V和R，不过为了实现高亮的光斑（一小块），我们需要一个指数运算：

$C = (V·R)^{g}$

V是视线向量，R是反射向量，g是高光系数gloss/shininess（越大越集中）
实际上这个公式也是phong的高光分布，当粗糙度g为1时，其衰减曲线就是个cos函数 $[0,\frac{\pi}{2})$ 的部分；然后g的不同可以改变分布的形状，g越小分布越平缓，越大越陡峭（幂函数）
由于并没有PBR中的能量守恒，所以g比较小的时候高光看起来会太大太亮
g=1的specular和diffuse的分布是不一样的！虽然都是高斯分布，但是作用方式是不一样的，diffuse是方向光，spec是点光源

spec = pow(max(dot(viewDir, reflectDir), 0.0), gloss)
（max函数目的在于将点积限制在 [0, 1]，避免了负数出现，但可惜的是视线方向和反射方向可以大于90度，这也是phong的缺陷所在）

R可以由专门的函数 reflect(N, -L)（具体是不是这个还没有考证）计算得，具体公式好像很麻烦，以后补充

Blinn-Phong

bp不再需要计算反射向量，而采用半程向量
与其相关的也仅有两个向量：法线，半程向量（需要计算）
在这里插入图片描述

$C=(H·N)^g$
spec = pow(max(dot(halfDir,normal), 0.0), gloss)
(H再怎么变也不会大于90度的，因此这里的max完全没问题，并且H的计算比R容易)
halfDir = normalize(lightDir + viewDir)

两者优劣对比

phong存在的问题

当gloss太小时，高光面积会非常大，这本身没什么问题，但是这在某些角度(一般是顺着光看地面)下会形成高光断层：

在这里插入图片描述

原因：我们在应用phong的高光计算时，会将视线V和反射R大于90度的部分定义为0，这是为了防止负数出现（ $cos120^\circ = -0.5$ ），但是真实情况先V和R的角度是可能大于90度的：
在这里插入图片描述
这便导致了断层，因为大于90度的高光直接消失了
因此才普遍使用blinn-phong：

两者效果

因为两者都是经验模型，在效果上并不存在优劣
两者唯一的不同在于高光的计算，因此在效果上不同的也仅仅是高光部分：
在这里插入图片描述
blinnphong的夹角通常会小于phong的夹角，因此在相似高光面积时，phong’的gloss会小很多；
就算相同的面积，glossBlinn-Phong的镜面光也会比冯氏模型更锐利

运行速度

普遍来讲blinn会更快，（硬件实现来说R和H到底哪个计算更快还没有考证）

（入门精要：摄像机和光源距离模型足够远时，blinn-phong会更快，因为硬件处理时会将H视为常量；当近到不能视为常量时，phong可能会更快）
个人不是很认同和理解：GPU会为这种东西优化？还根据距离视为常量，有点夸张）

两者共存的问题

1、不能计算菲涅尔（PBR里也不会用经验模型就是了）
2、不能计算各项异性（如金属拉丝）（还是一样轮不到）
因为它是是各项同性的，固定摄像机和光源，物体表面旋转时光照不会变化，而各项异性的表面是会变化的

unity shader实现

Shader "Unlit/phong"
{
    
    
    Properties
    {
    
    
        _Diffuse ("Diffuse", Color) = (1,1,1,1)
        _Specular ("Specular", Color) = (1,1,1,1)
        _Gloss ("Gloss", Range(8,256)) = 20
    }
    SubShader
    {
    
    
        Pass
        {
    
    
            Tags {
    
    "LightMode"="ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
 
            #include "UnityCG.cginc"
            #include "Lighting.cginc" //导入这个包是为了使用外源环境光_LightColor0，否则只能使用自己指定的环境光，可能会不自然

            struct appdata
            {
    
    
                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f
            {
    
    
                float4 vertex : SV_POSITION;
                float3 w_Normal : TEXCOORD0;
                float3 w_Pos : TEXCOORD1;
            };

            float4 _Diffuse;
            float4 _Specular;
            float _Gloss;

            v2f vert (appdata v)
            {
    
    
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);

                o.w_Normal = UnityObjectToWorldDir(v.normal); //注意这两句的两种不同实现方法
                o.w_Pos = mul(unity_ObjectToWorld, v.vertex).xyz;

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
    
    
                float3 w_Normal = normalize(i.w_Normal);
                float3 w_LightDir = normalize(_WorldSpaceLightPos0.xyz);
                float3 reflectDir = normalize(reflect(-w_LightDir,w_Normal));
                float3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.w_Pos.xyz);
 
                float3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                float3 diff = _LightColor0.rgb * _Diffuse.rgb * max(dot(w_Normal, w_LightDir), 0.0);
                float3 spec = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectDir, viewDir)), _Gloss);

                return fixed4(ambient + diff + spec , 1.0);
            }
            ENDCG
        }
    }
}

Blinn-Phong & Phong