1.材料清单
ESP8266开发板、SG90 9克舵机、microUSB数据线、导线及面包板。
2.电路连接
3.Arduino代码
程序中,WiFi需要改为自己家的WiFi名称和密码,开关灯的舵机角度需要根据自己制作的外壳进行调整。
/*
* nodemcu引脚对应数字:
* 16=D0;
* 4=D2;
* 0=D3;
* 2=D4;
* 14=D5;
* 12=D6;
* 13=D7;
* 15=D8;
* 3=D9;
* 1=D10;
* 舵机 ->D2--模拟输出
*/
#include <ESP8266WiFi.h>
#include <Servo.h>
#ifndef STASSID
#define STASSID "此处填WiFi名称" //WiFi名称
#define STAPSK "此处填WiFi密码" //WiFi密码
#endif
const char* ssid = STASSID;
const char* password = STAPSK;
int angle = 110;//上电置空时舵机角度
Servo myservo; //创造一个servo结构体
//创建服务器实例,指定要监听的端口为80端口
WiFiServer server(80);
void setup() {
Serial.begin(115200);
myservo.attach(4); //舵机信号线,接analogIn脚
//连接WiFi
Serial.println();
Serial.println();
Serial.print(F("WiFi正在连接 "));//用F函数将会把字符串放入RAM中,输出至串口
Serial.println(ssid);
WiFi.mode(WIFI_STA);//设置为接收WiFi模式
WiFi.begin(ssid, password);
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(F("."));
}
Serial.println();
Serial.println(F("WiFi已连接!"));
//开启模块的服务器
server.begin();
Serial.println(F("模块服务端已开启!"));
//打印模块的IP地址
Serial.println(WiFi.localIP());
}
void loop() {
//监测客户端是否连接
WiFiClient client = server.available();
if (!client) {
return;//如果未连接就重新循环监测
}
// Serial.println(F("new client"));
client.setTimeout(5000); // default is 1000
//读取请求内容的第一行
String req = client.readStringUntil('\r');
Serial.println(F("请求: "));
Serial.println(req);
//匹配 请求-->信号变量
if (req.indexOf(F("/gpio/0")) != -1) {
angle = 76; // 如果/gpio/0在请求内容中,发出开灯的信号
} else if (req.indexOf(F("/gpio/1")) != -1) {
angle = 153;// 关灯角度
} else {
Serial.println(F("无效请求"));
}
//根据请求内容设置灯的状态
myservo.write(angle);// 0~180°
Serial.print("当前值:");
Serial.println(angle);
//读取或忽略余下的请求内容
while (client.available()) {
client.read();
}
//向客户端发送回答,HTML网页代码内容
//nagle算法会将它们分组为一个数据包
client.print(F("<!DOCTYPE html>\r\n<html xmlns='http://www.w3.org/1999/xhtml'>\r\n"));
client.print(F("<head>\r\n<meta charset='utf-8'/>\r\n<title>智能卧室灯</title>\r\n"));
client.print(F("<style type='text/css'>.state{text-align:center;font-size:80px;}"));
client.print(F(".on{text-align:center;font-size:200px;alink='#1a9e5f'}.off{text-align:center;font-size:200px;alink='#da4f43'}"));
client.print(F("</style><body><div class='state'>灯状态:"));
client.print((angle>140) ? F("关</div>") : F("开</div>"));
client.print(F("<br><br><div class='on'><a href='http://"));//<br>换行
client.print(WiFi.localIP());
client.print(F("/gpio/0'>开</a></div><br><br><div class='off'><a href='http://"));
client.print(WiFi.localIP());
client.print(F("/gpio/1'>关</a></div></body></html>"));
// 客户端实际上将被“刷新”,然后断开连接
// 当函数返回并且“客户端”对象被销毁时
// 刷新=确保书面数据被服务端接收
Serial.println(F("客户端已挂起!"));
}
4.实现效果
通过串口获取到路由器分配给NodeMCU的IP地址,即可通过访问网址来控制开/关灯 。
比如笔者这里读取到的IP为192.168.0.105,那么开灯时手机上访问的网址为http://192.168.0.105/gpio/0;关灯时手机上访问的网址为http://192.168.0.105/gpio/1。(手机需要和NodeMCU在同一个路由器下,即连接的是同一个WiFi)