QML之MouseArea双击时过滤掉单击事件

Demo测试

代码

ApplicationWindow {
    visible: true
    width: 640
    height: 480
    title: qsTr("Hello World")

    MouseArea{
        anchors.fill: parent
        onPressed: {
            console.log("pressed , pressed , pressed !")
        }
        onReleased: {
            console.log("released , released , released !")
        }
        onClicked: {
            console.log("clicked , clicked , clicked !")
        }
        onDoubleClicked: {
            console.log("doubleClicked , doubleClicked , doubleClicked ！")
        }
    }
}

运行结果

鼠标按下时

鼠标释放时

鼠标单击时

鼠标双击时

分析

单击

1、click = press + release
2、click = release
  单击时，当鼠标按下并不会触发单击事件，鼠标释放时才会触发，所以MouseArea的onClicked（）槽函数等同于onReleased（）

双击

1、doubleClick = press + release + press
2、doubleClick = click + press
  双击时一定会触发一次单击信号，所以只需要触发双击事件的话必须要过滤掉单击事件
3、doubleClick ≠ click + click
  onDoubleClicked（）会在鼠标第二次按下时执行，并且并不存在第二次单击事件

双击时过滤单击信号

代码

    property int clickNum: 0

    Timer{
        id: clickTimer
        //超过300ms还没有触发第二次点击证明时单击（并不一定非要用300ms延时，不过300ms是经典延时时间）
        interval: 300;
        onTriggered: {
            clickNum = 0
            clickTimer.stop()
            console.log("clicked, clicked, clicked")
        }
    }

    Rectangle{
        anchors.fill: parent
        MouseArea{
            anchors.fill: parent
            onClicked: {
                clickNum ++
                if(clickNum == 1)
                {
                    clickTimer.start()
                }
                if(clickNum == 2)
                {
                    clickNum = 0
                    clickTimer.stop()
                    console.log("doubleClicked, doubleClicked,doubleClicked")
                }
            }
        }
    }