转移指令的原理

可以修改IP，或同时修改CS和IP的指令统称为转移指令。

8086CPU的转移行为有以下几类。

只修改IP时，称为段内转移，比如：jmp ax。
同时修改CS和IP时，称为段间转移，比如：jmp 1000:0。

段内转移又分为：短转移和近转移。

-**短转移**IP的修改范围为-128~127
- **近转移**IP的修改范围为-32768~32767

8086CPU的转移指令分为以下几类。

无条件转移指令(如：jmp)
条件转移指令
循环指令(如：loop)
过程
中断

9.1 操作符offset

操作符offset在汇编语言中是由编译器处理的符号，它的功能是取得标号的偏移地址。比如：

assume cd:codesg
codesg segment
    start:
        mov ax,offset start    ;相当于mov ax,0
    s:
        mov ax,offset s        ;相当于mov ax,3
codesg ends
end start

问题 9.1
有如下程序段，添写两条指令，使该程序在运行中将s处的一条指令复制到s0处。

assume cs:codesg
codesg segment
    s:
        mov ax,bx          ;mov ax,bx的机器码占两个字节
        mov si,offset s
        mov di,offset s0
        ;下面写两条指令
        mov ax,cs:[si]
        mov cs:[di],ax
    s0:
        nop                ;nop的机器码占一个字节
        nop
codesg ends
end s

9.2 jmp指令

jmp为无条件转移指令，可以只修改IP，也可以同时修改CS和IP。

jmp指令要给出两种信息：
（1）转移的目的地址
（2）转移的距离(段间转移、段内短转移，段内近转移)

9.3 依据位移进行转移的jmp指令

jmp short 标号(转到标号处执行指令)，这种格式的jmp指令实现的是段内短转移。

比如：

assume cs:codesg
codesg segment
    start:
        mov ax,0
        jmp short s
        add ax,1
    s:
        inc ax
codesg ends
end start

这段程序执行后，ax中的值为1，因为执行jmp short s后，越过了add ax,1，IP指向标号s处的inc ax。也就是说，程序只进行了一次ax加1操作。

程序所对应的机器码：
这里写图片描述

例子和图解：
这里写图片描述
实际上，jmp short 标号的功能为： $(IP)=(IP)+8位位移$ 。
（1）8位位移=标号处的地址-jmp指令后的第一个字节的地址；
（2）short指明此处的位移为8位位移；
（3）8位位移的范围为-128~127，用补码表示；
（4）8位位移由编译程序在编译时算出。

另一种段内近转移jmp near ptr 标号与此类似，范围为-32768~32767。

9.4 转移的目的地址在指令中的jmp指令

jmp指令并没有转移目的地址，而是相对于当前IP的转移位移。jmp far ptr 标号实现的是段间转移，又称为远转移。功能如：
$(CS)=标号所在段的段地址$
$(IP)=标号在段中的偏移地址$

例子：

assume cs:codesg
codesg segment
    start:
        mov ax,0
        mov bx,0
        jmp far ptr s
        db 256 dup (0)
    s:
        add ax,1
        inc ax
codesg ends
end start

程序所对应的机器码：
这里写图片描述
可以看出，这是直接将段间地址明确指出，而不是计算IP。

9.5 转移地址在寄存器中的jmp指令

指令格式：jmp 16位 reg
功能： $(IP)=(16位reg)$

9.6 转移地址在内存中的jmp指令

转移地址在内存中jmp指令有两种格式：
（1）jmp word ptr 内存单元地址(段内转移)
功能：从内存单元地址处开始存放着一个字，是转移的目的偏移地址。
格式：

mov ax,0123h
mov [bx],ax
jmp word ptr [bx]

执行后， $(IP)=0123H$
（2）jmp dword ptr 内存单元地址(段间转移)
功能：从内存单元地址处开始存放着两个字，高地址处的字是转移的目的段地址，低地址处是转移的目的偏移地址。
$(CS)=(内存单元地址+2)$
$(IP)=(内存单元地址)$
格式：

mov ax,0123h
mov [bx],ax
mov word ptr [bx+2],0
jmp dword ptr [bx]

执行后， $(CS)=0,(IP)=0123H$ ，CS:IP指向0000:0123

检测点 9.1
（1）程序如下。

assume cs:code,ds:data
data segment
    ?
data ends

code segment
    start:
        mov ax,data
        mov ds,ax
        mov bx,0
        jmp word ptr [bx+1]
code ends
end start

若要使程序中的jmp指令执行后，CS:IP指向程序的第一条指令，在data段中应该定义哪些数据？
答案：由于第一条指令的位置是在cs:0000，所以需要将IP改为0，因此data段中的数据只要头3个字节的数据为0即可。

（2）程序如下(补全程序)，使jmp指令执行后，CS:IP指向程序的第一条指令：

assume cs:code,ds:data

data segment
    dd 1234567h
data ends

code segment
    start:
        mov ax,data
        mov ds,ax
        mov bx,0
        ;补全下面两个代码
        mov [bx],bx
        mov [bx+2],cs
        jmp dword ptr ds:[0]
