从零开始vim搭建Java开发环境之coc.nvim 篇

企业开发 2023-01-29 12:17:14 阅读次数: 0

前言

vim之美妙我就不过多介绍了，懂的自然懂。之前我已经有一篇文章介绍如何使用SpaceVim来搭建Java开发环境。
传送门：《从零开始vim搭建Java开发环境[视频]》

最近使用coc.nvim,感觉体验也很棒，与是就想使用coc.nvim平台也来搭建个Java开发环境，来比较一下哪个更适合自己。

环境

搭建环境千差万别，大同小异，理论上各大平台都是支持的，我把我的环境发一下仅供参考。

项目 版本
操作系统 Linux version 5.11.11-arch1-1 (linux@archlinux)
vim 8.2 +python/dyn +python3/dyn

环境搭建

我们的主题就是用vim搭建Java开发环境，第一步当然是安装vim了，很多系统默认自带的vim是精简版本的，或者版本比较旧。建议自己安装一个，比如：macOS自带的vim就不支持python3，之前因为这个坑研究了好久才明白。

安装vim

安装vim或neovim都是可以的，上篇中我使用的neovim，这篇打算使用vim来搭建了。

sudo pacman -S vim

查询是否支持python3

vim --version

显示结果中如果有+python3字样就说明是支持的了。

这里需要注意一下，为了少走弯路，你安装的vim版本最好要有python3支持，因为我遇到过很多插件都需要这个。在archlinux中安装后默认就支持python3了。其他系统可以自行百度一下，如何让vim/neovim有python3支持。下列文章供参考：

安装vim-plug

软件管理器还是需要一个的，我们就使用coc.nvim演示中使用的vim-plug来管理插件吧。
项目主页：
https://github.com/junegunn/vim-plug

Unix中vim环境执行下面命令完成安装，其他环境请参考项目主页的介绍。

curl -fLo ~/.vim/autoload/plug.vim --create-dirs \
    https://raw.githubusercontent.com/junegunn/vim-plug/master/plug.vim

成功执行，就已经安装完成了。后面我们安装vim插件需要vim-plug。

安装node.js

coc.nvim依赖node.js而且版本要求nodejs >= 10.12。
archlinux下执行：

sudo pacman -S nodejs
sudo pacman -S npm

其他系统环境请参考：https://nodejs.org/

查node.js版本

node -v
v15.13.0

安装coc.nvim

终于轮到今天的主角了。看了一下贡献者中前几个是国内的大佬，在此膜拜一下。
项目地址：
https://github.com/neoclide/coc.nvim
安装很简单。

配置vim的配置文件

vim ~/.vimrc

内容如下：

" Specify a directory for plugins
" - For Neovim: stdpath('data') . '/plugged'
" - Avoid using standard Vim directory names like 'plugin'
call plug#begin('~/.vim/plugged')
" Use release branch (recommend)
Plug 'neoclide/coc.nvim', {'branch': 'release'}
call plug#end()

:wq保存退出，重启打开vim后，执行:PlugInstall完成插件的安装。

在这里插入图片描述
编辑配置文件

vim ~/.vimrc

并在~/.vimrc下面增加如下内容：

" 设置vim的内部编码，在neovim上不需要，因为coc.nvim使用了一些
" autoload / float.vim文件中的unicode字符
set encoding=utf-8
" 如果未设置“隐藏”，则TextEdit可能会失败。
set hidden
" 某些服务器的备份文件有问题，请参阅＃649。
set nobackup
set nowritebackup
" 留出更多空间来显示消息。
set cmdheight=2
" 较长的更新时间（默认值为4000 ms = 4 s）会导致明显的
" 延迟和糟糕的用户体验。
set updatetime=300
" 不要将消息传递到| ins-completion-menu |。
set shortmess+=c

" 始终显示标志列，否则每次都会移动文本
" 诊断出现/已解决。
if has("patch-8.1.1564")
  " 最近vim可以将signcolumn和number列合并为一个
  set signcolumn=number
else
  set signcolumn=yes
