UnityShader学习——渐变纹理

简介

渐变纹理的原理简单来说，就是使用diffuse的系数构建一套纹理坐标，从渐变纹理采样颜色。

代码实现

Shader "ShaderBook/Chapter7/RampMap" {
	Properties {
		//物体颜色属性
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_RampTex ("Ramp Tex", 2D) = "white" {}
		//高光属性
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		_Gloss ("Gloss", Range(8.0, 256)) = 20
	}
	SubShader {
		Pass { 
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag

			#include "Lighting.cginc"
			
			fixed4 _Color;
			sampler2D _RampTex;
			float4 _RampTex_ST;
			fixed4 _Specular;
			float _Gloss;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);				
				o.worldNormal = UnityObjectToWorldNormal(v.normal);				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				//使用了内置的TRANSFORM_TEX宏来计算经过平铺和偏移后的纹理坐标
				//等同于v.texcoord.xy * _RampTex_ST.xy + _RampTex_ST.zw;				
				o.uv = TRANSFORM_TEX(v.texcoord, _RampTex);				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {				
				//【1】环境光
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;				
				//【2】漫反射
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				//半兰伯特模型：对法线方向和光照方向的点积做一次0.5倍的缩放以及一个0.5大小的偏移
				fixed halfLambert  = 0.5 * dot(worldNormal, worldLightDir) + 0.5;//（0,1）
				//使用halfLambert来构建一个纹理坐标，并用这个纹理坐标对渐变纹理_RampTex进行采样
				//理论上halfLambert的值在[0, 1]之间，但可能会有1.00001这样的值出现。
				//如果我们使用的是Repeat模式，此时就会舍弃整数部分，只保留小数部分，得到的值就是0.00001。
				//如果使用Clamp模式就不会出现这样的问题。
				fixed3 diffuseColor = tex2D(_RampTex, fixed2(halfLambert, halfLambert)).rgb * _Color.rgb;				
				fixed3 diffuse = _LightColor0.rgb * diffuseColor;
				//【3】高光
				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 halfDir = normalize(worldLightDir + viewDir);
				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);
				//【4】最终颜色
				return fixed4(ambient + diffuse + specular, 1.0);
			}
			
			ENDCG
		}
	} 
	FallBack "Specular"
}