code ends
end start

（3）用Debug查看内存，结果如下：
2000:1000 BE 00 06 00 00 00 …
则此时，CPU执行指令：

mov ax,2000H
mov es,ax
jmp dword ptr es:[1000H]

后， $(CS)=0006h,(IP)=00BEh$

9.7 jcxz指令

jcxz指令为有条件转移指令，所有的有条件转移指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。对IP的修改范围都为：-128~127.

指令格式：jcxz 标号(如果(cx)=0，转移到标号处执行)
操作：

当(cx)=0时，(IP)=(IP)+8位位移
8位位移=标号处的地址-jcxz指令后的第一个字节的地址
8位位移的范围为-128~127，用补码表示
8位位移由编译程序在编译时算出
当(cx)=0时，什么也不做(程序向下执行)

jcxz 标号相当于if(cx==0) jmp short 标号。

检测点 9.2
补全编程，利用jcxz指令，实现在内存2000h段中查找第一个值为0的字节，找到后，将它的偏移地址存储在dx中。

assume cs:code 
code segment
    start:
        mov ax,2000h
        mov ds,ax
        mov bx,0
    s:
        ;补全下面4条指令
        mov ch,0
        mov cl,[bx]
        jcxz ok
        inc bx

        jmp short s
    ok:
        mov dx,bx
        mov ax,4c00h
        int 21h
code ends
end start

9.8 loop指令

loop指令为循环指令，所有的循环指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。对IP的修改范围都为：-128~127。

指令格式：loop 标号((cx)=(cx)-1,如果(cx)!=0,转移到标号处执行)
操作：

(cx)=(cx)-1
如果(cx)!=0，(IP)=(IP)+8位位移
8位位移=标号处的地址-loop指令后的第一个字节的地址
8位位移的范围为-128~127，用补码表示
8位位移由编译程序在编译时算出
如果(cx)=0，什么也不做(程序向下执行)

loop 标号相当于(cx)--; if((cx)!=0) jmp short 标号;。

检测点 9.3
补全编程，利用loop指令，实现在内存2000H段中查找第一个值为0的字节，找到后，将它的偏移地址存储在dx中。

assume cs:code
code segment
    start:
        mov ax,2000h
        mov ds,ax
        mov bx,0
    s:
        mov cl,[bx]
        mov ch,0

        ;补全下面一条指令
        inc cx

        inc bx
        loop s
    ok:
        dec bx          ;dec指令功能和inc相反
        mov dx,bx
        mov ax,4c00h
        int 21h
code ends
end start

9.9 根据位移进行转移的意义

前面讲到：

    jmp short 标号      ;-128~127
    jmp near ptr 标号   ;-32768~32767
    jcxz 标号           ;-128~127
    loop 标号           ;-128~127

这种设计，方便了程序段在内存中的浮动装配。

9.10 编译器对转移位移超界的检测

如果在源程序中出现了转移范围超界的问题，在编译的时候，编译器将报错。

实验8 分析一个奇怪的程序

分析下面的程序，在运行前思考：这个程序可以正确返回吗？

运行后再思考：为什么是这种结果？

通过这个程序加深对相关内容的理解。

assume cs:codesg
codesg segment
    mov ax,4c00h
    int 21h

    start:
        mov ax,0
    s:
        nop
        nop

        mov di,offset s
        mov si,offset s2
        mov ax,cs:[si]
        mov cs:[di],ax

    s0:
        jmp short s

    s1:
        mov ax,0
        int 21h
        mov ax,0

    s2:
        jmp short s1
        nop
codesg ends
end start

实验前分析：程序从start开始执行，执行完mov cs:[di],ax时，s的两个nop应该变为jmp short s1，继续执行完jmp short s后就要开始执行jmp short s1然后转移到标号s1处，执行到int 21h时，返回。

实验时：
（1）执行完mov cs:[di],ax后
这里写图片描述
可以看出nop变成了EBF6((IP)=(IP)-10)与下面的相同

此后将执行mov ax,4c00h 和 int 21h，最后结束程序。

实验9 根据材料编程

内容说明省略，只给出程序代码。

assume cs:code,ds:data

data segment
    db 'welcome to masm!'
data ends

code segment
    start:
        ;在第13行显示，也就是780H
        ;在第40/2-8=32列开始显示，也就是40H
        ;B800:0000H~B800:FFFFH这一段是从B800开始

        ;初始化
        mov ax,data
        mov ds,ax
        mov bx,0

        ;显示缓存区位置初始化
        mov ax,0b800h
        add ax,78h
        mov es,ax
        mov si,40h

        mov cx,16

    s:
        ;高字节,蓝色吧
        mov ah,1h
        mov al,ds:[bx]
        mov es:[si+1],ah
        mov es:[si],al
        inc bx
        add si,2
        loop s

        mov ax,4c00h
        int 21h

code ends
end start

实验结果：
这里写图片描述