endif

" 使用制表符可完成带有前面字符的触发操作并进行导航。
" NOTE: 这个命令':verbose imap <tab>' 去确实你的<tab>键
" 没有被其他插件使用。
inoremap <silent><expr> <TAB>
      \ pumvisible() ? "\<C-n>" :
      \ <SID>check_back_space() ? "\<TAB>" :
      \ coc#refresh()
inoremap <expr><S-TAB> pumvisible() ? "\<C-p>" : "\<C-h>"

function! s:check_back_space() abort
  let col = col('.') - 1
  return !col || getline('.')[col - 1]  =~# '\s'
endfunction

" 使用 <c-space> 触发自动完成。
if has('nvim')
  inoremap <silent><expr> <c-space> coc#refresh()
else
  inoremap <silent><expr> <c-@> coc#refresh()
endif

" 使<CR>自动选择第一个完成项目，并将coc.nvim通知给
" 输入格式，<cr>可能会被其他vim插件重新映射
inoremap <silent><expr> <cr> pumvisible() ? coc#_select_confirm()
                              \: "\<C-g>u\<CR>\<c-r>=coc#on_enter()\<CR>"

" 使用 `[g` and `]g` 浏览诊断
" Use `:CocDiagnostics` to get all diagnostics of current buffer in location list.
nmap <silent> [g <Plug>(coc-diagnostic-prev)
nmap <silent> ]g <Plug>(coc-diagnostic-next)

" GoTo代码导航
nmap <silent> gd <Plug>(coc-definition)
nmap <silent> gy <Plug>(coc-type-definition)
nmap <silent> gi <Plug>(coc-implementation)
nmap <silent> gr <Plug>(coc-references)

" 使用 K 在预览窗口中显示文档。
nnoremap <silent> K :call <SID>show_documentation()<CR>

