前面的实验中，无论是按键的状态，还是串口的发送接收状态，都是通过轮询的方式进行读取，不仅低效而且严重浪费CPU计算周期，在实际的生产环境下决不能使用！从本文开始，我们进进入一个新的时代，中断处理。
0 中断、异常、软中断，傻傻分不清
在CPU中断处理领域，术语比较混乱。而且有时候同一个术语在不同的语境含义也不相同。这里我们以S3C2440的数据手册为准解释相关概念。
- 异常，英文名Exception。是相对于正常Normal而言的，所有打断正常执行流程的情况都叫做异常。
- 中断，Interrupt。属于异常的一种，指的是CPU执行流程被来自CPU之外的信号打断，更加严格的叫法是外部中断 External Interrupt。
- 软中断，Software Interrupt。实际上它不是中断，只是异常，因为其来源于CPU内部。
在很多文章和书籍中，中断的概念被放大，指的不仅仅是外部中断，而是与这里的异常表示一个含义。比如常见的中断向量，实际上更加严格的名字应该是异常向量。实际使用时，往往对中断和异常不加区分，因为其实际处理流程也是一样的，只是信号来源不同而已。
有些异常和中断还是有区别的，例如未知指令、内存方位失败、软中断的异常是不能够被屏蔽的，CPU必须处理。而外部中断一般都是可以有选择的进行屏蔽和不处理的。
本文也没有区分这两个概念，请读者根据语境自行判断。
1 S3C2440中断原理
S3C2440片内集成了中断控制器，直接读写相关的寄存器，就可以完成中断处理相关的各种设置。中断控制器用来决定哪些中断可以发送至CPU核，而CPU的状态寄存器F、I位则决定是否对来自中断控制器的中断信号进行处理。CPU启动后，中断控制器默认是屏蔽所有中断的，但是CPU的CPSR允许处理中断。
1.1 中断产生流程
其数据手册上给出了非常清晰中断处理流程，如下图所示。
这里简单说一下几个特点：
（1）有两种中断模式，一般模式（IRQ）和快速模式(FIQ)，任何中断源都可以设置为两种模式之一，但是只能有一个中断源被设置FIQ模式。
（2）处理中断时，CPU会自动切换运行模式，并保存当前程序状态寄存器
（3）经过优先级过滤后，最后同一时刻只能有一个中断信号被发送到CPU核。
1.2 中断导致CPU运行模式切换
中断处理需要CPU进入中断前保存现场，并且在返回被中断程序时恢复现场，这涉及到大量的操作。为加速这一过程，ARM引出了CPU运行模式，每种模式都有自己独占的一组寄存器供其使用，这样就能够减少现场保存与恢复的寄存器数量。ARM920T共有7种运行模式：
切换模式有两种方式，一是软件设置CPSR寄存器中的模式位；二是当发生异常时，CPU自动切换到特定的模式运行。每种模式看到的寄存器是不完全相同的，尤其是SP寄存器为各模式各有自己的实体，所以需要各个模式分别设置自己的堆栈指针。
1.3 中断向量
处理中断时，CPU在保存现场后，自动跳转到中断源对应的中断向量地址。对于ARM920T，中断过向量表定义如下：
例如，当处理IRQ类型中断时， CPU自动跳转到0x00000018处执行。由于中断向量只有4个字节大小，所以一般都是只存放一条跳转指令。
2 S3C2440中断控制器配置
S3C2440的中断控制器可以接受来自60个不同的中断源。由于其控制寄存器只有32位，只能直接控制32个中断源，所以引入了分组的概念。把一些相关的中断源分成一组，然后再通过另一个寄存器来甄别一组中的具体的中断源。
2.1 中断屏蔽寄存器
通过INTMSK和SUBINTMSK这两个寄存器来控制60个中断源的使能与屏蔽。本文我们将测试开发板上的4个按键，它们分别对应EINT1, EINT4, EINT2, EINT0四个中断源。其中EINT0，EINT1，EINT2，EINT3是直接对应到INTMSK的第0、1、2、3位，而EINT4-EINT7则共享（或运算）INTMSK的第4位，具体屏蔽哪一个还需要继续设置EINTMASK寄存器的4-7位。
2.2 中断源状态寄存器
如何判断中断源是否产生中断请求信号了呢？这要通过读取SRCPEND的位来获取。对于EINT4中断源来说，由于其和其他三个中断源共享一位，所以要想判断具体是哪个中断源产生的信号，还需要继续读取ESRCPEND来判断。
2.3 中断状态寄存器
无论中断是否被屏蔽，SRCPEND，ESRCPEND，SUBSRCPEND等中断源状态寄存器都会由中断信号自动设置。而只有没有被屏蔽的中断源信号才能通过优先级处理后来到INTPEND和EINTPEND中断状态寄存器中，进而进入CPU核。
为了确定INTPEND中哪个位被置1，可以逐位进行测试，这会很麻烦耗时，为此提供了INTOFFSET寄存器来记录INTPEND中置1位的偏移量。
2.4 外部中断信号类型控制寄存器
对于外部中断而言，中断源对应实际的物理针脚，至于何种信号才能产生中断是通过EXTINTn寄存器来控制的。以EXTINT0为例。
对于按键，电路图如下：
可见，其抬起状态时对应的引脚电压为3.3V，按下时电压为0。如果采用低电平触发，那么按下时会一直不断的产生中断信号，不适合作为按键功能使用，为此我们选择下降沿触发方式，只在按下的瞬间产生中断信号。
3 IRQ中断处理程序规范
3.1 IRQ中断处理流程
发生IRQ中断后，ARM处理器首先需要执行完当前的指令，然后自动完成如下工作：
- 把当前执行指令的下一条指令的地址存入r14_irq
- 把当前的CPSR保存到IRQ模式下的SPSR_irq
- 使CPSR的模式控制位为0B10010，即切换至IRQ模式
- 似CPSR的I控制位为1，即禁用IRQ中断（这就阻止了IRQ的自我嵌套）
- 将PC寄存器赋值为0x00000018
以上是CPU硬件自动完成的，软件无需参与。当中断处理程序返回时，则需要软件来完成。
- 清除SRCPND，INTPND，EINTPEND等标志
- 把R14-4赋值给PC，实现跳转
- 同时，复制SPSR_irq到CPSR（返回到中断前模式）
上面两个动作，可以使用一个命令来完成：
subs pc, r14, #43.2 IRQ中断向量的安装
只需要在0x00000018处填写一个跳转指令即可。完整的异常向量表如下图
b ResetHandler
b UndHandler
b SwiHandler
b PabortHandler
b DabortHandler
b .
b IrqHandler
b FiqHandler
4 实验代码说明
前面已经分析了中断的处理原理与相关寄存器设置细节。本节直接给出具体的源码片段。
首先是设置IRQ模式堆栈，因为每个模式有自己的专用堆栈指针，所以必须单独设置。这里顺便把所有7中模式的堆栈都设置了，堆栈大小均为1MB。
/* --------------set statck----------------- */
mrs r0, cpsr
bic r0, r0, #0x1F
/* go into Undef mode */
ldr r1, =(0xC0 | UNDEFMODE)
orr r1, r0, r1
msr cpsr_cxsf, r1
ldr sp, =0x34000000
/* go into Abort mode */
ldr r1, =(0xC0 | ABORTMODE)
orr r1, r0, r1
msr cpsr_cxsf, r1
ldr sp, =0x33f00000
/* go into IRQ mode */
ldr r1, =(0xC0 | IRQMODE)
orr r1, r0, r1
msr cpsr_cxsf, r1
ldr sp, =0x33e00000
/* go into FIQ mode */
ldr r1, =(0xC0 | FIQMODE)
orr r1, r0, r1
msr cpsr_cxsf, r1
ldr sp, =0x33d00000
/* go into SYS mode */
ldr r1, =(0xC0 | SYSMODE)
orr r1, r0, r1
msr cpsr_cxsf, r1
ldr sp, =0x33c00000
/* return to SVC mode */
ldr r1, =(0xc0 | SVCMODE)
orr r1, r0, r1
msr cpsr_cxsf, r1
ldr sp, =0x33b00000 /* stack of svc mode */然后是使能CPU中断功能，只有在初始化完毕后才能启动中断功能，否则中断程序尚未准备好，万一来了中断会造成混乱。
/*-------------- enable IRQ/FIQ ------------*/
mrs r0, cpsr
bic r0, r0, #0xC0
msr cpsr_cxsf, r0
最后是，清除中断屏蔽，使得EINT0~4能把中断信号传送到CPU。
void irq_init(void)
{
/* KEY 1,2,3,4: EINT 1,4,2,0 */
rINTMSK &= ~( 1<<1 | 1<<4 | 1<< 2 | 1);
rEINTMASK &= ~(1<<4);
rEXTINT0 &= ~(7 | 7<<4 | 7<<8 | 7<<16);
rEXTINT0 |= (2 | 2<<4 | 2<<8 | 2<<16); /* 010 - Falling edge triggered */
}具体的中断处理。这里把所有的异常处理框架都写出来了。需要注意的是应为中断处理程序里使用BL指令调用C函数，而BL指令会修改lr寄存器的值，而之前lr寄存器保存的是中断返回地址，所以需要在BL指令之前，先把LR的值入栈保存。
每种异常的异常返回地址计算方式是不同的，官方手册给出了具体的算法，直接使用即可。
/* ======== IRQ Mode ============= */
IrqHandler:
sub lr, lr, #4
stmfd sp!, {r0-r12, lr}
mrs r0, cpsr
bl c_irq_handler
ldmfd sp!, {r0-r12, pc}^
FiqHandler:
sub lr, lr, #4
stmfd sp!, {r0-r7, lr}
bl c_fiq_handler
ldmfd sp!, {r0-r7, pc}^
UndHandler:
stmfd sp!, {r0-r12, lr}
bl c_und_handler
ldmfd sp!, {r0-r12, pc}^
SwiHandler:
stmfd sp!, {r0-r12, lr}
bl c_swi_handler
ldmfd sp!, {r0-r12, pc}^
DabortHandler:
sub lr, lr, #8
stmfd sp!, {r0-r12, lr}
bl c_dabort_handler
ldmfd sp!, {r0-r12, pc}^
PabortHandler:
sub lr, lr, #4
stmfd sp!, {r0-r12, lr}
bl c_pabort_handler
ldmfd sp!, {r0-r12, pc}^
IRQ中断处理C函数 c_irq_handler定义在exception.c文件中。
void on_key_down(int key);
/* IRQ handler */
void c_irq_handler(unsigned int cpsr)
{
if((cpsr & (1<<7)) != 0) {
puts("IRQ disabled\n");
}else {
puts("IRQ enabled\n");
}
int offset = rINTOFFSET;
/* clear SRCPEND and INTPEND */
rSRCPND |= (1<<offset);
rINTPND |= (1<<offset);
if(offset == 4) {
rEINTPEND |= (1 << 4);
}
/* handle */
switch (offset) {
case 0:
on_key_down(4);
break;
case 1:
on_key_down(1);
break;
case 2:
on_key_down(3);
break;
case 3:
break;
case 4:
on_key_down(2);
break;
default:
on_unkown_irq();
break;
}
}
按键响应程序on_key_down定义如下：
/* key - the key no, from 1 to 4 */
void on_key_down(int key)
{
if(key == 1) {
puts("key 1 press\n");
}
if(key == 2) {
puts("key 2 press\n");
}
if(key == 3) {
puts("key 3 press\n");
}
if(key == 4) {
puts("key 4 press\n");
}
}
5 完整源码下载
完整源码下载 v0.7。
6 遗留问题
虽然按键采用了边沿触发方式，但是一次按下时，仍然会出现收到2个以上中断信号的情况，是按键硬件设计问题？如何通过软件解决呢？
请大牛们不吝赐教。