现在大家用惯了C，估计对汇编会比较头大，但是上下文切换往往是汇编写的，操作系统的上下文又是任务调度的关键。这篇文章，就给大家详解下LiteOS的上下文切换。
ARM中，上下文的切换逻辑是在PendSV中断中完成的。PendSV中断在系统中断中优先级最低，因此任务切换策略可以有systick触发，或者操作系统已有有的策略触发。systick触发状态下，就完成了时间片和优先级条件下的任务切换，也就是操作系统中常常提到的根据时间片切换（隐含了优先级的）。
本篇文章是基于STM32F103RC写的，请大家根据相关根据芯片适当调整。
LiteOS中，任务调度是通过osSchedule和LOS_Schedule完成的，最终的调度都是通过osTaskSchedule实现的。
在文件Los_dispatch.s中，osTaskSchedule用汇编完成了相关功能。
以下是真个上下文切换的过程。
这个过程中需要注意一下几个寄存器：PRIMASK 保存了中断状态，R0~R3没有保存和取出
稍微用心的小伙伴都会想到，R0和R3没有保存，那原来的数据岂不是就丢了？
不会，因为R0和R3是在中断过程中自动压栈的。它们中断前的值已经存入了栈中。
另外，压栈SP是为了恢复任务时，能够找到栈的起始位置。
代码中，还有过程：push LR，这个是为了保存，当前任务执行完的返回状态。
以下贴出这个过程的代码和注释，请大家自己阅读
osTaskSchedule
LDR R0, =OS_NVIC_INT_CTRL ;使能PendSV中断
LDR R1, =OS_NVIC_PENDSVSET
STR R1, [R0]
BX LR
PendSV_Handler
MRS R12, PRIMASK ;R12=PRIMASK，保存终端状态
CPSID I ;禁止全局终端
LDR R2, =g_pfnTskSwitchHook ;R2=&g_pfnTskSwitchHook
LDR R2, [R2] ;R2=g_pfnTskSwitchHook
CBZ R2, TaskSwitch ;if(R2!=TaskSwitch) push (LR) g_pfnTskSwitchHook为0，则一定都会push
PUSH {LR}
BLX R2 ;将下一行 pop{LR} 存入LR,同时跳转到R2给出的地址
POP {LR}
TaskSwitch
MRS R0, PSP ;R0=PSP
STMFD R0!, {R4-R12} ;R4~R12的寄存器数据存入堆栈 同时更改栈顶
LDR R5, =g_stLosTask ;R5=g_stLosTask
LDR R6, [R5] ;R6=*g_stLosTask.pstRunTask即当前运行的任务地址
STR R0, [R6] ;存储任务到栈
LDRH R7, [R6 , #4] ;R7=usTaskStatus
MOV R8,#OS_TASK_STATUS_RUNNING ;
BIC R7, R8 ;R7 &= ~R8
STRH R7, [R6 , #4] ;usTaskStatus = R7
LDR R0, =g_stLosTask ;R0=g_stLosTask.pstNewTask
LDR R0, [R0, #4] ;
STR R0, [R5] ;g_stLosTask.pstRunTask = g_stLosTask.pstNewTask
LDRH R7, [R0 , #4] ;R7=g_stLosTask.pstNewTask
MOV R8, #OS_TASK_STATUS_RUNNING ;
ORR R7, R8 ;
STRH R7, [R0 , #4] ;g_stLosTask.pstNewTask.usTaskStatus|=OS_TASK_STATUS_RUNNING
LDR R1, [R0] ;堆栈中弹出寄存器R4~R12，同时更改栈顶
LDMFD R1!, {R4-R12} ;
MSR PSP, R1 ;堆栈复制
MSR PRIMASK, R12 ;PRIMASK = R12 恢复中断状态
BX LR ;跳转回PendSV_Handler
NOP
ALIGN
END