Shader "Unity Shaders Book/Common/Bumped Specular" {
Properties {
_Color ("Color Tint", Color) = (1, 1, 1, 1)
_MainTex ("Main Tex", 2D) = "white" {
}
_BumpMap ("Normal Map", 2D) = "bump" {
}
_Specular ("Specular Color", Color) = (1, 1, 1, 1)
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader {
Tags {
"RenderType"="Opaque" "Queue"="Geometry"}
Pass {
//前向渲染，计算平行光和环境光，多个平行光时只会有一个按逐像素处理，其他按逐顶点或addtional中逐像素
Tags {
"LightMode"="ForwardBase" }
CGPROGRAM
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST; //缩放和偏移
sampler2D _BumpMap; //存储表面法线，当没有提供任何法线纹理时，bump对应模型自带的法线信息
float4 _BumpMap_ST;//控制凹凸程度，值为0时，该法线纹理不会对模型产生任何影响
fixed4 _Specular;
float _Gloss;
struct a2v {
//语义由每个材质的mesh renderer组件提供，调用draw call时把模型数据（法线、顶点等）发送给shader
float4 vertex : POSITION;
float3 normal : NORMAL; //[-1,1]
float4 tangent : TANGENT; //填充切线方向，float4是因为w分量存储副切线的方向性
float4 texcoord : TEXCOORD0; //纹理坐标，二维向量，横纵坐标0-1，对应物体表面的顶点坐标
};
struct v2f {
float4 pos : SV_POSITION; //必须要用这个语义，不然没有裁剪空间坐标无法渲染顶点到屏幕
float4 uv : TEXCOORD0;//xy存_MainTex纹理坐标，zw存_BumpMap纹理坐标，通常都使用同一组
//模型到世界空间的变换矩阵，因为对矢量变换只需要3*3，因此最后一列用来存世界空间的顶点位置，充分利用。
float4 TtoW0 : TEXCOORD1; //一个插值寄存器最多只能存储4个float
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
//插值寄存器索引值，0-3已经被用掉
SHADOW_COORDS(4)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
//模型空间到切线空间的变换矩阵rotation，在UnityCG.cginc中定义
TANGENT_SPACE_ROTATION;
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; //副切线
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
//计算v2f中声明的阴影纹理坐标，如果平台可以使用屏幕空间的阴影投射技术（判断是否定义UNITY_NO_SCREENSPACE_SHADOWS）
//如果定义了，就会调用ComputerScreenPos函数来计算_ShadowCoord，把顶点坐标从模型空间变换到光源空间后存储到_ShadowCoord中
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target {
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
//对法线纹理进行采样和解码，需要把法线纹理的格式标识成Normal Map
fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
//把法线变换到世界空间下
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
//同时计算光照衰减和阴影。它的第一个参数为光照衰减和阴影值相乘的结果，
//atten不需要自己声明，它会帮我们声明，第二个参数为结构体v2f，传递给SHADOW_ATTENUATION计算阴影，
//第三个参数为世界空间的坐标，用来计算光源空间下的坐标，再对光照衰减纹理采样得到光照衰减。
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);
return fixed4(ambient + (diffuse + specular) * atten, 1.0);
}
ENDCG
}
Pass {
//Add中只需要去掉base的环境光和自发光，做一些简单的修改
Tags {
"LightMode"="ForwardAdd" }
//透明度混合
Blend One One
CGPROGRAM
#pragma multi_compile_fwdadd
// Use the line below to add shadows for point and spot lights
// #pragma multi_compile_fwdadd_fullshadows
#pragma vertex vert
#pragma fragment frag
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _BumpMap;
float4 _BumpMap_ST;
float _BumpScale;
fixed4 _Specular;
float _Gloss;
struct a2v {
float4 vertex : POSITION;
float3 normal : NORMAL;
float4 tangent : TANGENT;
float4 texcoord : TEXCOORD0;
};
struct v2f {
float4 pos : SV_POSITION;
float4 uv : TEXCOORD0;
float4 TtoW0 : TEXCOORD1;
float4 TtoW1 : TEXCOORD2;
float4 TtoW2 : TEXCOORD3;
SHADOW_COORDS(4)
};
v2f vert(a2v v) {
v2f o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
o.uv.zw = v.texcoord.xy * _BumpMap_ST.xy + _BumpMap_ST.zw;
float3 worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w;
o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);
o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);
o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(v2f i) : SV_Target {
float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
fixed3 lightDir = normalize(UnityWorldSpaceLightDir(worldPos));
fixed3 viewDir = normalize(UnityWorldSpaceViewDir(worldPos));
fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));
bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
fixed3 albedo = tex2D(_MainTex, i.uv.xy).rgb * _Color.rgb;
fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(bump, lightDir));
fixed3 halfDir = normalize(lightDir + viewDir);
fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(bump, halfDir)), _Gloss);
UNITY_LIGHT_ATTENUATION(atten, i, worldPos);
return fixed4((diffuse + specular) * atten, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}
Unity Shader阶段总结——光照、纹理、阴影
猜你喜欢
转载自blog.csdn.net/memory_MM_forever/article/details/118276172
今日推荐
周排行