一键部署Ride环境

一、一键部署Ride环境脚本

@ECHO OFF

ECHO **********************************************
ECHO  * 用于安装RIDE的批处理程序
ECHO  * 以下注意事项：
ECHO  * 1）配置环境变量前会先备份注册表（备份当前脚本所在文件夹的backup.reg）
ECHO  * 2）如配置的环境变量有问题请运行backup.reg还原
ECHO  * 3）修改注册表，有些杀毒软件会报警，请点击信任
ECHO **********************************************


ECHO 备份注册表
CALL:backup_reg

ECHO 静默安装python2.7
CALL:install_python_packages

ECHO 配置python环境变量
SET KEY=path
SET VALUE=C:\Python27\;C:\Python27\Scripts\;
CALL:modify_env %KEY%,"%VALUE%"

ECHO 安装setuptools
CALL:install_setuptools

ECHO 安装wxpython
CALL:install_wxpython

ECHO 安装robotframework
CALL:install_robotframework

ECHO 安装robotframework_ride
CALL:install_robotframework_ride

ECHO 安装robotframework_selenium2library
CALL:install_robotframework_selenium2library

ECHO 安装chromedriver
COPY %~dp0\chromedriver.exe C:\Python27

ECHO 创建Ride快捷方式
SET Program=C:\Python27\Scripts\ride.py
SET LnkName=Ride
SET IC=C:\Python27\Lib\site-packages\robotide\widgets\robot.ico
call:create_desktop_shortcut "%Program%","%LnkName%","%IC%"

ECHO.&GOTO:EOF

:: 定义备份注册表函数
:backup_reg
	::用户变量存储路径
	SET USERREGPATH=HKEY_CURRENT_USER\Environment
	::注册表备份路径，%~dp0指的当前目录
	SET REGBACKUPPATH=%~dp0backup.reg
	ECHO 备份注册表...
	REG EXPORT %USERREGPATH% "%REGBACKUPPATH%"
GOTO:EOF

:: 定义安装python函数
:install_python_packages
	:: 获取unzip安装包的路径
	FOR /r %~dp0 %%i IN (*.msi) DO (ECHO %%i|FIND "python">NUL && SET PYTHON_PACKAGE_PATH=%%i)
	:: 安装python包
	ECHO 正在安装python，请稍等...
	START /WAIT /MIN %PYTHON_PACKAGE_PATH% /quiet && ECHO python安装成功！
GOTO:EOF

:: 定义安装setuptools函数
:install_setuptools
	ECHO 安装setuptools，请稍等...
	C:\Python27\python.exe %~dp0\setuptools-36.0.1\setup.py install
	ECHO setuptools安装成功!
GOTO:EOF

:: 定义安装wxpython环境
:install_wxpython
	ECHO 安装wxpython，请稍等...
	START /WAIT %~dp0\wxPython2.8-win64-unicode-2.8.12.1-py27.exe /sp- /silent /norestart
	ECHO wxpython安装成功!
GOTO:EOF

:: 定义安装robotframework函数
:install_robotframework
	ECHO 安装robotframework，请稍等...
	C:\Python27\Scripts\pip.exe install robotframework==3.0.4
	ECHO robotframework安装成功!
GOTO:EOF

:: 定义安装robotframework-ride函数
:install_robotframework_ride
	ECHO 安装robotframework_ride，请稍等...
	C:\Python27\Scripts\pip.exe install robotframework-ride==1.5.2.1
	ECHO robotframework_ride安装成功!
GOTO:EOF

:: 定义安装robotframework_selenium2library函数
:install_robotframework_selenium2library
	ECHO 安装robotframework_ride，请稍等...
	C:\Python27\Scripts\pip.exe install robotframework-selenium2library==3.0.0
	ECHO robotframework_selenium2library安装成功!
GOTO:EOF

:: 定义创建桌面快捷
:: -- %~1: 应用程序所在路径
:: -- %~2: 桌面快捷方式名称
:: -- %~3: 快捷方式图标目录
:create_desktop_shortcut
	IF NOT DEFINED WorkDir call:GetWorkDir "%~1" 
	(ECHO Set WshShell=CreateObject("WScript.Shell"^)
	ECHO strDesKtop=WshShell.SpecialFolders("DesKtop"^)
	ECHO Set oShellLink=WshShell.CreateShortcut(strDesKtop^&"\%~2.lnk"^)
	ECHO oShellLink.TargetPath="%~1"
	ECHO oShellLink.WorkingDirectory=""
	ECHO oShellLink.IconLocation="%~3"
	ECHO oShellLink.WindowStyle=1
	ECHO oShellLink.Description=""
	ECHO oShellLink.Save)>makelnk.vbs
	ECHO 桌面快捷方式创建成功！
	makelnk.vbs
	DEL /f /q makelnk.vbs
GOTO:EOF

:: 定义修改注册表函数，需要提起设置和
:: -- %~1: 环境变量KEY的值
:: -- %~2: 环境变量的VALUE
:modify_env
	::用户变量存储路径
	SET USERREGPATH=HKEY_CURRENT_USER\Environment
	::使用关键字key查询用户环境变量注册表
	REG QUERY %USERREGPATH% /v %~1 1>nul 2>nul
	::若使用关键字key查询用户环境变量成功，将查询出来变量的结果存到oldPathValue中
	IF %ERRORLEVEL%==0 (
		FOR /f "tokens=3 delims= " %%i IN ('REG QUERY %USERREGPATH% /v %~1') DO (SET OLD_REG_VALUE="%%i")
	)
	ECHO 设置环境变量%~1
	IF DEFINED OLD_REG_VALUE (
		SETX %~1 "%OLD_REG_VALUE%;%~2"
	) ELSE SETX %~1 "%~2"
	ECHO 环境变量%~1设置成功！
GOTO:EOF

:: 定义添加用户环境变量
:: -- %~1: 环境变量key的值
:: -- %~2: 环境变量的VALUE
:add_evn
	ECHO 设置环境变量%~1 
	::用户变量存储路径
	SET USERREGPATH=HKEY_CURRENT_USER\Environment
	::使用关键字key查询用户环境变量注册表
	REG QUERY %USERREGPATH% /v %~1 1>nul 2>nul
	::若使用关键字key查询用户环境变量成功，将查询出来变量的结果存到oldPathValue中
	IF %ERRORLEVEL%==0 (
		ECHO 环境变量%~1已经添加！
	) ELSE (
		SETX %~1 "%~2" && ECHO 环境变量%~1设置成功！
	)
GOTO:EOF

二、脚本下载地址

链接：https://pan.baidu.com/s/1Q2AJoRy2CdGs4efB5j4tAg 提取码：7q5v

三、FAQ

Q：CMD命令模式使用pip提示Did not provide a command
R：系统中存在多个pip，因此无法确定您要使用的是哪一个，虽然不并不知道另外两个是
S：使用命令where pip命令查看

Q：搭建ride环境后执行脚本报如下错误：
command: pybot.bat --argumentfile c:\users\keikei\appdata\local\temp\RIDEama2ym.d\argfile.txt --listener D:\Python27\lib\site-packages\robotide\contrib\testrunner\TestRunnerAgent.py:52418 E:robot\测试项目
R：robotframework的版本过高
S：使用命令pip freeze查看robotframework的版本如下：
解决方法：
pip uninstall robotframework
pip install robotframework==3.0.4

一、一键部署Ride环境脚本

二、脚本下载地址

三、FAQ

猜你喜欢