学习自狄泰软件，仅作为个人笔记。
杂记：1 为了运用所有的内存空间，8086设定了四个段寄存器，专门用来保存段地址：
CS（Code Segment）：代码段寄存器；
DS（Data Segment）：数据段寄存器；
SS（Stack Segment）：堆栈段寄存器；
ES（Extra Segment）：附加段寄存器。
杂记2： jmp段内跳转和段间跳转
函数调用必须要有栈空间的存在，除了栈空间之外，还要一个栈顶指针，也就是 esp 寄存器，它必须指向栈空间最顶上的位置。
先从 32位保护模式的代码段 跳转到 16位保护模式的代码段
然后再从 16位保护模式的代码段 跳转到16位实模式的代码段
注意；中间有一个 16位保护模式代码段的 作为中转站
注意，保护模式下也有16位的代码段，很好理解，保护模式就体现在保护这两个字上面，就是对内存进行保护，即内存有各自的属性，如这段内存 是否只读 只写等等，那么也完全可以定义16位的 受保护的代码段，即有各自属性的16位代码段。
而这个作为中转的16位保护模式代码段 只做一件事，就是 用合适的选择子对目标段寄存器进行赋值。
问题：为什么要 用合适的选择子对段寄存器进行赋值 ？？
绝大多数时候。处理器运行于保护模式下，而处理器运行在保护模式的时候，性能的瓶颈在于 段描述符是定义在内存中的，所以如果处理需要得到 段基址 段界限 或者 段属性的时候，就必须去读内存，从内存中拿到想要的值。那么这时候问题来了，众所周知，处理器的速度要比内存的速度快的多得多，如果要反复频发的去读内存里面的值，显然会拖慢速度，效率当然会限制。
所以需要解决的一个首要问题就是，如何快速高效的访问内存中的段描述符 ？？
在处理器内存，职能是将 相应的段描述符的值 缓存下来，这样的话，需要得到 段基址 段界限 或者 段属性的时候，就不用不停的读内存了，直接到处理器内部的 高速缓冲存储器中取数据就可以了，而这个高速缓冲存储器 特点就是高速！！ 这样就解决了性能问题。
问题：高速缓冲存储器 会在什么时候 缓存 内存段描述符的值呢？
答案：就在我们使用选择子对段寄存器赋值的时候，就会触发处理器的一个内部操作，即 将段描述符 从 内存中 加载进对应的高速缓冲存储器。
注意：每一个段寄存器都有一个与之对应的高速缓冲存储器。
所以说我们在进入实模式的时候，必须要保证高速缓冲存储器里面的值是合适的，但是不能够直接访问设置高速缓冲存储器的值，可以用段描述符。
注意此处的 ： 在实模式下，段属性的值不可设置！！！，只能沿用保护模式下所设置的值！！ 所以这里就需要在 保护模式跳转到实模式的最后一步
，在保护模式中 通过段描述符 提前设定好 需要跳转到的实模式的段属性！！！
实验
%include "inc.asm"
org 0x9000
jmp ENTRY_SEGMENT
[section .gdt]
; GDT definition
; 段基址， 段界限， 段属性
GDT_ENTRY : Descriptor 0, 0, 0
CODE32_DESC : Descriptor 0, Code32SegLen - 1, DA_C + DA_32
VIDEO_DESC : Descriptor 0xB8000, 0x07FFF, DA_DRWA + DA_32
DATA32_DESC : Descriptor 0, Data32SegLen - 1, DA_DR + DA_32
;32位保护模式下专用栈 段描述符
;32位保护模式下专用栈属性 ：32位保护模式下 可读可写段 范围 0 - 0x7c00 定义为32位保护模式下全局栈空间
STACK32_DESC : Descriptor 0, TopOfStack32, DA_DRW + DA_32
;保护模式下的 16位代码段 段描述符
;保护模式下的 16位代码段属性 ：可执行
;注意段界限一定要指定为 0xFFFF 64k, 否则跳不回实模式
CODE16_DESC : Descriptor 0, 0xFFFF, DA_C
;特殊的 段描述符
;属性 段基址是0，因为最后是跳转到16位的实模式下，所以这里的段基址其实是用不到的，主要用到的是段界限和段属性
;界限是64K(16位实模式下 每个段最多就是64K 即每个段寻址最大界限) ， 属性可读可写
UPDATE_DESC : Descriptor 0, 0xFFFF, DA_DRW
; GDT end
GdtLen equ $ - GDT_ENTRY
GdtPtr:
dw GdtLen - 1
dd 0
; GDT Selector
Code32Selector equ (0x0001 << 3) + SA_TIG + SA_RPL0
VideoSelector equ (0x0002 << 3) + SA_TIG + SA_RPL0
Data32Selector equ (0x0003 << 3) + SA_TIG + SA_RPL0
;定义 32位保护模式下专用栈空间 段描述符STACK32_DESC的 选择子，在全局段描述符表中的下标是4 所以段描述符索引值是 4
Stack32Selector equ (0x0004 << 3) + SA_TIG + SA_RPL0
;定义 保护模式下的 16位代码段 段描述符CODE16_DESC的选择子，在全局段描述符表中的下标是5 所以段描述符索引值是 5
Code16Selector equ (0x0005 << 3) + SA_TIG + SA_RPL0
;定义 特殊的段描述符 段描述符UPDATE_DESC的 选择子 在全局段描述符表中的下标是6 所以段描述符索引值是 6
UpdateSelector equ (0x0006 << 3) + SA_TIG + SA_RPL0
; end of [section .gdt]
;16位实模式 栈顶
TopOfStack16 equ 0x7c00
[section .dat]
[bits 32]
DATA32_SEGMENT:
DTOS db "D.T.OS!", 0
DTOS_OFFSET equ DTOS - $$
HELLO_WORLD db "Hello World!", 0
HELLO_WORLD_OFFSET equ HELLO_WORLD - $$
Data32SegLen equ $ - DATA32_SEGMENT
[section .s16]
[bits 16]
ENTRY_SEGMENT:
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
mov sp, TopOfStack16
;向 BACK_TO_REAL_MODE标签地址+3个字节 的位置 写入 cs寄存器的值，即设置jmp段间跳转的 段基址(cd代码段基址)
mov [BACK_TO_REAL_MODE + 3], ax
; initialize GDT for 32 bits code segment
mov esi, CODE32_SEGMENT
mov edi, CODE32_DESC
call InitDescItem
mov esi, DATA32_SEGMENT
mov edi, DATA32_DESC
call InitDescItem
mov esi, STACK32_SEGMENT
mov edi, STACK32_DESC
call InitDescItem
;初始化 保护模式16位代码段 的段描述符的段基址信息
mov esi, CODE16_SEGMENT
mov edi, CODE16_DESC
call InitDescItem
; initialize GDT pointer struct
mov eax, 0
mov ax, ds
shl eax, 4
add eax, GDT_ENTRY
mov dword [GdtPtr + 2], eax
; 1. load GDT
lgdt [GdtPtr]
; 2. close interrupt
cli
; 3. open A20
in al, 0x92
or al, 00000010b
out 0x92, al
; 4. enter protect mode
mov eax, cr0
or eax, 0x01
mov cr0, eax
; 5. jump to 32 bits code
jmp dword Code32Selector : 0
;从保护模式回到此处
;当代码执行到此处时，处理器已经成功返回实模式，对段寄存器的赋值只会改变相应高速缓冲存储器中的段基址，而段界限和
;段属性仍沿用 UPDATE_DESC中定义的值
BACK_ENTRY_SEGMENT:
;对这些段寄存器重新赋值 ds(数据段寄存器) es(附加段寄存器) ss(堆栈段寄存器)，即刷新对应的高速缓冲存储器
;赋的值就是段基地址左移四位之前的值，cs(代码段寄存器),获取代码段 段继地址
mov ax, cs
mov ds, ax
mov es, ax
mov ss, ax
;改变栈顶指针 16位实模式 栈顶0x7c00
mov sp, TopOfStack16
;关闭A20地址线
in al, 0x92
and al, 11111101b
out 0x92, al
;打开中断
sti
;此处已经从保护模式 返回到 实模式，在实模式下打印 hello world
mov bp, HELLO_WORLD
mov cx, 12
mov dx, 0
mov ax, 0x1301
mov bx, 0x0007
int 0x10
jmp $
; esi --> code segment label
; edi --> descriptor label
InitDescItem:
push eax
mov eax, 0
mov ax, cs
shl eax, 4
add eax, esi
mov word [edi + 2], ax
shr eax, 16
mov byte [edi + 4], al
mov byte [edi + 7], ah
pop eax
ret
;保护模式下的 16位代码段，用于做中转，只做一件事，就是 用合适的选择子对段寄存器进行赋值
; 32位保护模式的代码段 -->(16位保护模式的代码段)--> 16位实模式的代码段
[section .s16]
[bits 16]
CODE16_SEGMENT:
;这里是关键！！ 因为在我们使用选择子对段寄存器赋值的时候，会触发处理器的一个内部操作，即 将段描述符 从 内存中 加载进对应的高速缓冲存储器
;所以这里是将 特殊的 段描述符UPDATE_DESC信息 刷新到 目标段寄存器对应的高速缓冲存储器
;用 特殊的 段描述符UPDATE_DESC的 选择子 为段寄存器进行赋值，是为了刷新目标段寄存器对应的高速缓冲存储器
; 该段描述符 没有段基址(0),段界限64K，段属性可读可写
;将 该段描述符信息 复制到 ax寄存器，并同步到如下寄存器 ds(数据段寄存器)，es(附加段寄存器)，fs，gs(用于显存段)，ss(堆栈段寄存器)
;即同时刷新了 这些寄存器对应的高速缓冲存储器，刷新到符合16位实模式下 段界限和段属性该有的样子
;注意1 此时没有刷新 cs(代码段寄存器)对应的高速缓冲处理器，因为此时我们现在还是处于保护模式的16位代码段中执行，执行需要受保护，不能将此刻的代码段属性改为16位实模式！！
;注意2 该段 段界限一定要指定为 0xFFFF 64k, 否则跳不回实模式，因为 BACK_ENTRY_SEGMENT代表16位实模式下的偏移地址，最大64K, 要保持一致！！
mov ax, UpdateSelector
mov ds, ax
mov es, ax
mov fs, ax
mov gs, ax
mov ss, ax
;通知处理器 现在退出保护模式 进入实模式
mov eax, cr0
;将对应位置 0
and al, 11111110b
mov cr0, eax
;此处已经不是保护模式了，跳转地址不可以用选择子了，要用16位实模式下的地址操作方法 目标地址 ： 段基地址<<4 + 偏移地址
;这里是段间跳转！！！ 跳转到 16位实模式所对应的代码处
;我们想要跳转到( 段基地址<<4+BACK_ENTRY_SEGMENT)地址处继续执行，所以段基地址应该是cs寄存器值(前面有设置为ENTRY_SEGMENT标签地址)，
BACK_TO_REAL_MODE:
jmp 0 : BACK_ENTRY_SEGMENT
;段的长度
Code16SegLen equ $ - CODE16_SEGMENT
[section .s32]
[bits 32]
CODE32_SEGMENT:
mov ax, VideoSelector
mov gs, ax
mov ax, Stack32Selector
mov ss, ax
mov eax, TopOfStack32
mov esp, eax
mov ax, Data32Selector
mov ds, ax
mov ebp, DTOS_OFFSET
mov bx, 0x0C
mov dh, 12
mov dl, 33
call PrintString
mov ebp, HELLO_WORLD_OFFSET
mov bx, 0x0C
mov dh, 13
mov dl, 31
call PrintString
;跳转到 16位保护模式代码段，即 CODE16_SEGMENT 标签处
jmp Code16Selector : 0
; ds:ebp --> string address
; bx --> attribute
; dx --> dh : row, dl : col
PrintString:
push ebp
push eax
push edi
push cx
push dx
print:
mov cl, [ds:ebp]
cmp cl, 0
je end
mov eax, 80
mul dh
add al, dl
shl eax, 1
mov edi, eax
mov ah, bl
mov al, cl
mov [gs:edi], ax
inc ebp
inc dl
jmp print
end:
pop dx
pop cx
pop edi
pop eax
pop ebp
ret
Code32SegLen equ $ - CODE32_SEGMENT
;32位保护模式下专用栈段 代码节 大小4K
[section .gs]
[bits 32]
STACK32_SEGMENT:
;times 可以占位？
times 1024 * 4 db 0
;栈空间大小
Stack32SegLen equ $ - STACK32_SEGMENT
;栈顶值
TopOfStack32 equ Stack32SegLen - 1