function! s:show_documentation()
  if (index(['vim','help'], &filetype) >= 0)
    execute 'h '.expand('<cword>')
  elseif (coc#rpc#ready())
    call CocActionAsync('doHover')
  else
    execute '!' . &keywordprg . " " . expand('<cword>')
  endif
endfunction

" 按住光标时突出显示该符号及其参考。
autocmd CursorHold * silent call CocActionAsync('highlight')

" 重命名符号。
nmap <leader>rn <Plug>(coc-rename)

" 格式化选定的代码。
xmap <leader>f  <Plug>(coc-format-selected)
nmap <leader>f  <Plug>(coc-format-selected)

augroup mygroup
  autocmd!
  " Setup formatexpr specified filetype(s).
  autocmd FileType typescript,json setl formatexpr=CocAction('formatSelected')
  " 更新有关跳转占位符的签名帮助。
  autocmd User CocJumpPlaceholder call CocActionAsync('showSignatureHelp')
augroup end

" 将codeAction应用于所选区域。
" Example: `<leader>aap` for current paragraph
xmap <leader>a  <Plug>(coc-codeaction-selected)
nmap <leader>a  <Plug>(coc-codeaction-selected)

" 重新映射用于将codeAction应用于当前缓冲区的键。
nmap <leader>ac  <Plug>(coc-codeaction)
" 将AutoFix应用于当前行的问题。
nmap <leader>qf  <Plug>(coc-fix-current)

" 映射函数和类文本对象
" 注意：需要语言服务器提供'textDocument.documentSymbol'支持。
xmap if <Plug>(coc-funcobj-i)
omap if <Plug>(coc-funcobj-i)
xmap af <Plug>(coc-funcobj-a)
omap af <Plug>(coc-funcobj-a)
xmap ic <Plug>(coc-classobj-i)
omap ic <Plug>(coc-classobj-i)
xmap ac <Plug>(coc-classobj-a)
omap ac <Plug>(coc-classobj-a)

" Remap <C-f> and <C-b> for scroll float windows/popups.
if has('nvim-0.4.0') || has('patch-8.2.0750')
  nnoremap <silent><nowait><expr> <C-f> coc#float#has_scroll() ? coc#float#scroll(1) : "\<C-f>"
  nnoremap <silent><nowait><expr> <C-b> coc#float#has_scroll() ? coc#float#scroll(0) : "\<C-b>"
  inoremap <silent><nowait><expr> <C-f> coc#float#has_scroll() ? "\<c-r>=coc#float#scroll(1)\<cr>" : "\<Right>"
  inoremap <silent><nowait><expr> <C-b> coc#float#has_scroll() ? "\<c-r>=coc#float#scroll(0)\<cr>" : "\<Left>"
  vnoremap <silent><nowait><expr> <C-f> coc#float#has_scroll() ? coc#float#scroll(1) : "\<C-f>"
  vnoremap <silent><nowait><expr> <C-b> coc#float#has_scroll() ? coc#float#scroll(0) : "\<C-b>"
endif

" 使用CTRL-S作为选择范围。
" Requires 'textDocument/selectionRange' support of language server.
nmap <silent> <C-s> <Plug>(coc-range-select)
xmap <silent> <C-s> <Plug>(coc-range-select)

" 添加`:Format`命令格式化当前缓冲区。
command! -nargs=0 Format :call CocAction('format')

" 添加`：Fold`命令来折叠当前缓冲区。
command! -nargs=? Fold :call     CocAction('fold', <f-args>)

" Add `:OR` command for organize imports of the current buffer.
command! -nargs=0 OR   :call     CocAction('runCommand', 'editor.action.organizeImport')

" 添加（Neo）Vim的本机状态行支持。
" NOTE: Please see `:h coc-status` for integrations with external plugins that
" provide custom statusline: lightline.vim, vim-airline.
set statusline^=%{
    
    coc#status()}%{
    
    get(b:,'coc_current_function','')}

" CoCList的映射
" Show all diagnostics.
nnoremap <silent><nowait> <space>a  :<C-u>CocList diagnostics<cr>
" Manage extensions.
nnoremap <silent><nowait> <space>e  :<C-u>CocList extensions<cr>
" Show commands.
nnoremap <silent><nowait> <space>c  :<C-u>CocList commands<cr>
" Find symbol of current document.
nnoremap <silent><nowait> <space>o  :<C-u>CocList outline<cr>
" Search workspace symbols.
nnoremap <silent><nowait> <space>s  :<C-u>CocList -I symbols<cr>
" Do default action for next item.
nnoremap <silent><nowait> <space>j  :<C-u>CocNext<CR>
" Do default action for previous item.
nnoremap <silent><nowait> <space>k  :<C-u>CocPrev<CR>
" Resume latest coc list.
nnoremap <silent><nowait> <space>p  :<C-u>CocListResume<CR>

这些内容源于coc.nvim项目主页的demo，我是直接复制过来的，并对注释做了简单的翻译。

至此我们的基础环境，总算搭建好了。如果需要实现Java的开发环境还有一些路要走。

安装jdk

既然要搭建Java开发环境，JDK必不可少。这个大家应该都轻车熟路了吧。
个人建议安装jdk11，其他版本不能保证可以使用（最低Java 11是最低要求）。

sudo pacman -S jdk11-openjdk

安装coc-java

项目主页：
https://github.com/neoclide/coc-java

打开vim 并执行：

:CocInstall coc-java

在这里插入图片描述
如果本地没有jdt.ls则会自动下载最新版本的。这个jdt.ls我这里大概20秒不到就下载完成了。

其实我第一次使用coc-java的时候就卡在了jdt.ls的下载这块，一直显示downloading,几个小时过后还是这样。后来我放弃使用coc.nvim了，改为SpaceVim。这次就很顺利（身处两个不同的城市可能网络环境不同）。如果你跟我一项目被这个jdt.ls卡住了，不防切换不同网络环境试试。

先写个HelloWorld测试一下吧，我这里测试自动补全和文档的显示都没有问题。
在这里插入图片描述
至此vim下搭建java开发环境就已经完成啦！

coc.nvim the java server crashed 5 times in the last 3 minutes

2021年4月15日补
操作系统：macOS Big Sur 11.2.3
同样的操作，安装完成coc-java后打开java文件报错如下：
coc.nvim the java server crashed 5 times in the last 3 minutes. the server will not be restarted

解决办法参考：https://github.com/neoclide/coc-java/issues/99

JDT Lang Sever的57版可以正常使用
https://download.eclipse.org/jdtls/milestones/0.57.0/

下载后解压后
替换所有目录/文件~/.config/coc/extensions/coc-java-data/server。

vim简单优化

上面已经完成啦，现在的主题和默认配置还要微调一下。

美化主题

安装插件morhetz/gruvbox

Plug 'morhetz/gruvbox'

:wq保存退出，重启打开vim后，执行:PlugInstall完成插件的安装。
并增加配置

" 使用gruvbox配色
autocmd vimenter * ++nested colorscheme gruvbox
" 强制使用dark模式
set bg=dark

重启打开vim发现风格已经大变。
在这里插入图片描述
是不是比默认风格要好看多了。
还是打开刚才的java代码对比一下。
在这里插入图片描述
个人感觉比默认的风格更养眼。

vim-airline

提到美化，怎么能少的了vim-airline呢？
项目主页：
https://github.com/vim-airline/vim-airline

插件管理中增加：

Plug 'vim-airline/vim-airline'
Plug 'vim-airline/vim-airline-themes'

:wq保存退出，重启打开vim后，执行:PlugInstall完成插件的安装。
并增加配置

" vim-airline
let g:airline#extensions#tabline#enabled = 1
let g:airline_powerline_fonts = 1

看一下美化后的效果：
在这里插入图片描述
多了一些字体图标，看起来更时髦。不知道的还以为不是命令行程序呢。

解决乱码

如果你发现你显示的不是像我截图里的那样的，而是有乱码？之类的。那是因为字体的原因。
只要安装nerd-font字体，并设置终端模拟器的字体为nerd-font。

以macOS为例。
使用Homebrew安装nerd-font字体，顺序运行如下命令行：

brew tap homebrew/cask-fonts
brew install font-hack-nerd-font --cask

设置iterm
在这里插入图片描述
设置Mac自带终端。
在这里插入图片描述
解决SpaceVim图标在termux中乱码
字体文件下载

把这个字体文件上传到 /data/data/com.termux/files/home/.termux/font.ttf目录即可解决SpaceVim 乱码的问题。

没有乱码真舒服！

其他情况，就不举例啦，不管是什么终端模拟器，只要设置好字体就可以啦。

vim配置个人习惯分享

这个是非必须的，主要还是看个人使用习惯了。

"----vim 个人使用习惯配置start------
" leader设置成空格
let mapleader=" "
" 使用鼠标
set mouse=a
" 显示行号
set nu
" 相对行号
set relativenumber
" tab=4个空格
set tabstop=4
" 改变 vim中光标的形状
let g:db_ui_use_nerd_fonts=1
let &t_SI.="\e[5 q" "SI = INSERT mode
let &t_SR.="\e[4 q" "SR = REPLACE mode
let &t_EI.="\e[1 q" "EI = NORMAL mode (ELSE)
" 高度光标所在行
set cursorline
" 设置不换行
set nowrap
" 显示按下的按键
set showcmd
" 按tab显示菜单
set wildmenu
" 插入模式移动光标
inoremap <C-h> <Left>
inoremap <C-j> <Down>
inoremap <C-k> <Up>
inoremap <C-l> <Right>
inoremap <C-d> <Delete>
" hh在我用的单词里出现的频率极低，其实感觉home用的没有end多，统一风格都用大写的吧
inoremap HH <Home>
" 单词中包含ll的太多了，所以用大写LL
inoremap LL <End>
" 快速跳转行首与行尾
nnoremap L $
nnoremap H ^
" 向下5行
noremap <C-j> 5j
" 向上5行
noremap <C-k> 5k
"----vim 个人使用习惯配置end------

代码格式化

选中要格式化的代码<leader>f，默认leader是\键也就是\ f完成代码格式化。
我把leader修改成空格了，所在我按 空格+f就可以实现代码格式化，

" leader设置成空格
let mapleader=" "

如果觉得选中代码在格式化比较麻烦，直接格式化当前编辑的源码。

:Format

重命名变量

<leader>rn 用来重命名变量，真舒服。

代码段

提高效率神器，安装coc-snippets
项目主页：
https://github.com/neoclide/coc-snippets

打开vim然后运行:CocInstall coc-snippets
安装完成后，重新使用vim编辑java代码的时候就可以使用代码段了，非常方便。以我们常用的
System.out.println为例，直接输入sout回车就搞定了。
在这里插入图片描述
使<tab>用于触发完成，完成确认，摘要扩展和跳转，就像VSCode一样。

inoremap <silent><expr> <TAB>
      \ pumvisible() ? coc#_select_confirm() :
      \ coc#expandableOrJumpable() ? "\<C-r>=coc#rpc#request('doKeymap', ['snippets-expand-jump',''])\<CR>" :
      \ <SID>check_back_space() ? "\<TAB>" :
      \ coc#refresh()

function! s:check_back_space() abort
  let col = col('.') - 1
  return !col || getline('.')[col - 1]  =~# '\s'
endfunction

let g:coc_snippet_next = '<tab>'

安装honza/vim-snippets

 Plug 'honza/vim-snippets'

安装完成以后会更多实用的代码段。

比如：
clc

public class Person {
    
      
      public Person() {
    
    Person
      
      } 
}

这里有个美中不足的，第二行末尾会多出个Person不知为什么。
sout :

System.out.println();

psvm

public static void main (String[] args) {
    
    
	
}

基本上我在Intelj IDEA中常用代码段都有了。

其他

:CocCommand

查询支持的命令

coc-lists

安装方法：

:CocInstall coc-lists

coc-actions

:CocInstall coc-actions

生成getter setter

执行:CocAction
操作如下：
在这里插入图片描述

打开一个终端

:term

总结

与SpaceVim实现的方式各有优化缺点。比较起来感觉SpaceVim相对更重一些，集成了很多好用的插件对于新手更友好一些。coc.nvim感觉就比较轻量，coc.nvim共用了一些vscode的插件，个人感觉生态会更好一些。

如果觉得有用的话，点赞评论支持一下吧！

猜你喜欢

转载自blog.csdn.net/lxyoucan/article/details/115460229#comments_24800459
今日推荐
火速冲上 GitHub 热榜 —— 开源编程语言、框架哪有这么可爱？
北京人形机器人创新中心发布全球首个纯电驱拟人奔跑的全尺寸人形机器人“天工”
LFOSSA 源来如此公开课 | 掌握云原生未来：CNCF 认证全面攻略与备考秘籍
国产云输入法——仅华为无云端数据上传安全问题
开源日报 | 工业开源项目OGG 1.0；姐姐，你要和我一起配置火狐吗；苹果AI遥遥落后？Fedora 40
开放签电子签章：停止新增，优化体验，前进更进（五一假期前工作）
开源日报 | 中学生开源前端动画引擎；全球首个Llama3 8B中文版开源模型；联想电脑恐出局；Linus讽刺AI炒作
周排行
浏览器对同一域名进行请求的最大并发连接数
React Hook之自定义Hook
【转】MyBatis缓存机制
-Java-泛型
自动化测试常用脚本-发送邮件
LeetCode#859: Buddy Strings
java、Python处理字符串
第二篇の博客
Hadoop伪分布式环境安装
SQL Server进阶（十一）临时表、表变量
每日归档
更多
2024-04-27(56)
2024-04-26(39)
2024-04-25(22)
2024-04-24(36)
2024-04-23(26)
2024-04-22(39)
2024-04-21(0)
2024-04-20(6)
2024-04-19(5)
2024-04-18(0)

代码天地 © 2018 codetd.com

境外服务器   最新电视剧2022