这个实验好复杂
思路：通过观察可以看出，字符串“year sumn ne ?? "总共16个字符，可分为四段，每段用空格隔开，字符串最后再加空格。
可以描述为：前四个字符 ，空格，然后是收入数值，空格，然后是雇员数，空格，要算出的人均收入，空格
要求的格式为：前四个字符复制，空格，然后是收入数值，空格，然后是雇员数，空格， 然后人均收入，空格
大小：四个字节 ；一个字节；四个字节 ；一个字节； 两个字节； 一个字节；两个字节；一个字节
前4个字符无脑复制就OK了，之后空格不用复制，直接跳过以此类推，前13个没什么问题。
第14个第15个字节需要找到前面的存放收入的地址（要放入ax和dx中，并且要注意高位和低位）和存放雇员数值的地址（这里要记下来）用div指令计算出来，然后循环，循环需要入栈
assume cs:code,ds:data,es:table,ss:stack
data segment
db '1975','1976','1977','1978','1979','1980','1981','1982','1983'
db '1984','1985','1986','1987','1988','1989','1990','1991','1992'
db '1993','1994','1995'
dd 16,22,382,1356,2390,8000,16000,24486,50065,97479,140417,197514
dd 345980,590827,803530,1183000,1843000,2759000,3753000,4649000,5937000
dw 3,7,9,13,28,38,130,220,476,778,1001,1442,2258,2793,4037,5635,8226
dw 11542,14430,15257,17800
data ends
table segment
db 21 dup ('year sumn ne ?? ')
table ends
stack segment
dw 0,0,0,0
stack ends
code segment
start :mov ax,data
mov ds,ax ;这里数据初始化存放位置
mov ax,stack
mov ss,ax
mov sp,8 ;初始化存放位置
mov ax,table
mov es,ax ;初始化存放位置
mov cx,21
mov bx,0
mov bp,0
mov si,84
mov di,168 ;进行初始化，用bx定位年份字符串，bp定位table中的位置
;si定位总收入，di定位雇员人数，cx准备循环21次
s:push cx ;将cx入栈，准备好循环中的循环
mov cx,4
t:mov al,ds:[bx]
mov es:[bp],al
inc bx
inc bp
loop t ;循环4次将table表中每一行的前四个字符复制好
inc bp ;空格不需要再复制，直接bp+1跳过
mov cx,4
g:mov al,ds:[si]
mov es:[bp],al
inc bp
inc si
loop g ;循环4次将表中的收入数据无脑复制好
inc bp ;跳过空格
mov cx,2
s1:mov al,ds:[di]
mov es:[bp],al
inc bp
inc di
loop s1 ;循环2次将雇员数复制好
inc bp ;跳过空格
mov dx,es:[bp-6] ;找到收入的高位地址放到dx中，这里其实在前面入栈更好
mov ax,es:[bp-8] ;找到收入的低位地址放到ax中
div word ptr es:[bp-3] ;找到雇员数地址，进行运算
mov es:[bp],ax ;计算结果放到人均收入地址中
add bp,3 ;让bp定位下一行的第一个字节
pop cx
loop s ;循环
mov ax,4c00h
int 21h
code ends
end start
正确答案：
