什么是DML触发器?
DML触发器是指基于DML操作所建立的触发器.
(DML操作:SELECT、UPDATE、INSERT、DELETE,用来对数据库里的数据进行操作)
DML触发器的作用?
DML触发器可用于实现数据安全保护、数据审计、数据完整性、参照完整性、数据复制等功能.
DML触发器类型?
1.语句触发器
在指定的操作语句之前或之后执行一次,不管这条语句影响了多少行.
2.行触发器
触发语句作用的每一条记录都被触发,在行级触发器中使用 :old 和 :new 伪记录变量,识别值的状态.
:old 表示操作之前该行的值
:new 表示操作之后该行的值
创建DML触发器语法:
语句触发器:
delete from empnew where empno=7788;
create [or replace] trigger trigger_name
{before|after}
{delete|insert|update|[of列名]}
on 表名
PLSQL块
行触发器:
delete from empnew where empno=7788;
create [or replace] trigger trigger_name
{before|after}
{delete|insert|update|[of列名]}
on 表名
[for each row [when(条件)]]
PLSQL块
实例1:实现数据的安全保护
功能: 禁止在休息日(周六、周日)改变emp表数据
create or replace trigger emp_trigger1
before insert or update or delete
on emp
begin
if to_char(sysdate,'day') in ('星期六','星期日') then
raise_application_error(-20006,'不能在休息日改变员工信息!');
end if;
end;
当执行删除操作时,会自定执行触发器
实例1属于语句触发器.
实例2: 实现数据审计
功能: 审计员工信息表数据的变化,审计删除时间,以及被删除的雇员名.
--创建审计表
create table delete_emp_audit(
name varchar2(10), --员工姓名
delete_time date --删除时间
);
--创建触发器
create or replace trigger del_emp_tigger
after delete
on emp
for each row
begin
insert into delete_emp_audit values(:old.ename,sysdate);
end;
--测试
delete from emp where empno =7499;
首先创建一张审计表,然后创建触发器.最后删除数据触发已创建的触发器.
查询审计表,发现里面新增了一条删除的员工姓名和删除时间.
实例2是一个行级触发器.
实例3:实现数据完整性
功能: 要求员工涨后的工资不能低于原来的工资,并且所涨的工资不能超过原工资的50%
create or replace trigger tr_check_sal
before update of sal --of 指定更新sal列时触发 触发器
on emp
for each row
when (new.sal < old.sal or new.sal > old.sal * 1.5) --此处new和old不加冒号(:),因为when语句不在qlsql块内部
begin
raise_application_error(-20028,'工资只升不降,并且升幅不能超过50%');
end;
当修改员工工资时会触发这个触发器
实例3也是行级触发器
实例4:实现参照完整性
功能: 级联更新dept表的主键列以及emp表的外键列
create or replace trigger upd_cascade_trigger
after update of deptno
on dept
for each row
begin
update emp set deptno = :new.deptno where deptno = :old.deptno;
end;
执行修改dept表中deptno列,会触发定义的触发器upd_cascade_trigger,在触发器中会把emp表对应的deptno字段进行更新操作.
--测试
update dept set deptno =50 where deptno =10;
查询一下更新后的员工信息
以上就是对DML触发器用法的介绍.