Android开发Gradle高级技巧、自定义Gradle Task、打包完成自动签名、执行Shell脚本

先说下为什么有这篇文章吧，最近在写一个应用需要进行系统签名；每次我都需要先将apk生成然后使用`sign.jar`和系统证书进行签名，非常的麻烦而且tmd还是搞两个系统也就是每次都需要用两个系统证书分别进行签名…

一：每次我都需要两个不同的设备的安装包，所以我使用多渠道打包这样每次进行打包都会给我生成两个apk 。如下代码:

app.gradle ，这里需要注意的是多渠道打包，需要指定一个flavorDimensions具体可以查看下度娘

android {
    defaultConfig {
        //多渠道打包
        flavorDimensions "versionCode"
    }
    // ...
    //两种设备的渠道打包
    productFlavors {
        inches21 {
            buildConfigField("String", "INCHES_TYPE", "\"21\"")
        }
        inches32 {
            buildConfigField("String", "INCHES_TYPE", "\"32\"")
        }
    }
}

如上定义好了多渠道打包就只需要在`Terminal`执行

Mac/Linux用户

./gradlew assembleDebug

Windows用户

gradlew assembleDebug

这样就会在`/app/build/outputs/apk`中生成我们的apk了

二：废话不说了直接进入正题，自定义Gradle Task

先看下一个基本的task结构（当然也还要一些其他东西，这就需要去Gradle文档查看了）

task autoSign {
  //依赖于其他Task执行完，在执行本Task
	  dependsOn ''
	  //先执行
	  doFirst{
	  }
	  // 后执行
	  doLast{
	  }
}

1.这里还是要先科普一些基本的东西，如下：

签名系统apk所需要的东西，两个系统提供的证书，一个jdk提供签名jar文件
sign.sh就是执行这个java -jar ./signapk.jar ./platform.x509.pem ./platform.pk8 被签名apk的路径签名好的apk路径命令，只不过被封装了一下而已

#!/bin/sh
# apk源文件路径
origin=$1
output=$2
java -jar ./signapk.jar ./platform.x509.pem ./platform.pk8 ${origin} ${output}

2.开始编写我们的Task，与`android{}`同级

android{
  // ....
}
// ....
//自定义的Task
task autoSign {
// 这个task执行会在assembleDebug之后执行
    dependsOn 'assembleDebug'
    doLast {
        //签名包的输出目录
        def outputDir = "/Users/azhon/Documents/ebox版本/"
        //签名文件目录
        def inches21Dir = project.rootDir.absolutePath + "/sign/iMx6-21/"
        def inches32Dir = project.rootDir.absolutePath + "/sign/Rk3288-32/"
        android.applicationVariants.all { variant ->
            variant.outputs.all { output ->
                //获取多渠道的名字
                def channel
                variant.productFlavors.each { product ->
                    channel = product.name
                }
                //获取 apk打包出来的文件 output.outputFile
                def exist = output.outputFile.exists()
                if (exist) {
                    //签名之后的apk名字
                    def name = "signed_" + output.outputFile.getName()
                    //apk打包所在的目录
                    def apk = output.outputFile.getPath()
                    //根据不同渠道获取对于的.sh文件路径
                    def wDir = "", shPath = ""
                    switch (channel) {
                        case "inches21":
                            wDir = inches21Dir
                            shPath = inches21Dir + "sign.sh"
                            break
                        case "inches32":
                            wDir = inches32Dir
                            shPath = inches32Dir + "sign.sh"
                            break
                    }
                    println("-----------------------------------")
                    println("签名文件脚本：" + shPath)
                    println("开始签名：" + channel + "......")
                    exec {
                        //切换到sh文件所在的目录，执行脚本
                        workingDir wDir
                        //执行shell脚本 "," 传参
                        commandLine "sh", shPath, apk, outputDir + name
                    }
                    println("签名成功，文件保存至：" + outputDir + name)
                    println("-----------------------------------")
                }
            }
        }
    }
}

3.代码有点多这里进行一下补充

project.rootDir.absolutePath
这个api就是获取当前项目所在磁盘的绝对路径，例如:/Users/azhon/Downloads/office/AndroidStudioProject/demo
output.outputFile
获取通过assembleDebug打包出来的apk文件是个File类型，所以可以直接使用File的方法
exec { workingDir =" " commandLine= “sh” }
执行.sh文件
如果需要拿到执行命令之后的返回值，只需要修改成如下代码即可

def result = new ByteArrayOutputStream()
exec {
    workingDir '.'
    commandLine 'ls','-a'
    standardOutput = result
}
//打印执行的结果
println(result.toString())